Print Page - Feature announcement: Function References and Anonymous Functions

Announcements => Free Pascal => Topic started by: PascalDragon on May 26, 2022, 09:47:14 pm

Title: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on May 26, 2022, 09:47:14 pm

Dear Free Pascal Community,

The Free Pascal Developer team is pleased to finally announce the addition of a long awaited feature, though to be precise it's two different, but very much related features: Function References and Anonymous Functions. These two features can be used independantly of each other, but their greatest power they unfold when used together.

These features are based on the work by Blaise.ru, so thank you very much and I hope you're doing well considering the current situation.

In the following we'll highlight both features separately and then we'll take a look at using them together.

Function References

Function References (also applicable names are Procedure References and Routine References, in the following only Function References will be used) are types that can take a function (or procedure or routine), method, function variable (or procedure variable or routine variable), method variable, nested function (or nested procedure or nested routine) or an anonymous function (or anonymous procedure or anonymous routine) as a value. The function reference can then be used to call the provided function just like other similar routine pointer types. In contrast to these other types nearly all function-like constructs can be assigned to it (the only exception are nested function variables (or nested procedure variables or nested routine variables), more about that later on) and then used or stored.

Function references are enabled with the modeswitch FUNCTIONREFERENCES (the following examples will assume that this modeswitch is provided).

A function reference is declared as follows:

REFERENCE TO FUNCTION|PROCEDURE [(argumentlist)][: resulttype;] [directives;]

Examples:

Code: Pascal [Select][+]

type
  TProcLongInt = reference to procedure(aArg: LongInt); stdcall;
  TFuncTObject = reference to function(aArg: TObject): TObject;

Like other function pointer types function references can also be declared as generic:

Code: Pascal [Select][+]

type
  generic TGenericProc<T> = reference to procedure(aArg: T);

As you can see, once function references are enabled you can't use the identifier "REFERENCE" as part of an alias declaration without using "&":

Code: Pascal [Select][+]

type
  someref = reference; // will fail
  someref = &reference; // correct fix
  
var
  somevar: reference; // will fail
  somevar: &reference; // correct fix

A function reference variable can then be called like any other function pointer type:

Code: Pascal [Select][+]

var
  p: TProcLongInt;
begin
  p := @SomeLongIntProc;
  p(42);
end.

If a function reference has no parameters then you need to use "()" nevertheless in the FPC/ObjFPC modes like for other function pointer types:

Code: Pascal [Select][+]

type
  TProc = reference to procedure;
var
  p: TProc;
begin
  p := @SomeProcedure;
  p(); // required
  p; // this can be used e.g. in mode Delphi
end.

Like other function pointer types they can also be declared anonymously as part of a variable, field declaration (but not as part of a paramater declaration):

Code: Pascal [Select][+]

var
  f: reference to function: LongInt;
  
type
  TTest = class
    f: reference to procedure;
  end;

They get their great power from a point that is for once not considered an implementation detail: function references are in fact internally declared as reference counted interfaces with a single Invoke() method of the provided signature. So the above examples are in fact declared like this:

Code: Pascal [Select][+]

type
  TProcLongInt = interface(IInterface)
    procedure Invoke(aArg: LongInt); stdcall; overload;
  end;
  
  TFuncTObject = interface(IInterface)
    procedure Invoke(aArg: TObject): TObject; overload;
  end;
  
  generic TGenericProc<T> = interface(IInterface)
    procedure Invoke(aArg: T); overload;
  end;

This has a few implications:

in the RTTI this will appear like a normal interface
it reacts to the $M directive like a normal interface
it is a managed type
it has no valid GUID
it can be implemented by a class
it can be inherited from

Especially the last two points are important.

That the interface can be implemented means that much more functionality and state can be added to a function reference:

Code: Pascal [Select][+]

type
  TFunc = reference to function: LongInt;
 
  TSomeImpl = class(TInterfacedObject, TFunc)
    f: LongInt;
    function Invoke: LongInt;
  end;
  
function TSomeImpl.Invoke: LongInt;
begin
  Result := f;
end;
 
var
  t: TSomeImpl;
  f: TFunc;  
begin
  t := TSomeImpl.Create;
  f := t;
  Writeln(f()); // will write 0
  t.f := 42;
  Writeln(f()); // will write 42
  f := Nil; // the usual warnings about mixing classes and interface apply!
end.

As function references don't have valid GUIDs you can't however use QueryInterface() or the as-operator to retrieve it. Using the low level interface related functions of TObject however will work.

An interface that inherits from a function reference is still considered invokable by the compiler, so it can still be used like an ordinary function reference could, but you can also add additional methods including overloads for Invoke itself:

Code: Pascal [Select][+]

type
  TTest = reference to procedure(aArg: TObject);
  
  TTestEx = interface(TTest)
    function Invoke: TObject; overload;
  end;
  
var
  f: TTestEx;
  o: TObject;
begin
  f := TSomeImplEx.Create;
  o := f();
  f(o);
end.

This is for example described by Stefan Glienke on his blog (https://delphisorcery.blogspot.com/2015/06/anonymous-method-overloading.html). His linked example won't work as-is however due to missing functionality in Rtti.TValue.

As mentioned initially you can assign a nested function to a function reference, but not a nested function variable. There is no real technical reason for this, but it's instead a design choice based on how function references are assumed to behave: they are assumed to be valid beyond their scope (this will become clearer when combined with anonymous functions in the third part), so they can for example be returned from a function or stored in some class instance and can still be considered valid. However a nested function variable is no longer useable once the function frame it was retrieved has been left (for a nested function the compiler can safely convert it in a way that this is no problem, but for a nested function variable it simply can't).
One could argue that the same is true for method pointers and method variables as they aren't callable anymore once their class instance is freed however these are much more common in the Object Pascal world while nested function variables are very seldom used, thus the dangers of the former are much more apparent than the dangers of the later.
For this reason assigning nested function variables to function references is prohibited.

Anonymous Functions

Anonymous Functions (or Anonymous Procedures or Anonymous Routines, in the following simply Anonymous Functions) are routines that have no name associated with them and are declared in the middle of a code block (for example on the right side of an expression or as a parameter for a function call). However they can just as well be called directly like a nested function (or nested procedure or nested routine) would.

