Stuck in a wait

[w click]

I've written a procedure that causes the program to wait, but I can't find a way to interrupt it with a key press.

    while now<waittime do begin
      temptime:=waittime-now;

// Stuff here to update the progressbar and a label showing the time left.   

      if keypressed then waittime:=0;
    end;

Keypressed, from the crt unit, just locks it up completely.  I'm using form1.onkeypress for keyboard handling. I need a sort of 'handle events' instead of a keypressed approach.  Any thoughts would be much appreciated.

[Laksen]

Why not just handle interface updating from a timer event?

Lengthy processing in events will block other events from occuring

[Mando]

 add:
 

Code: [Select]

application.ProcessMessages; in the loop so that the form can respond to messages from the keyboard.
 
 Regards,
 
 

[Carver413]

be sure to set keypreview to true;

Code: [Select]

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormKeyPress(Sender: TObject; var Key: char);
  private
    { private declarations }
  public
    Timer:Integer;
    Procedure TimeOut;
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
  Timeout;
end;

procedure TForm1.FormKeyPress(Sender: TObject; var Key: char);
begin
  Timer:=0;
end;
Procedure TForm1.TimeOut;
begin
  Timer:=30; //set the timer to 30 sec
  while Timer>0 do
  begin
    //your code here
    Form1.Caption:='Timer:'+IntToStr(Timer);
    Application.ProcessMessages; //allow events to be processed
    Sleep(1000); //sleep for one sec
    Dec(Timer);
  end;
  Form1.Caption:='Time out finished';
end;

end.



[w click]

Application.processmessages did the trick and, once I'd sorted out my regular issue with getting things to refresh, it all looks good now.  Many thanks.

To be fair to Lasken, that would be intelligent, but I'd have to turn my whole program inside out.

Thanks all.