Helper functions for Integers and other primitive types

[carl_caulkett]

* Mac Mini M1
* macOS 14.6.1
* Lazarus 3.99
* FPC 3.3.1

I notice that it is possible to use code such as "Count.ToString" where Count is an Integer. Is this done by something similar to class helpers, and can it be added to, or is it some "behind the scenes" IDE magic taking place?

[TRon]

Those are typehelpers, defined in sysutils see also Class, Record and Type helpers or the wiki helper types

[jamie]

you can add to them, btw.

[TRon]

Indeed you can jamie but be aware that afaik trunk supports mutliple helpers while current release FPC requires subclassing the old typehelper in order to extend.

[VisualLab]

In particular, type helpers work very well for your own enumeration types. I've been using them for a long time.

[Thaddy]

It is not IDE magic. It is is built into the language. You can use the helpers in any editor

[carl_caulkett]

I've just discovered that you can use TStringHelpers on the class itself, rather than just instances of a string... so: "LineStr := string.Create(LineChar, 180);"
This is so cool 

I see from the docs at https://www.freepascal.org/docs-html/rtl/sysutils/tstringhelper.html that the members of TStringHelper are split into "class function" and "function" so that explains why my discovery works

[TRon]

@carl_caulkett:
Or things like:

Code: Pascal  [Select][+][-]

1.   writeln('remove me and keep this'.Remove(0,9));
2.  

[carl_caulkett]

I've tried to define my own helper for Integers using inheritance, with this...

Code: Pascal  [Select][+][-]

1.   TcaIntegerHelper = type helper(TIntegerHelper) for Integer
2.   public
3.     function Pred: Integer;
4.   end;
5.  

and by using multihelpers with this...

Code: Pascal  [Select][+][-]

1. {$modeswitch multihelpers}
2.  
3. uses
4.   ... Sysutils, ...
5.  
6. type
7.   TcaIntegerHelper = type helper for Integer
8.   public
9.     function Pred: Integer;
10.   end;
11.  

In both cases it's falling over at the TcaIntegerHelper definition with...

Code: Text  [Select][+][-]

1. camidimac.pas(17,27) Error: Identifier not found "helper"
2.  

What am I doing wrong?

[Thaddy]

Demo inherited helpers:

Code: Pascal  [Select][+][-]

1. program helpers;
2. {$if fpc_fullversion < 30301}{$error this program needs trunk}{$endif}
3. {$mode objfpc}{$H+}
4. {$modeswitch typehelpers}
5. uses sysutils;
6. type
7.   TMyIntegerHelper = type helper(TintegerHelper) for integer
8.     procedure inc(const num:integer = 1);
9.   end;
10.  
11.   procedure TMyIntegerHelper.inc(const num:integer);
12.   begin
13.     system.inc(self,num);
14.   end;
15.  
16. var
17.   i:integer = 100;
18. begin
19.   i.inc;
20.   writeln(i);// 101
21.   i.inc(99);
22.   writeln(i);// 200
23. end.

[Thaddy]

Demo multihelpers (needs, trunk/main 3.3.1)

Code: Pascal  [Select][+][-]

1. program helpers2;
2. {$if fpc_fullversion < 30301}{$error this program needs trunk}{$endif}
3. {$mode objfpc}{$H+}
4. {$modeswitch typehelpers}
5. {$modeswitch multihelpers}
6. uses sysutils;
7. type
8.   TIntegerHelper = type helper for integer
9.   procedure inc(const num:integer = 1);
10.   end;
11.  
12.   procedure TIntegerHelper.inc(const num:integer);
13.   begin
14.     system.inc(self,num);
15.   end;
16.  
17. var
18.   i:integer = 100;
19. begin
20.   i.inc;
21.   writeln(i);
22.   i.inc(99);
23.   writeln(i.tostring);
24. end.

Both examples need trunk/main, otherwise they won't compile

[Thaddy]

Demo for version < fpc 3.3.1:

Code: Pascal  [Select][+][-]

1. program helpers3;
2. {$if fpc_fullversion < 30000}{$error this program needs 3.0.0 or higher}{$endif}
3. {$mode objfpc}{$H+}
4. {$modeswitch typehelpers}
5. uses sysutils;
6. type
7.   TMyIntegerHelper = type helper for integer
8.   procedure inc(const num:integer = 1);
9.   end;
10.  
11.   procedure TMyIntegerHelper.inc(const num:integer);
12.   begin
13.     system.inc(self,num);
14.   end;
15.  
16. var
17.   i:integer = 100;
18. begin
19.   i.inc;
20.   writeln(i);
21.   i.inc(99);
22. end.

This compiles from version 3.0.0
So if you have a version below trunk, you must use this version and only one helper can be in scope.

[carl_caulkett]

No worries, I forgot the line {$modeswitch TypeHelpers}.

[carl_caulkett]

Demo inherited helpers:

Thanks, Thaddy. That's brilliant help 🙏🏽

I'm not explicitly on trunk for either Lazarus or FPC, but both inherited and multi seem to work fine