Synapse UDP eventually ends up in a timeout loop

[Leledumbo]

This is only the broadcaster side since the devices expected to reply are 3rd parties, but maybe enough to see where the problem is:

Code: Pascal  [Select][+][-]

1. {$mode objfpc}{$H+}
2. uses
3.   SysUtils,blcksock, synsock;
4.  
5. const
6.   BroadcastAddress = '239.255.255.250';
7.   BroadcastPort    = '1982';
8.   BroadcastMessage = 'M-SEARCH * HTTP/1.1'#13#10
9.                    + 'MAN: "ssdp:discover"'#13#10
10.                    + 'ST: wifi_bulb'#13#10
11.                    ;
12.   BroadcastIntervalMS = 1000;
13.   ReceiveTimeoutMS = 1000;
14.  
15. var
16.   LConn: TUDPBlockSocket;
17.   LRawResponse: String;
18. begin
19.   LConn := TUDPBlockSocket.Create;
20.   LConn.Bind('0.0.0.0', '9999');
21.   if LConn.LastError <> 0 then begin
22.     WriteLn('Failed to bind socket: ', LConn.GetErrorDesc(LConn.LastError));
23.     Halt(1);
24.   end;
25.   LConn.AddMulticast(BroadcastAddress);
26.   LConn.Connect(BroadcastAddress,BroadcastPort);
27.  
28.   while true do begin
29.     WriteLn('Broadcasting...');
30.     LConn.SendString(BroadcastMessage + #13#10);
31.     WriteLn('Waiting for response...');
32.     LRawResponse := LConn.RecvPacket(ReceiveTimeoutMS);
33.     if Trim(LRawResponse) <> EmptyStr then begin
34.       WriteLn(LRawResponse + LineEnding);
35.     end;
36.     WriteLn('Sleeping...');
37.     Sleep(BroadcastIntervalMS);
38.   end;
39. end.
40.  

Initially, for the first few broadcasted messages, the replies are complete and fine. Then it only has 2 possibilities:

• RecvPacket always times out
• One last RecvPacket displays garbage, then always times out

I'm guessing there could be some buffer to flush or connection to reset, but I have no idea at all. Maybe someone knowledgeable in Synapse and UDP Multicast can enlighten me.

[Laksen]

Have you checked with Wireshark what you should be seeing?

[rvk]

This is only the broadcaster side since the devices expected to reply are 3rd parties, but maybe enough to see where the problem is:

Mmm. I'm saw several potential problems (which all but one seem to be non-issues).

*) You are using port 1982 to broadcast a M-SEARCH discovery packet?
I thought these always needed to be on port 1900.
But according to this pdf it seems that you are dealing with non-standard SSDP protocol (which uses 1982 instead of 1900).
https://www.yeelight.com/download/Yeelight_Inter-Operation_Spec.pdf

*) You bind to 0.0.0.0. I've never gotten listening on multiple interfaces for broadcast messages to work.
It's strange that it does work for you. I needed to change it to my local IP to receive anything.

Now for the possible reason of getting garbage and timeouts...

*) You have the SendString for BroadcastMessage inside the loop !!!
So you are sending the M-SEARCH every 1 second. DON'T DO THAT.
Only send once and let the devices have the opportunity to answer.
Now you are flooding the network with M-SEARCH messages, not waiting for an answer.
So your whole network ends up with answer over answer over answer.

Move the SendString outside the loop or wait at least 5 seconds before sending the string again.
You normally only need to send the string once and wait at least 3 second to get all the answers.

You can also add MX: 3 to ask the devices to answer within 3 seconds.

BTW. You can also increase the timeout in LConn.RecvPacket(ReceiveTimeoutMS);
If waiting is all you do in this code, you can just wait 5 seconds for a response.
If it times out then OK. If it receives a response you have a package.
But DON'T send the broadcast again until you are at least 5 seconds after the last one.

Also... In your code you do have the BroadcastIntervalMS. Even setting that to 5000 doesn't fix this issue.
When you have multiple light-bulbs... you only retrieve one package at a time before waiting the 5 seconds.
Other (possible) packages build up in the buffer which come out in the next loop.
The whole flow is kinda messed up with all those sleep() intervals.

So it's better to build a separate loop which runs for 5 to 10 seconds in which you have the receive package.
The timeout for that recvpacket can be 3 (or even 5) seconds (because it doesn't matter if it waits that long at that point).

Sonething like:

Code: Pascal  [Select][+][-]

1.   WriteLn('Broadcasting...');
2.   LConn.SendString(BroadcastMessage + #13#10);
3.   while {check 5 seconds} do
4.   begin
5.     WriteLn('Waiting for response...');
6.     LRawResponse := LConn.RecvPacket( {5 seconds} );
7.     if Trim(LRawResponse) <> EmptyStr then begin
8.       WriteLn(LRawResponse + LineEnding);
9.     end;
10.   end;

If the light-bulb is not found in the loop (note: you could find several) then you can loop that entire code (including sending the broadcast) again.