[SOLVED] class constant ain't recognized as constant expression

[Kays]

Why doesn't the following compile?

Code: Pascal  [Select][+][-]

1. program cc;
2.  
3. {$mode objfpc}
4.  
5. type
6.     TLala = class
7.         public
8.             const
9.                 x: char = 'x';
10.             class procedure doBlub(const i: char);
11.     end;
12.  
13. class procedure TLala.doBlub(const i: char);
14. begin
15.     case i of
16.         TLala.x:
17.             writeln('XXX');
18.         else
19.             writeln(stderr, 'unacceptable input');
20.     end;
21. end;
22.  
23. begin
24.     TLala.doBlub('o');
25. end.

Code: [Select]

Free Pascal Compiler version 3.0.0 [2015/12/05] for x86_64
Copyright (c) 1993-2015 by Florian Klaempfl and others
Target OS: Linux for x86-64
Compiling cc.pas
cc.pas(16,10) Error: Constant Expression expected
cc.pas(26) Fatal: There were 1 errors compiling module, stopping
Fatal: Compilation aborted
Error: /usr/bin/ppcx64 returned an error exitcodeHint: The answer is not „because you haven't wrote a constant expression there“ („42“ neither).

[Martin_fr]

try

Code: Pascal  [Select][+][-]

1.                  
2. const
3.     x = char('x');
4.  

search for "typed constants" do learn why they are not constant (same outside class)

[Kays]

I do have set

Code: Pascal  [Select][+][-]

1. {$J-}

in my original source, which is in the long form

Code: Pascal  [Select][+][-]

1. {$writeableconst off}

.

I forgot it in my minimal non working example.

Why does it still not work? Or to what were you referring to?

[Leledumbo]

I do have set

Code: Pascal  [Select][+][-]

1. {$J-}

in my original source, which is in the long form

Code: Pascal  [Select][+][-]

1. {$writeableconst off}

.

I forgot it in my minimal non working example.

Why does it still not work? Or to what were you referring to?

That doesn't make writableconst to have const semantics, i.e.: it's NOT a constant expression as Martin_fr describe. It still has location in memory instead of immediate value.

[Thaddy]

That is correct.
The following code will be translated to a char literal and will work as expected:

Code: Pascal  [Select][+][-]

1. const x = 'x' ;

In that case the compiler will generate an immediate value.

Note that writable typed consts are a means to preserve state over multiple calls, and not really consts as explained above. A real const will if possible be translated into an immediate value.

Example:
The - local - test const will be incremented over multiple calls in $J+ mode. Something that can not be achieved if it was a var:

Code: Pascal  [Select][+][-]

1. program x;
2. {$APPTYPE CONSOLE}
3. {$mode objfpc}{$J+}
4.   function myconst:integer;
5.   const test:integer = 0;
6.   begin
7.     inc(test);
8.     result := test;
9.   end;
10. var
11.   i:integer;
12. begin
13.  for i := 0 to 9 do
14.    writeln(myconst);
15.  readln;
16. end.
17.