SendKeys Alernative for Linux

[pixelink]

I have am planning to move to Linux OS within a year or two.
So, as I prepare to do so I am beginning to remake some of my windows apps (made in VS studio and Laz) to be Linux compatible
However, I do have an app that uses the Windows Sendkeys functionality that performs "sendkeys" by sending text or OS commands to other applications on Windows.

I am wondering.... is there an equivalent function in Laz (Free Pascal) that I can do something similar to SendKeys on other external programs?
If not, what about a 3rd party package or something similar?

Thanks for any suggestion!

[Handoko]

I haven't tried, maybe MouseAndKeyInput unit is what you need. But it is under GPL license, which means you can't use it for closed-sourced projects.

https://wiki.freepascal.org/MouseAndKeyInput

[Thaddy]

I found several examples:

Code: Pascal  [Select][+][-]

1. unit inputsimulator;
2. {$mode objfpc}
3. {$linklib C}    
4. {$linklib X11}  
5. // unit keysym contains the key codes, part of X11 package.
6. interface
7.  
8. uses
9.   X, Xlib, Xutil, keysym;
10.  
11.  
12. procedure Simulate_KeyPress(keySym: cardinal; shiftState: boolean = false);
13. procedure Simulate_Mouse_Click(x, y: integer; button: integer = 1);
14. procedure Simulate_Mouse_move(x, y: integer);
15.  
16. implementation
17.  
18. procedure Simulate_KeyPress(keySym: cardinal; shiftState: boolean = false);
19. var
20.   display: PDisplay;
21.   event: TXKeyEvent;
22.   keyCode: TKeyCode;
23. begin
24.   display := XOpenDisplay(nil);
25.   if display = nil then Exit;
26.  
27.   keyCode := XKeysymToKeycode(display, keySym);
28.  
29.   event.display := display;
30.   event.window := XDefaultRootWindow(display);
31.   event.root := XDefaultRootWindow(display);
32.   event.subwindow := None;
33.   event.time := CurrentTime;
34.   event.x := 1;
35.   event.y := 1;
36.   event.x_root := 1;
37.   event.y_root := 1;
38.   event.same_screen := 1;
39.   event.keycode := keyCode;
40.   event.state := 0;
41.  
42.   if shiftState then
43.     event.state := event.state or ShiftMask;
44.  
45.   // Key press
46.   event._type := KeyPress;
47.   XSendEvent(display, XDefaultRootWindow(display), 1, KeyPressMask, @event);
48.  
49.   // Small delay (optional)
50.   // Sleep(10);
51.  
52.   // Key release
53.   event._type := KeyRelease;
54.   XSendEvent(display, XDefaultRootWindow(display), 1, KeyReleaseMask, @event);
55.  
56.   XFlush(display);
57.   XCloseDisplay(display);
58. end;
59.  
60. procedure Simulate_Mouse_Click(x, y: integer; button: integer = 1);
61. var
62.   display: PDisplay;
63.   event: TXButtonEvent;
64. begin
65.   display := XOpenDisplay(nil);
66.   if display = nil then Exit;
67.  
68.   // Move mouse to position
69.   XWarpPointer(display, None, XDefaultRootWindow(display), 0, 0, 0, 0, x, y);
70.   XFlush(display);
71.  
72.   // Set up event
73.   event.display := display;
74.   event.window := XDefaultRootWindow(display);
75.   event.root := XDefaultRootWindow(display);
76.   event.subwindow := None;
77.   event.time := CurrentTime;
78.   event.x := x;
79.   event.y := y;
80.   event.x_root := x;
81.   event.y_root := y;
82.   event.same_screen := 1;
83.   event.state := 0;
84.   event.button := button;
85.  
86.   // Press
87.   event._type := ButtonPress;
88.   XSendEvent(display, XDefaultRootWindow(display), 1, ButtonPressMask, @event);
89.   XFlush(display);
90.  
91.   // Release
92.   event._type := ButtonRelease;
93.   XSendEvent(display, XDefaultRootWindow(display), 1, ButtonReleaseMask, @event);
94.   XFlush(display);
95.  
96.   XCloseDisplay(display);
97. end;
98.  
99. procedure Simulate_Mouse_move(x, y: integer);
100. var
101.   display: PDisplay;
102. begin
103.   display := XOpenDisplay(nil);
104.   if display = nil then Exit;
105.  
106.   XWarpPointer(display, None, XDefaultRootWindow(display), 0, 0, 0, 0, x, y);
107.   XFlush(display);
108.   XCloseDisplay(display);
109. end;
110.  
111. end.
112.  