Anonymous functions are enabled with the modeswitch ANONYMOUSFUNCTIONS (the following examples will assume that this modeswitch is provided).

An anonymous function is declared as follows:

FUNCTION|PROCEDURE [(argumentlist)][[resultname]: resulttype;] [directives;] [[VAR|TYPE|CONST section]|[nested routine]]* BEGIN [STATEMENTS] END

As can be seen an anonymous function looks like a regular function (or procedure or routine) with the most important differences being that it does not have a name and that it isn't terminated by a semicolon (because it's essentially an expression). Because it doesn't have a name for modes that don't have the implicit RESULTvariable it's allowed to explicitely name the result variable (even in modes that do have the RESULT variable) like is the case with operator overloads.

It's possible to directly call an anonymous function in which case it essentially behaves like a nested function.

Like nested functions anonymous functions have access to the symbols (variables, functions, etc.) of the surrounding scope including Self if the surrounding scope is a method. Accessing such a symbol is named “capturing” and is one of the core concepts of anonymous functions.

Their main use however is when assigning them to one of the various function pointer types: function variables, method variables, nested function variables and function references. However not every anonymous function is assignable to every function pointer type as it depends on which symbols (if any) are captured from the surrounding scope. Unlike for non-anonymous function or method identifiers this assignment is however always done without the "@"-operator, because aside from calling one can't do much else with anonymous functions.
An anonymous function that captures no symbols at all (except for global symbols or static symbols) is assignable to all four function pointer types. If the anonymous function captures Self then it is no longer assignable to function variables, but still to the other three. And if it captures any local symbol then it's only assignable to nested function variables or function references.
In case of function variables, method variables and nested function variables anonymous functions behave just like their non-anonymous counterparts. The differences appear when they're used with function references which will be highlighted in the next part.

But first some examples:

Code: Pascal [Select][+]

type
  TFunc = function: LongInt;
 
var
  p: TProcedure;
  f: TFunc;
  n: TNotifyEvent;
begin
  procedure(const aArg: String)
  begin
    Writeln(aArg);
  end('Hello World');
  
  p := procedure
       begin
             Writeln('Foobar');
           end;
  p();
  
  n := procedure(aSender: TObject);
       begin
             Writeln(HexStr(Pointer(aSender));
           end;
  n(Nil);
  
  f := function MyRes : LongInt;
       begin
             MyRes := 42;
           end;
  Writeln(f());
end.

Anonymous Function References

As mentioned above the greatest power of the two new features comes when the two are combined: like a nested function an anonymous function can access symbols from the surrounding scope, however unlike for nested functions a anonymous function that has been assigned to a function reference can leave the scope where it has been declared in and it will then take the captured symbols with it.
For this purpose any variable or parameter that is captured by an anonymous function will become part of the implicitely created object instance (which shall be considered opaque) that will be assigned to the function reference instead of belonging to the original function. The original function will then reference these symbols using the object instance instead of its stack frame. This has the implication that changes to the symobls will be reflected in all anonymous function that capture that symbol.

For example:

Code: Pascal [Select][+]

type
  TProc = reference to procedure;
 
procedure Test;
var
  i: LongInt;
  p: TProc;
begin
  i := 42;
  p := procedure
       begin
             Writeln(i);
           end;
           
  p(); // will print 42
  
  i := 21;
  
  p(); // will print 21
end;

Changes will those also be persistent across calls and different anonymous functions as long as they capture the same symbols:

Code: Pascal [Select][+]

type
  TProc = reference to procedure;
  
procedure Test;
var
  i: LongInt;
  p1, p2: TProc;
begin
  i := 42;
  p1 := procedure
        begin
              Writeln(i);
                  i := i * 2;
            end;
           
  p1(); // will print 42
  
  p2 := procedure
        begin
                  Writeln(i);
                end;
  
  p1(); // will print 84
  p2(); // will print 168
end;

The lifetime of managed types captured by anonymous function references will be handled accordingly (they will stay alive as long as at least one anonymous function that has captured them is alive as well), however special care needs to be taken regarding manual memory management:

Code: Pascal [Select][+]

type
  TProc = reference to procedure;
 
function Test: TProc;
var
  o: TObject;
begin
  o := TObject.Create;
  Result := procedure
            begin
                          Writeln(o.ClassName);
                        end;
  o.Free;
end;

Calling the function reference returned by Test will essentially result in use-after-free. And not freeing “o” at all will result in a memory leak.

Compatibility

The two features are by and large compatible to Delphi's Anonymous Methods. However FPC allows the assignment of anonymous functions to various function pointer types while Delphi restricts them to function references.
Also FPC handles the assignment of function, method and nested function variables to function variables slightly differently. Take the following code:

Code: Pascal [Select][+]

procedure Foo;
begin
  Writeln('Foo');
end;
 
procedure Bar;
begin
  Writeln('Bar');
end;
 
procedure Test;
var
  p: reference to procedure;
  p2: procedure;
begin
  p2 := Foo;
  p := p2;
  p();
  p2 := Bar;
  p();
end;

Delphi essentially generates the following:

Code: Pascal [Select][+]

procedure Test;
var
  p: reference to procedure;
  p2: procedure;
begin
  p2 := Foo;
  p := procedure
       begin
             p2();
           end;
  p();
  p2 := Bar;
  p();
end;

This will result in the following output:

Code: [Select]

Foo
Bar

However FPC will generate the following:

Code: Pascal [Select][+]

procedure Test;
var
  p: reference to procedure;
  p2, tmp: procedure;
begin
  p2 := Foo;
  tmp := p2;
  p := procedure
       begin
             tmp();
           end;
  p();
  p2 := Bar;
  p();
end;

This will result in the following output:

Code: [Select]

Foo
Foo

This is more consistent with assignments of other function pointer types to function pointer types.

The Function References feature is available on all platforms which have the Classes feature available (so essentially everything except AVR) and Anonymous Functions themselves are available on all platforms (excluding the assignment to function references on platforms where these are missing). Yes, this includes platform like DOS where directives like “far” and “near” are handled accordingly (which means that these need to be compatible as well when assigning).

As these two features are rather complicated there might still be a huge bundle of bugs lurking around so I ask you to test them to year heart's content and report found bugs to the issues on GitLab so that we can fix as many of them as possible before the next major version (which is not yet planned, so don't worry ;) ).

