TList

[Rodney]

Good afternoon
What I would like to do is very simple - Create a dynamic list of integers.
I assumed that the answer was some form of TList but my searches have failed to reveal any simple example of using TList.  (By simple I mean examples that I can understand!)

I would like to be able to add to, delete from, and sort an arbitrary list of numbers.

Any help would be appreciated.

Best regards
Rodney

[eric]

Probably the easiest way would be to use a dynamic array:

Code: [Select]

var
  MyArray: array of Integer;
...
...
SetLength(MyArray, <Value>);      //Sets the length of the array to <Value> elements
Don't bother with sorting the array, just insert each new element in the right position after moving all the higher values up one place. To delete an element, move all the higher values down one place.

[marcov]

Real adventurous people might also look in unit FGL for generic solutions.

[Rodney]

Thanks Eric.

I know about dynamic arrays but I was looking rather for a 'collection' where a 'delete' method would automatically handle all the necessary shuffling of the array elements, and as 'insert' method would allow you to add an integer at a particular place in the list.

Regards

Rodney

[Rodney]

Marcov

Is there a simple user-friendly introduction to FGL?

I need a nice straightforward example where I can learn by building on.

Regards

Rodney

[marcov]

Marcov

Is there a simple user-friendly introduction to FGL?

Not really. There is some information about generics syntax in the wiki though.

I need a nice straightforward example where I can learn by building on.

Well, the FGL mostly manages pointer types, so they wouldn't really apply directly. The FGL unit was more or less meant as an example, how to do a container type.

[mse]

I would like to be able to add to, delete from, and sort an arbitrary list of numbers.

msearrayutils:

https://gitorious.org/mseide-msegui/mseide-msegui/source/5f1ce35b9e1caa7c1bd1184e0597e98620369845:lib/common/kernel/msearrayutils.pas

[Rodney]

Thanks MSE

That looks interesting.  I will see if I can make use of it.

Regards
Rodney

[BeniBela]

Or bbutils:

https://github.com/benibela/bbutils/blob/master/bbutils.pas

[Leledumbo]

Is there a simple user-friendly introduction to FGL?

I don't think any introduction is required for FGL, but for generics syntax is another thing and already done. Once you get it, you just need to know the interface. Simple example:

Code: [Select]

{$mode objfpc}
uses fgl;
type TIntegerList = specialize TFPGList<Integer>;
var IntegerList: TIntegerList;
begin
  IntegerList := TIntegerList.Create;
  // call .Add() .Find() .IndexOf() .Delete() .WhateverYouSeeInTheInterface()
  IntegerList.Free;
end;


[Ocye]

...for FGL, but for generics syntax is another thing and already done.

...and explained in detail at the wiki .

But maybe the OP want to learn how to use a TList with integer. Since TList handles only pointers (or objects) you have to allocate the items explicitly.

Code: [Select]

type
  pinteger=^integer;
var
  aList:TList;
  pi:pinteger;
  i:integer;
begin
  aList:=TList.Create;

  for i:=0 to 9 do
  begin
    New(pi);
    pi^:=i;
    aList.Add(pi);
  end;

  for i:=0 to aList.Count-1 do
    writeln(pinteger(aList[i])^);

  //take care about self created items
  for i:=aList.Count-1 downto 0 do
    Dispose(pinteger(aList[i]));

  aList.Clear;
  aList.Free;
end.

It's much easier with classes:

Code: [Select]

type
  TTest=class
    Value:integer;
  end;

var
  aList:TList;
  aTest:TTest;
  i:integer;
begin
  aList:=TList.Create;

  for i:=0 to 9 do
  begin
    aTest:=TTest.Create;
    aTest.Value:=i;
    aList.Add(aTest);
  end;

  for i:=0 to aList.Count-1 do
    writeln(TTest(aList[i]).Value);

  //take care about self created items
  for i:=aList.Count-1 downto 0 do
    TTest(aList[i]).Free;

  aList.Clear;
  aList.Free;
end.


[eny]

http://delphiforfun.org/Programs/Library/IntegerList.htm

[User137]

Based on info given in this thread, it should be possible make

Code: [Select]

TIntegerList = class(TList)
private
  function GetIntValue(index: integer): integer;
  procedure SetIntValue(index, value: integer);
public
  procedure Add(value: integer); // Allocate memory for int and add pointer to list
  property values[index: integer]: integer read GetIntValue write SetIntValue;
end;
If out of principle like me, you want to avoid 3rd party libraries for something like this.

[mangakissa]

Isn't it easier to to use pointer en integer.

Code: [Select]

TList.add(pointer(1))

value := integer(TList[0])

[howardpc]

Isn't it easier to to use pointer en integer.

What do you mean by "easier"?
All TList-based classes (whether standard or generic) necessarily involve casting to and from the value of the base pointer type. The whole point of developing derived classes such as TStringList, TIntegerList, TFPGList is to enable us to have type-safe TList functionality across all the common data types we want list functionality for without needing to do explicit (error-prone) casts every time the class is used (since the casting has been safely done in the wrapper class once and for all).