[SOLVED] TImage remains black after FillRect in FormShow

[munair]

I have a procedure to fill the initial bitmap's canvas of TImage (ItemImage):

Code: [Select]

procedure TfrmMain.ClearImage();
begin
  with ItemBmp.Canvas do
    begin
      // form's background color
      Brush.Color := GetColorResolvingParent;
      Brush.Style := bsSolid;
      FillRect(Rect(0, 0, Width, Height));
    end;
  // update image
  ItemImage.Picture.Bitmap.Canvas.Draw(0, 0, ItemBmp);
end;
First of  all: if I call this procedure in FormShow, then ItemImage remains black. When I call it two times in FormShow, then I get the desired result.

Also, it appears that I need a second bitmap (ItemBmp) to clear the image; if I try to do the fillrect directly on ItemImage, it remains black.

Before calling this procedure, Width and Height are properly set in FormShow:

Code: [Select]

procedure TfrmMain.FormShow(Sender: TObject);
begin
  // setup bitmaps
  ItemBmp := TBitMap.Create;
  with ItemImage.Picture.Bitmap do
    begin
      // fixed size
      SetSize(610, 546);
      ItemBmp.SetSize(Width, Height);
    end;
  ClearImage;
  ClearImage;
end;
This is on Debian Linux 7.8. I am probably doing something wrong, but I cannot figure out what it is.

[Blaazen]

Hi,

GetColorResolvingParent can give you values like clForm or clBtnFace which are not RGB values but system constants (see unit Graphics where it is defined).

Try to pass it thru ColorToRGB, it should work:

Code: [Select]

Brush.Color:=ColorToRGB(GetColorResolvingParent);

[munair]

Thanks Blaazen, but no effect.

I narrowed it down to the first problem. Here is my complete example code:

Code: [Select]

unit uImage;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ExtCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Image1: TImage;
    procedure FormShow(Sender: TObject);
  private
    procedure ClearImage;
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.ClearImage;
begin
  with Image1.Picture.Bitmap.Canvas do
    begin
      // form's background color
      Brush.Color := ColorToRGB(GetColorResolvingParent);
      Brush.Style := bsSolid;
      FillRect(Rect(0, 0, Width, Height));
    end;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  Image1.Picture.Bitmap.SetSize(200, 200);
  ClearImage;  // image remains black
  //ClearImage;  // uncomment to give image the window bgcolor
end;

end.

[Blaazen]

Try replace Width&Height with Image1.Width/Height:

Code: [Select]

procedure TForm1.ClearImage;
begin
  with Image1.Picture.Bitmap.Canvas do
    begin
      // form's background color
      Brush.Color := ColorToRGB(GetColorResolvingParent);
      Brush.Style := bsSolid;
      FillRect(Rect(0, 0, Image1.Width, Image1.Height));
    end;
end;
It has some relation to initialization of the canvas, I don't exactly why it is but modified code works.

[munair]

Thanks Blaazen, indeed this works.