Depends on X, not tested for Wayland, but XWayland works.

You can also use xdotool, which works like this:

Code: Pascal  [Select][+][-]

1. procedure SimulateWithXdotool(command: string);
2. begin
3.   ExecuteProcess('/usr/bin/xdotool', command);
4. end;
5.  
6. // Usage examples:
7. // SimulateWithXdotool('key a');           // Press 'a'
8. // SimulateWithXdotool('key Ctrl+c');      // Press Ctrl+C
9. // SimulateWithXdotool('mousemove 100 100'); // Move mouse
10. // SimulateWithXdotool('click 1');         // Left click

Needs xdotool installed: apt-get install xdotool

I have more examples, but these need root priviliges.

[Thaddy]

Side note:
Does anybody know why I could not post my code without using underscores: the original code did not use underscores, but I get this:

Code: Pascal  [Select][+][-]

1. procedure Simula]"]>BlockeduseClick(x, y: integer; button: integer = 1);
2. procedure Simula]"]>BlockeduseMove(x, y: integer);

So I had to add the underscores. Rather irritating...There should not be a security risk, because the code is contained in the codeblock.
Anyway, the inputsimulator unit works, but note some key combinations can be reserved. (also the case with sendkeys)

[MarkMLl]

At a somewhat lower level there's the events API https://www.kernel.org/doc/html/v4.18/input/event-codes.html and also see the evtest program: note that this is specifically input device codes, rather than "events" as in interrupts etc.

What I don't know is whether it's possible to send events to a specific process (identified by PIC) or window (identified at the widget set level).

MarkMLl

[Thaddy]

That needs root privileges, so I left that out. If you are interested I can post for that too..
Using /dev/uinput and fpioctrl. Not really recommended and I doubt if it is very useful to OP.
(Or anybody sane for that matter, usually discussions unfold that are not relevant to the question: a replacement for sendkeys)

[MarkMLl]

That needs root privileges, so I left that out.

No, user needs to be a member of the input group, or the program he's running needs appropriate capabilities.

The sticking point is routing to a specific PID, window etc.

MarkMLl

[pixelink]

Thanks for the info!

[LemonParty]

At a somewhat lower level there's the events API https://www.kernel.org/doc/html/v4.18/input/event-codes.html and also see the evtest program: note that this is specifically input device codes, rather than "events" as in interrupts etc.

What I don't know is whether it's possible to send events to a specific process (identified by PIC) or window (identified at the widget set level).

MarkMLl

I am intersting if someone successfully used this API.

[MarkMLl]

I am intersting if someone successfully used this API.

Not with my own code. I've got a slightly-modified version of mxk originally from http://welz.org.za/projects/mxk (not sure whether that site is still live **), but basically there should be plenty of examples around although they'll probably be written in C.

However as I've said: the problem is that it's global, and oblivious to what program's running etc. To decide whether that API is going to be any use at all for you I suggest playing with evtest, noting that you'll need to be a member of the input group.

MarkMLl

** https://web.archive.org/web/20150804022200/http://welz.org.za/projects/mxk

[LemonParty]

That is quite a lot of C code. But it well written C code. Will be challenging to extract what needed from this sources.
Thank you.