Further RTL enhancements like the declaration of TProc<> or the addition of a TThread.Queue() that takes a function reference will come in the near future now that the basics on the compiler side are done. Maybe we can now also tackle ports of libraries like Spring4D and OmniThreadLibrary. There's also the idea to introduce a syntax to control whether symbols are captured by-reference (as currently) or by-value.

Enjoy!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Okoba on May 26, 2022, 09:52:59 pm

Thank you so much to the team!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: marcov on May 26, 2022, 10:09:52 pm

Are the modeswitches already always on for $mode Delphi ?

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on May 26, 2022, 10:13:07 pm

Quote from: marcov on May 26, 2022, 10:09:52 pm

Are the modeswitches already always on for $mode Delphi ?

Not yet, I first want to spot any mature hurdles with more testers and then we can make them default before the next major release (though at least they shouldn't affect exisiting code except for the point I had mentioned in my announcement post regarding reference, so we can make them default sooner as well *shrugs*).

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: bytebites on May 27, 2022, 08:02:40 am

Oh, it happened in our lifetime. :D Thank you.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Thaddy on May 27, 2022, 01:20:11 pm

Nice toy! Well done you all.
Here's an old Barry Kelly smartpointer example for Delphi that now compiles in FPC:

Code: Pascal [Select][+]

{$ifdef windows}{$apptype console}{$endif}
{$mode delphi}{$modeswitch functionreferences}{$modeswitch anonymousfunctions}
{$warn 5036 off}
uses
  SysUtils;
 
type
  Tproc = reference to procedure;
  TLifetimeWatcher = class(TInterfacedObject)
  private
    FWhenDone: TProc;
  public
    constructor Create(const AWhenDone: TProc);
    destructor Destroy; override;
  end;
 
{ TLifetimeWatcher }
 
constructor TLifetimeWatcher.Create(const AWhenDone: TProc);
begin
  FWhenDone := AWhenDone;
end;
 
destructor TLifetimeWatcher.Destroy;
begin
  if Assigned(FWhenDone) then
    FWhenDone;
  inherited;
end;
 
type
  TSmartPointer<T: class> = record
  strict private
    FValue: T;
    FLifetime: IInterface;
  public
    constructor Create(const AValue: T); overload;
    class operator Implicit(const AValue: T): TSmartPointer<T>;
    property Value: T read FValue;
  end;
 
{ TSmartPointer<T> }
 
constructor TSmartPointer<T>.Create(const AValue: T);
begin
  FValue := AValue;
  FLifetime := TLifetimeWatcher.Create(procedure
  begin
    AValue.Free;
  end);
end;
 
class operator TSmartPointer<T>.Implicit(const AValue: T): TSmartPointer<T>;
begin
  Result := TSmartPointer<T>.Create(AValue);
end;
 
procedure UseIt;
var
  x: TSmartPointer<TLifetimeWatcher>;
begin
  x := TLifetimeWatcher.Create(procedure
  begin
    Writeln('I died.');
  end);
end;
 
begin
  try
    UseIt;
    Readln;
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: simone on May 27, 2022, 03:05:29 pm

Thanks to the development team. Will this new feature be available in the next release version of fpc?

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on May 27, 2022, 03:19:01 pm

Quote from: simone on May 27, 2022, 03:05:29 pm

Thanks to the development team. Will this new feature be available in the next release version of fpc?

It will be in the next major release which is not yet scheduled. The next release will be a minor release (namely 3.2.4).

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Bi0T1N on May 27, 2022, 09:09:59 pm

I'm glad to see that it has finally arrived in FPC - good work! This should allow us to use several nice Delphi libraries with FPC. 8-)
I think you can also close the issue (https://gitlab.com/freepascal.org/fpc/source/-/issues/24481) now.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Thaddy on May 27, 2022, 09:32:11 pm

Quote from: Bi0T1N on May 27, 2022, 09:09:59 pm

I'm glad to see that it has finally arrived in FPC - good work! This should allow us to use several nice Delphi libraries with FPC. 8-)
I think you can also close the issue (https://gitlab.com/freepascal.org/fpc/source/-/issues/24481) now.

Not only that: FPC can do more as per PascalDragon's introductary notes...
I have been toying with old D2009 and XE2 examples today and 90% can be made to work in minutes. Much more than I expected.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: edwinyzh on May 28, 2022, 05:44:29 am

Wonderful! Now all must-have syntax I want from FPC is available!
Thank all you guys!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: avk on May 28, 2022, 12:34:01 pm

This is really great news, many thanks to the FPC team!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Thaddy on May 28, 2022, 03:12:27 pm

If you want to experiment, you need the latest trunk.
These defines can help others as well:

Code: Pascal [Select][+]

{$ifdef windows}{$apptype console}{$endif}
{$mode delphi}{$modeswitch functionreferences}{$modeswitch anonymousfunctions}
{$warn 5036 off}// "Warning: (5036) Local variable "$Capturer" does not seem to be initialized"
 

The "warn 5036 off" is just to suppress a warning about the $capturer variable:
I suppose that will be fixed later? It does not really harm, but I sometimes like to compile with -Sew.
Everything else looks OK, except some advanced examples that use extended RTTI, but that is logical and described in the announcement. It just means that some frameworks do not work yet.
I have by now tested some 20+ examples from Delphi that do work and some homebrew.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on May 28, 2022, 06:24:23 pm

Quote from: Bi0T1N on May 27, 2022, 09:09:59 pm

I think you can also close the issue (https://gitlab.com/freepascal.org/fpc/source/-/issues/24481) now.

I wanted to look for that already. Thanks for finding it for me. :)

Quote from: Thaddy on May 27, 2022, 09:32:11 pm

Quote from: Bi0T1N on May 27, 2022, 09:09:59 pm
I'm glad to see that it has finally arrived in FPC - good work! This should allow us to use several nice Delphi libraries with FPC. 8-)
I think you can also close the issue (https://gitlab.com/freepascal.org/fpc/source/-/issues/24481) now.
Not only that: FPC can do more as per PascalDragon's introductary notes...
I have been toying with old D2009 and XE2 examples today and 90% can be made to work in minutes. Much more than I expected.

The other 10% would probably be interesting. At least if they don't rely on feature that we currently don't support (extended RTTI, some of the TValue functionality, etc.).

Quote from: Thaddy on May 28, 2022, 03:12:27 pm

These defines can help others as well:
Code: Pascal [Select][+][-]
{$ifdef windows}{$apptype console}{$endif}
{$mode delphi}{$modeswitch functionreferences}{$modeswitch anonymousfunctions}
{$warn 5036 off}// "Warning: (5036) Local variable "$Capturer" does not seem to be initialized"

The "warn 5036 off" is just to suppress a warning about the $capturer variable:
I suppose that will be fixed later? It does not really harm, but I sometimes like to compile with -Sew.

And why, pray tell, did you not report this? This is the first time I hear of this considering that I wrote a ton of tests... :o Do you have an example where this happens?

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Thaddy on May 28, 2022, 08:19:38 pm

Of course, Sarah. See my above Barry Kelly example and comment the warn 8-)
But a great achiviement.

The warnings are on:
testanon.pas(51,1) Warning: (5036) Local variable "$Capturer" does not seem to be initialized
And on line 61 the same.

"$Capturer" is not accessible for the normal user.
There is also a note, but I tend to ignore those.
For completeness: "testanon.pas(60,3) Note: (5027) Local variable "x" is assigned but never used" which is not true...

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: AFFRIZA 亜風実 on June 01, 2022, 07:56:54 am

Nice, can't wait to test that. :D

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 01, 2022, 08:54:39 am

Quote from: Thaddy on May 28, 2022, 08:19:38 pm

The warnings are on:
testanon.pas(51,1) Warning: (5036) Local variable "$Capturer" does not seem to be initialized
And on line 61 the same.

Can it be that you compile with -O3? (Cause there's another report about this, but without optimizations enabled I can't reproduce this)

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Thaddy on June 01, 2022, 10:41:24 am

I compiled with -O4 and win64. It should be reproducible in main. With -02 there is no warning.
On linux32/64 debian the warning is also there with -O4
Nothing important since the compiler is built with -Sew and -O2 and that gives no warnings.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 01, 2022, 01:37:30 pm

Quote from: Thaddy on June 01, 2022, 10:41:24 am

I compiled with -O4 and win64. It should be reproducible in main. With -02 there is no warning.
On linux32/64 debian the warning is also there with -O4

Then, next time, please also mention what settings you use to compile, cause that can make a significant difference.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: JdeHaan on June 17, 2022, 10:58:09 am

Hi, first of all, great to have this new functionality and using it already in several places in my code.

I have a small (for me unsolvable) issue, and was hoping to use the function references/anonymous functions to find a solution.
What is the problem? I’m trying to convert a C++ macro to a Pascal function:

#define MEM(allocator, …) (someFunctionCall(), allocator(__VA_ARGS__))

it is called as follows:

MEM(allocString, “Hello world”);
MEM(allocCell, value);
MEM(allocFunction, codeObject);

The result of the MEM call will be a ‘Value’ type.

so, the macro allows to call different functions with different arguments.

The functions are defined as:

Value allocString(std::String string)
Value allocCell(Value value)
Value allocFunction(CodeObject codeObject)

Any idea how to convert this to Object Pascal?

Regards,
Jeroen

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: marcov on June 17, 2022, 12:41:53 pm

I don't think this is possible. Except maybe with an external macro package like M4.

Macro shenanigans are simply intrinsicly unportable between languages as they operate on the text of the code.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 17, 2022, 01:24:53 pm

Quote from: JdeHaan on June 17, 2022, 10:58:09 am

Any idea how to convert this to Object Pascal?

Under the assumption that the allocators only take one argument you can do it like this (this requires main due to the implicit function specialization):

Code: Pascal [Select][+]

program ttest;
 
{$mode objfpc}{$H+}
{$modeswitch implicitfunctionspecialization}
 
type
  Value = record
  end;
 
  generic TAllocator<T> = function(const aArg: T): Value;
 
procedure SomeFunctionCall;
begin
 
end;
 
generic function MEM<T>(allocator: specialize TAllocator<T>; const aValue: T): Value; inline;
begin
  SomeFunctionCall;
  Result := allocator(aValue);
end;
 
function AllocString(const aStr: String): Value;
begin
end;
 
function AllocCell(const aCell: Value): Value;
begin
end;
 
function AllocFunction(const aCodeObject: CodePointer): Value;
begin
end;
 
var
  v: Value;
begin
  v := MEM(@AllocString, 'Hello World');
  v := MEM(@AllocCell, v);
  v := MEM(@AllocFunction, CodePointer(@SomeFunctionCall));
end.

At least assuming I understood correctly what you're trying to do...

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: JdeHaan on June 17, 2022, 02:11:59 pm

Yes, that's pretty much what I need, thanks, I'll give it a try!
So, nothing to do with function references, as mentioned in the new feature...

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Pascal Gladiator on June 19, 2022, 05:56:58 am

Quote

Under the assumption that the allocators only take one argument you can do it like this (this requires main due to the implicit function specialization):

Firstly I just joined the forum and I couldn't figure out how to reply by quoting selected text. Is this possible?

I just actually posted this exact same question on the FPC mail list before I saw this post. So it works with only one argument but why are arguments not allowed? The type is an undefined generic so it should work in theory and only consider the parameters when the function is specialize

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 19, 2022, 01:12:13 pm

Quote from: Pascal Gladiator on June 19, 2022, 05:56:58 am

Quote
Under the assumption that the allocators only take one argument you can do it like this (this requires main due to the implicit function specialization):

Firstly I just joined the forum and I couldn't figure out how to reply by quoting selected text. Is this possible?

You just did?

Quote from: Pascal Gladiator on June 19, 2022, 05:56:58 am

I just actually posted this exact same question on the FPC mail list before I saw this post. So it works with only one argument but why are arguments not allowed? The type is an undefined generic so it should work in theory and only consider the parameters when the function is specialize

It's possible for more arguments as well, but it means that you need to add overloads of MEM that uses different types of function variables. E.g. like this:

Code: Pascal [Select][+]

type
  generic TAllocator1<T1> = function(const aArg1: T1): Value;
  generic TAllocator2<T2> = function(const aArg1: T1; const aArg2: T2): Value;
 
generic function MEM<T1>(allocator: specialize TAllocator1<T1>; const aValue1: T1): Value; inline;
generic function MEM<T1, T2>(allocator: specialize TAllocator2<T1, T2>; const aValue1: T1; const aValue2: T2): Value; inline;

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Pascal Gladiator on June 20, 2022, 04:47:23 am

For quoted reply I could copy and pasted but notice how it doesn't say who the quote was from. I expected to select some text and then hover the mouse over it and have an option to quote the selection. Pressing the quote button quotes the entire message which I think need to edit by hand.

The question was more about the undefined type and adding parameters like:

Code: Pascal [Select][+]

generic procedure Perform<T>(func: T);
begin
func(1);
end;

I replied and CC'd you on the mail list also since we're both having problems getting messages. I'm using a gmail account btw because my private domain was blocked (Jonas discovered this some years ago) but I think that's our problem. Other users reported this also so maybe Gmail is the culprit for them also.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 20, 2022, 01:36:24 pm

Quote from: Pascal Gladiator on June 20, 2022, 04:47:23 am

For quoted reply I could copy and pasted but notice how it doesn't say who the quote was from. I expected to select some text and then hover the mouse over it and have an option to quote the selection. Pressing the quote button quotes the entire message which I think need to edit by hand.

Correct. You quote whole and then edit by hand.

Quote from: Pascal Gladiator on June 20, 2022, 04:47:23 am

The question was more about the undefined type and adding parameters like:

Code: Pascal [Select][+][-]
generic procedure Perform<T>(func: T);
begin
func(1);
end;

Then you should have mentioned that in the first place, cause I thought you were referring to what I had written to JdeHaan.

Quote from: Pascal Gladiator on June 20, 2022, 04:47:23 am

I replied and CC'd you on the mail list also since we're both having problems getting messages. I'm using a gmail account btw because my private domain was blocked (Jonas discovered this some years ago) but I think that's our problem. Other users reported this also so maybe Gmail is the culprit for them also.

It has something to do with SPF records and the domain we send e-mails from. We're already trying to solve this, but as documentation is a bit sparse it's a bit hit-and-miss.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: JdeHaan on June 21, 2022, 10:16:04 pm

Again thank you PascalDragon for the examples. I did need 1 or 2 arguments. Above that I needed it to be part of an advanced record. The following code runs now perfectly:

Code: Pascal [Select][+]

{$mode objfpc}{$H+}
{$ModeSwitch advancedrecords}
{$ModeSwitch implicitfunctionspecialization}
 
type
  generic TAllocator1<T1> = function(const aArg1: T1): TValue;
  generic TAllocator2<T1, T2> = function(const aArg1: T1; const aArg2: T2): TValue;
 
  TMyRec = record
    procedure someProc;
    generic function MEM<T1>(allocator: specialize TAllocator1<T1>; 
      const aValue1: T1): TValue;
    generic function MEM<T1, T2>(allocator: specialize TAllocator2<T1, T2>; 
      const aValue1: T1; const aValue2: T2): TValue;
  end;
 
implementation
 
generic function TMyRec.MEM<T1>(allocator: specialize TAllocator1<T1>; 
  const aValue1: T1): TValue; 
begin
  someProc;
  Result := allocator(aValue1);
end;
 
generic function TMyRec.MEM<T1, T2>(allocator: specialize TAllocator2<T1, T2>; 
  const aValue1: T1; const aValue2: T2): TValue;
begin
  someProc;
  Result := allocator(aValue1, aValue2);
end;
 

and then calling the respective MEM functions with 1 or 2 arguments from other functions in the record:

Code: Pascal [Select][+]

Result := MEM(@allocString, 'Hello world!');
Result := MEM(@allocCell, Value);
 
Result := MEM(@allocFunction, Name, Arity);
 

Really nice feature!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on June 22, 2022, 09:01:59 am

Quote from: JdeHaan on June 21, 2022, 10:16:04 pm

Really nice feature!

You're welcome.

Please note that you need the ImplicitFunctionSpecialization modeswitch only in the unit where you call MEM, not where you declare it (I know you said that you call MEM from other methods of the same record, so for your real code this doesn't apply, but I just wanted to be sure that you're aware of this).

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: JdeHaan on June 22, 2022, 12:25:09 pm

Noted, thanks!

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: VTwin on July 08, 2022, 02:02:16 am

Please forgive my ignorance, but how are function references superior to

Code: Pascal [Select][+]

type
  TPoint = record
    X : double;
    Y : double;
  end;
  TDistanceFunc = function(p, q: TPoint): double;

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: y.ivanov on July 08, 2022, 02:44:10 pm

Quote from: VTwin on July 08, 2022, 02:02:16 am

Please forgive my ignorance, but how are function references superior to

Code: Pascal [Select][+][-]
type
TPoint = record
X : double;
Y : double;
end;
TDistanceFunc = function(p, q: TPoint): double;

It has something to do with the variable binding (https://docwiki.embarcadero.com/RADStudio/Sydney/en/Anonymous_Methods_in_Delphi#Variable_Binding) I believe.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: PascalDragon on July 08, 2022, 05:43:56 pm

Quote from: VTwin on July 08, 2022, 02:02:16 am

Please forgive my ignorance, but how are function references superior to

Code: Pascal [Select][+][-]
type
TPoint = record
X : double;
Y : double;
end;
TDistanceFunc = function(p, q: TPoint): double;

Function references can take additional context. Assume that TDistanceFunc is declared as a reference to function instead of a function and you can do the following (stupid example):

Code: Pascal [Select][+]

function OffsetBy(const aPoint: TPoint): TDistanceFunc;
begin
  Result := function(aArg1, aArg2): Double;
    var
      v: TPoint;
    begin
      v.x := aArg1.X - aArg2.X + aPoint.X;
      v.y := aArg1.Y - aArg2.Y + aPoint.Y;
    
      Result := Sqrt(Sqr(v.x) + Sqr(v.y)); 
    end;
end;
 
var
  f: TDistanceFunc;
begin
  f := OffsetBy(Point(10, 20));
  Writeln(f(Point(5, 3), Point(6, 8));
  f := OffsetBy(Point(5, -1));
  Writeln(f(Point(5, 3), Point(6, 8));
end.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: y.ivanov on July 08, 2022, 06:36:07 pm

@VTwin
Function references encapsulates the function together with it's lexical context (at least - part of) which is also knows as a "closure" (C#, C++). May be the most familiar example in FPC is the method delegate (procedure of object), which keeps together the method address and the Self pointer of the instance it belongs. Thus, the receiver object can execute the method in the context of the original object.

Function references just broadens the context by being able to keep it bigger - including variables from the current scope, etc.

But the devil is into the details, and I wonder how useful it will be in practice considering the dynamic nature of the class instances in FPC.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: VTwin on July 08, 2022, 06:54:39 pm

Thanks!

I appreciate the example PascalDragon.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Warfley on July 08, 2022, 08:35:41 pm

To give a more practical example about this, with such a feature you can generalize partial function application which can be used to specialize functions:

Code: Pascal [Select][+]

program Project1;
 
{$mode objfpc}{$H+}
{$modeswitch functionreferences}
{$modeswitch anonymousfunctions}
uses
  SysUtils;
 
type
  generic TBinaryProcedure<TParam1, TParam2> = reference to procedure(const A: TParam1; const B: TParam2);
  generic TUnaryProcedure<TParam1> = reference to procedure(const A: TParam1);
 
generic function Partial<TParam1, TParam2>(Func: specialize TBinaryProcedure<TParam1, TParam2>; const AValue: TParam1): specialize TUnaryProcedure<TParam2>;
begin
  Result := procedure(const AParam: TParam2)
            begin
              Func(AValue, AParam);
            end;
end;
 
procedure LogToFile(const AFile: THandle; const AMessage: String);
var
  LogMessage: String;
begin
  LogMessage := '[%s] %s%s'.Format([DateTimeToStr(Now), AMessage, LineEnding]);
  FileWrite(AFile, LogMessage[1], LogMessage.Length);
end;
 
var
  Log: specialize TUnaryProcedure<String>;
  fl: THandle;
begin
  // Log to consone out
  Log := specialize Partial<THandle, String>(@LogToFile, StdOutputHandle);
  Log('Console Log');
  // Log to console error
  Log := specialize Partial<THandle, String>(@LogToFile, StdErrorHandle);
  Log('Error Log');
  // Log to file
  fl := FileOpen('log.txt', fmOpenWrite);
  Log := specialize Partial<THandle, String>(@LogToFile, fl);
  Log('File Log');
  ReadLn;
end.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: y.ivanov on July 09, 2022, 07:17:27 pm

Quote from: Warfley on July 08, 2022, 08:35:41 pm

To give a more practical example about this, with such a feature you can generalize partial function application which can be used to specialize functions:
Code: Pascal [Select][+][-]
program Project1;

{$mode objfpc}{$H+}
{$modeswitch functionreferences}
{$modeswitch anonymousfunctions}
uses
SysUtils;

type
generic TBinaryProcedure<TParam1, TParam2> = reference to procedure(const A: TParam1; const B: TParam2);
generic TUnaryProcedure<TParam1> = reference to procedure(const A: TParam1);

generic function Partial<TParam1, TParam2>(Func: specialize TBinaryProcedure<TParam1, TParam2>; const AValue: TParam1): specialize TUnaryProcedure<TParam2>;
begin
Result := procedure(const AParam: TParam2)
begin
Func(AValue, AParam);
end;
end;

procedure LogToFile(const AFile: THandle; const AMessage: String);
var
LogMessage: String;
begin
LogMessage := '[%s] %s%s'.Format([DateTimeToStr(Now), AMessage, LineEnding]);
FileWrite(AFile, LogMessage[1], LogMessage.Length);
end;

var
Log: specialize TUnaryProcedure<String>;
fl: THandle;
begin
// Log to consone out
Log := specialize Partial<THandle, String>(@LogToFile, StdOutputHandle);
Log('Console Log');
// Log to console error
Log := specialize Partial<THandle, String>(@LogToFile, StdErrorHandle);
Log('Error Log');
// Log to file
fl := FileOpen('log.txt', fmOpenWrite);
Log := specialize Partial<THandle, String>(@LogToFile, fl);
Log('File Log');
ReadLn;
end.

Weird.

I suppose that is the result of the effort for achieving a partial specialization overcoming limitation of the current generics in FPC, considering this (https://forum.lazarus.freepascal.org/index.php/topic,45818.msg325801.html#msg325801) and this (https://forum.lazarus.freepascal.org/index.php/topic,58753.0.html).

I'd use a generic advanced record for that particular case, just to keep the context (the handle) and to be of managed type. The latter is also not mandatory if you have at hand something like TAuto (https://forum.lazarus.freepascal.org/index.php/topic,46306.0.html).

I'm a big fan of the functional programming too and I'm seeing the anonymous functions handy for map/fold/filter on containers and also for async/await futures (combined with a STAX?) but I'm not so sure for the function references.

Maybe they're good for replacing the current method delegates, but that would break the LCL backward compatibility, i.e. it would not happen.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Warfley on July 09, 2022, 10:34:30 pm

Quote from: y.ivanov on July 09, 2022, 07:17:27 pm

Weird.

I suppose that is the result of the effort for achieving a partial specialization overcoming limitation of the current generics in FPC, considering this (https://forum.lazarus.freepascal.org/index.php/topic,45818.msg325801.html#msg325801) and this (https://forum.lazarus.freepascal.org/index.php/topic,58753.0.html).

This is the partial application pattern, that is used in function programming languages (https://wiki.haskell.org/Partial_application). You can see it as a generalization of OOP methods.
Take for example this

Code: Pascal [Select][+]

TTest = class
  public procedure Foo (A: Integer);
end;
 
procedure TTest.Foo(A: Integer);
...
 
// method pointer
var
  MethodPtr: reference to procedure(A: Integer);
begin
  MethodPtr := @MyTest.Foo;
 

The Foo method is then just a function that takes a hidden Self parameter, and the taking of the pointer to that function can be thought of creating a new function that fixes the first parameter to the value MyTest.
So this is generally the same as:

Code: Pascal [Select][+]

procedure TTestFoo(Self: TTest; A: Integer);
 
var
  MethodPtr: reference to procedure(A: Integer);
begin
  MethodPtr := procedure(A: Integer) begin TTestFoo(MyTest, A) end;

The function partial just abstracts this process and might some day with implicit specialization work as easy as simply writing:

Code: Pascal [Select][+]

  MethodPtr := Partial(@TTestFoo, MyTest);

So this is basically the generalization of OOP methods. And as such it allows to give really powerfull tools, because OOP methods are bound to classes (or objects) and inheritance. With partial application, the same principle can be extended to any type and any number of parameters. The example above, makes use of the polymorphism inherent in filehandles, to create one instance for each type, similar to inheriting from one base class multiple times, just for a single function (of course, such sets of functions could be combined, e.g. in a record, which would basically emulate classes and virtual methods).

Together with generics, where as you stated this could be used as partial specialization, the same function could be used to be specialized for different types, where only the interface of the type must be the same. This allows to write basically inheritance like methods but for any types that do not need to be related (or even classes at all), as long as they either have a common interface (like a shared method) or there exist common overloaded functions for this type.

If you go completely mad you could even completely emulate OOP with it:

Code: Pascal [Select][+]

program Project1;
 
{$mode objfpc}{$H+}
{$ModeSwitch anonymousfunctions}
{$ModeSwitch functionreferences}
{$ModeSwitch nestedprocvars}
 
uses
  SysUtils;
 
type
  TLogFunction = reference to procedure(const AMessage: String);
  TLogLevel = (llDebug=0, llWarning, llError, llNone);
 
  TLogger = record      
    Debug: TLogFunction;
    Warning: TLogFunction;
    Error: TLogFunction;
  end;
 
function CreateLogger(AFile: THandle; LogLevel: TLogLevel): TLogger;
 
  procedure NoLog(const AMessage: String);
  begin end;
 
  procedure LogMessage(const Prefix: String; const AMessage: String);
  var
    LogMessage: String;
  begin
    LogMessage := '%s: [%s] %s%s'.Format([Prefix, DateTimeToStr(Now), AMessage, LineEnding]);
    FileWrite(AFile, LogMessage[1], LogMessage.Length);
  end;
 
begin
  if LogLevel <= llDebug then
    Result.Debug := procedure(const AMessage: String) begin LogMessage('DEBUG', AMessage) end
  else
    Result.Debug := @NoLog;
 
  if LogLevel <= llWarning then
    Result.Warning := procedure(const AMessage: String) begin LogMessage('WARNING', AMessage) end
  else
    Result.Warning := @NoLog;     
 
  if LogLevel <= llError then
    Result.Error := procedure(const AMessage: String) begin LogMessage('ERROR', AMessage) end
  else
    Result.Error := @NoLog;
end;
 
function ConsoleLogger(LogLevel: TLogLevel): TLogger;
begin
  Result := CreateLogger(StdOutputHandle, LogLevel);
end;  
 
function ErrorLogger(LogLevel: TLogLevel): TLogger;
begin
  Result := CreateLogger(StdErrorHandle, LogLevel);
end;
 
var
  Logger: TLogger;
begin
  Logger := ConsoleLogger(llDebug);
  Logger.Debug('Debug Test');
  Logger.Warning('Warning Test');
  Logger.Error('Error Test');
 
  Logger := ErrorLogger(llError);
  Logger.Debug('Debug Test');
  Logger.Warning('Warning Test');
  Logger.Error('Error Test');
  ReadLn;
end.

This has a really interesting property, that is that all the logging functions make use of the Handle, so it is like a private field in a class, but because it is a paramter, as soon as it goes out of scope, you can't access it from outside. It's basically the "purest" form of a private identifier, one that doesn't exist after the declaration.

Aside from that, what I find really interesting about this approach, this is possible with only very few lines of code (basically the whole logger core type, which would be some form of abstract class in OOP, is with all function definitions just 40 lines of code). OOP introduces a lot of boilerplate code. This on the other hand is very slim. So I could imagine using this for some rather small things, where previously I would have used classes with just 1 or 2 (virtual/overriden) functions

Quote

I'm a big fan of the functional programming too and I'm seeing the anonymous functions handy for map/fold/filter on containers and also for async/await futures (combined with a STAX?) but I'm not so sure for the function references.

Maybe they're good for replacing the current method delegates, but that would break the LCL backward compatibility, i.e. it would not happen.

Function references have a huge andvantage. So I am writing a lot of code that makes use of function pointers, for example STAX, but also my iterators library (https://github.com/Warfley/ObjPasUtils/tree/master/src/iterators), and because I don't want to restrict the user to only one kind of function pointer, I need to define everything multiple times. Look at my functypes unit (https://github.com/Warfley/ObjPasUtils/blob/master/src/functypes/functypes.pas):

Code: Pascal [Select][+]

  generic TFunction<TResult> = function(): TResult;
  generic TFunctionMethod<TResult> = function(): TResult of object;
  generic TFunctionNested<TResult> = function(): TResult is nested;
 
  generic TAnyFunction<TResult> = record
  public type
    TMyType = specialize TAnyFunction<TResult>;
    TMyFunction = specialize TFunction<TResult>;
    TMyFunctionMethod = specialize TFunctionMethod<TResult>;
    TMyFunctionNested = specialize TFunctionNested<TResult>;
 
  public
    class operator :=(AFunc: TMyFunction): TMyType; inline; overload;
    class operator :=(AFunc: TMyFunctionMethod): TMyType; inline; overload;
    class operator :=(AFunc: TMyFunctionNested): TMyType; inline; overload;
 
  public
    function apply(): TResult; inline;
 
  private
    case FunctionType: TFunctionType of
      ftFunction: (FFunction: TMyFunction);
      ftFunctionMethod: (FFunctionMethod: TMyFunctionMethod);
      ftFunctionNested: (FFunctionNested: TMyFunctionNested);
  end;
 
class operator TAnyFunction.:=(AFunc: TMyFunction): TMyType;
begin
  Result.FunctionType := ftFunction;
  Result.FFunction := AFunc;
end;
 
class operator TAnyFunction.:=(AFunc: TMyFunctionMethod): TMyType;
begin
  Result.FunctionType := ftFunctionMethod;
  Result.FFunctionMethod := AFunc;
end;
 
class operator TAnyFunction.:=(AFunc: TMyFunctionNested): TMyType;
begin
  Result.FunctionType := ftFunctionNested;
  Result.FFunctionNested := AFunc;
end;
 
function TAnyFunction.apply(): TResult;
begin
  case FunctionType of
  ftFunction: Result := FFunction();
  ftFunctionMethod: Result := FFunctionMethod();
  ftFunctionNested: Result := FFunctionNested();
  end;
end;

60 lines or so, just to basically implement something that behaves as function references (just worse, because implicit specializations don't work transitively through implicit casts). And I have this for all kinds of functions and procedures from 0 to 5 parameters, It's 600 lines of code, just to emulate what is now provided at language level (and better).
Function references are a huge update, personally I feel they are a bigger upgrade than anonymous functions (as these where previously also possible using nested procedures).

And somewhen in the future I will update both STAX and ObjPasUtils for the new features, this is going to give it a huge upgrade in usability

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: y.ivanov on July 10, 2022, 12:45:56 pm

Quote from: Warfley on July 09, 2022, 10:34:30 pm

Quote from: y.ivanov on July 09, 2022, 07:17:27 pm
Weird.

I suppose that is the result of the effort for achieving a partial specialization overcoming limitation of the current generics in FPC, considering this (https://forum.lazarus.freepascal.org/index.php/topic,45818.msg325801.html#msg325801) and this (https://forum.lazarus.freepascal.org/index.php/topic,58753.0.html).
This is the partial application pattern, that is used in function programming languages (https://wiki.haskell.org/Partial_application).
*snip*

I see. Not familiar with Haskell but with the scheme language (https://en.wikipedia.org/wiki/Scheme_(programming_language)) where the same pattern is used to its fullest.

Quote from: Warfley on July 09, 2022, 10:34:30 pm

*snip*
So this is basically the generalization of OOP methods. And as such it allows to give really powerfull tools, because OOP methods are bound to classes (or objects) and inheritance. With partial application, the same principle can be extended to any type and any number of parameters.
*snip*

I don't see it as a generalization but as an alternative way to bind code to a context. I'll admit that in the latter you'll have an internally managed context, yes.

Quote from: Warfley on July 09, 2022, 10:34:30 pm

*snip*

Aside from that, what I find really interesting about this approach, this is possible with only very few lines of code (basically the whole logger core type, which would be some form of abstract class in OOP, is with all function definitions just 40 lines of code). OOP introduces a lot of boilerplate code. This on the other hand is very slim. So I could imagine using this for some rather small things, where previously I would have used classes with just 1 or 2 (virtual/overriden) functions

Quote
I'm a big fan of the functional programming too and I'm seeing the anonymous functions handy for map/fold/filter on containers and also for async/await futures (combined with a STAX?) but I'm not so sure for the function references.

Maybe they're good for replacing the current method delegates, but that would break the LCL backward compatibility, i.e. it would not happen.
Function references have a huge andvantage. So I am writing a lot of code that makes use of function pointers, for example STAX, but also my iterators library (https://github.com/Warfley/ObjPasUtils/tree/master/src/iterators), and because I don't want to restrict the user to only one kind of function pointer, I need to define everything multiple times. Look at my functypes unit (https://github.com/Warfley/ObjPasUtils/blob/master/src/functypes/functypes.pas):
*snip*
*snip*
60 lines or so, just to basically implement something that behaves as function references (just worse, because implicit specializations don't work transitively through implicit casts). And I have this for all kinds of functions and procedures from 0 to 5 parameters, It's 600 lines of code, just to emulate what is now provided at language level (and better).
*snip*

It reminds me of similar efforts in another language before the variadic templates were added.

Anyway, it doesn't look any less weird to me.

IMHO Such an undertaking to approximate a Pascal so close to a functional language is a bit too much. But it is not that I don't appreciate it from the academic point of view.

Title: Re: Feature announcement: Function References and Anonymous Functions
Post by: Warfley on July 10, 2022, 04:20:20 pm

Quote from: y.ivanov on July 10, 2022, 12:45:56 pm

IMHO Such an undertaking to approximate a Pascal so close to a functional language is a bit too much. But it is not that I don't appreciate it from the academic point of view.

I think that it is not necessarily trying to approximate pascal to a functional language, I think this is neither wise nor actually that possible (especially as the core concepts of functional languages, algebraic type system, fully expression based programs and side effect free programming, are something that must be supported on the very core of the language).
That said, there are some concepts that are helpful in a cross paradigm way, e.g. most of the work in my ObjPasUtils is actually just creating such iterator functionality like map, filter, etc. for abritrary types, which I think is something that would be really helpful (there are libraries like LGenerics that provide these functions for their own types, but what I try to build is something that can be applied accross types to work with everything from arrays over TList to any custom class).
This at it's core is not really functional programming (java has it for goodness sake, and I think you don't get further away from functional programming than with java), just because it uses function pointers. It's just something that will now be much easier.

That said, there are also a lot of more academic, the OOP emulation shown above, is basically the concept of prototype based OOP as used in Javascript or Python, and I think can be really helpful in some scenarios (but is not a cureal for every use-case, I think this gets unreadable if the size of the class is larger than 1-2 functions). So how useful this will be is to be shown.
And then there are other things like implementing monads, which could be very interesting from an academic point of view, but will be stretching the language probably to a breaking point (I want to see if I can basically create something like the monadic chaining operator for OOP, where where you could write something like csv := Chain(TStringList.Add, TStringList.Add, TStringList.SetDelimiter, TStringList.GetDelimitedText)(TStringList.Create, 'Item1', 'Item2', ',').

But I like to think that at least the stuff already implemented in ObjPasUtils is useful and not just an academic exercise.

Lazarus

Announcements => Free Pascal => Topic started by: PascalDragon on May 26, 2022, 09:47:14 pm