access element's in form

[ali-libre]

how to access all (ie:)tlist create constly in the form?
like:

Code: Pascal  [Select][+][-]

1. with List* do
2.   font.color := clclack;
3. end;

i must be mention the object's not created in an array.

[howardpc]

I am not entirely clear what you are asking, but it may be you are looking for a procedure something like this:

Code: Pascal  [Select][+][-]

1. implementation
2.  
3. uses typinfo, Controls;
4.  
5. procedure ChangeFontColorOf(aForm: TForm; const aControlName: string;
6.   aNewColor: TColor);
7. var
8.   c: TControl;
9.   i: Integer;
10. begin
11.   if Assigned(aForm) then begin
12.     for i:=0 to aForm.ControlCount-1 do begin
13.       c:=aForm.Controls[i];
14.       if c.ClassNameIs(aControlName) and IsPublishedProp(c, 'Font') then
15.         c.Font.Color:=aNewColor;
16.     end;
17.   end;
18. end;

To change the Font.Color of all buttons on your form you might call it like this:

Code: Pascal  [Select][+][-]

1. procedure TForm1.FormCreate(Sender: TObject);
2. begin
3.   ChangeFontColorOf(Self, 'TButton', clBlue);
4. end;

[Remy Lebeau]

Code: [Select]

c.Font.Color:=aNewColor;


The Font property is protected in TControl, you can't access it directly without a type-cast:

Code: [Select]

type
  TControlAccess = class(TControl)
  end;

procedure ChangeFontColorOf(aForm: TForm; const aControlName: string; aNewColor: TColor);
var
  c: TControl;
  i: Integer;
begin
  if Assigned(aForm) then begin
    for i:=0 to aForm.ControlCount-1 do begin
      c:=aForm.Controls[i];
      if c.ClassNameIs(aControlName) and IsPublishedProp(c, 'Font') then
        TControlAccess(c).Font.Color:=aNewColor;
    end;
  end;
end;

Or, use RTTI (since you are using it anyway):

Code: [Select]

procedure ChangeFontColorOf(aForm: TForm; const aControlName: string; aNewColor: TColor);
var
  c: TControl;
  i: Integer;
begin
  if Assigned(aForm) then begin
    for i:=0 to aForm.ControlCount-1 do begin
      c:=aForm.Controls[i];
      if c.ClassNameIs(aControlName) and IsPublishedProp(c, 'Font') then
        TFont(GetObjectProp(c, 'Font')).Color:=aNewColor;
    end;
  end;
end;

Either way, note that the Controls[] list only contains *immediate child controls*.  If you have nested controls more than 1 level deep and want to change their colors, you will have to change the aForm parameter to a TWinControl and then drill down the parent/child hierarchy calling ChangeFontColorOf() recursively:

Code: [Select]

type
  TControlAccess = class(TControl)
  end;

procedure ChangeFontColorOf(aParent: TWinControl; const aControlName: string; aNewColor: TColor);
var
  c: TControl;
  i: Integer;
begin
  if Assigned(aParent) then begin
    for i:=0 to aParent.ControlCount-1 do begin
      c:=aParent.Controls[i];
      if c.ClassNameIs(aControlName) and IsPublishedProp(c, 'Font') then
        TControlAccess(c).Font.Color:=aNewColor;
      if c is TWinControl then
        ChangeFontColorOf(TWinControl(c), aControlName, aNewColor);
    end;
  end;
end;

Otherwise, if you are just interested in controls created at design-time, use the form's Components[] list instead of the Controls[] list.

[howardpc]

@Remy
Your point about accessing nested controls is well made. Thank you demonstrating how to extend to nested controls.

Although Font is a protected property of TControl, the code I showed does work without need of
a cracker class (at least on Linux where I tested it), since the c.Font property is accessed only after a  check to make sure c has a published Font property.

[Remy Lebeau]

Although Font is a protected property of TControl, the code I showed does work without need of
a cracker class (at least on Linux where I tested it), since the c.Font property is accessed only after a  check to make sure c has a published Font property.

You are accessing the Font property through a pointer to TControl itself.  The property is NOT publicly accessible in TControl itself. Regardless of whether a derived class publishes the property, you should NOT be able to access the property from TControl itself. Your code is not in the same unit that declares TControl itself, so you don't have direct access to TControl's non-public members. The code should NOT have compiled as you showed it. If it is, that would be a compiler bug.

[howardpc]

I can't disagree with the theory you present. Since the code I showed compiles and runs on both Linux and Windows, and changes the font colour of any top-level control of the specified control class (though not for nested sub controls), I presume this is a (minor) FPC bug, for not respecting the protected visibility of TControl.Font.

I double checked.

TControl.Font is a public property in the LCL. I don't know about the VCL.
So no FPC bug.

[ASerge]

TControl.Font is a public property in the LCL. I don't know about the VCL.

In VCL it is protected.
Your code is working, but I am confused by the following

Code: Pascal  [Select][+][-]

1. const aControlName: string

+

Code: Pascal  [Select][+][-]

1. c.ClassNameIs(aControlName)

I think either that

Code: Pascal  [Select][+][-]

1. const AControlClassName: string

or so

Code: Pascal  [Select][+][-]

1. SameText(c.Name, aControlName)

[howardpc]

@ASerge
You're right. I chose the parameter name carelessly, and your suggestion is much better, and accurately self-descriptive.
I tell others to improve their naming, and then pick a confusing name myself.

[avra]

how to access all (ie:)tlist create constly in the form?

http://forum.lazarus.freepascal.org/index.php/topic,16773.msg91595.html
http://forum.lazarus.freepascal.org/index.php/topic,34871.msg229597.html
https://www.computerworld.dk/eksperten/spm/779297

[ali-libre]

Yes.
I was searched for wrong key-word...!

Thank's