Print Page - [SOLVED] Any way to Exit a control when form is clicked?

Programming => LCL => Topic started by: egsuh on October 05, 2020, 08:49:16 am

Title: [SOLVED] Any way to Exit a control when form is clicked?
Post by: egsuh on October 05, 2020, 08:49:16 am

Let's assume that I have a TMEMO in a form. When I click the TMemo, TMemo.OnEnter is called. But OnExit is not called when I click on the vacant area of the form which contains the TMemo. OnExit is called when I click on another control in the same form.

Is there anyway that I can make the OnExit event handler is called when I click on the form?

Title: Re: Any way to Exit a control when form is clicked?
Post by: Handoko on October 05, 2020, 09:11:43 am

OnExit is only triggered when it's losing focus. Clicking the form does not make the Memo to lose focus. Clicking other control (on the same form) will make that control to receive focus and that will send a signal to the Memo to trigger the OnExit.

Can you explain more detail why you need to trigger the event when user click the form?

-edit-
You can make form click to trigger Memo.OnExit. Try this code:

Code: Pascal [Select][+]

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, Forms, Controls, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormClick(Sender: TObject);
    procedure Memo1Exit(Sender: TObject);
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.Memo1Exit(Sender: TObject);
begin
  Caption := Random(100).ToString;
end;
 
procedure TForm1.FormClick(Sender: TObject);
begin
  Memo1Exit(Self);
end;
 
end.

Title: Re: Any way to Exit a control when form is clicked?
Post by: lucamar on October 05, 2020, 09:23:48 am

Add a handler for the form's OnClick event which does this:

Code: Pascal [Select][+]

procedure TForm1.FormClick(Sender: TObject);
begin
  if Memo.Focused then Memo.PerformTab(True); { Or False to go backwards }
end;

It will move the focus away from the memo and trigger its OnExit event. Note that for it to work there must be some other focusable control in the form, say, a button or alike; otherwise PerformTab will do nothing.

Title: Re: Any way to Exit a control when form is clicked?
Post by: egsuh on October 05, 2020, 09:57:58 am

Quote

Can you explain more detail why you need to trigger the event when user click the form?

What I need is to store the content of controls whenever it is changed. I'm looking for the most secure way. Practically exiting control may happen in many cases .. by directly entering into another control, clicking on a form, closing the form by clickicking on the small x button, or closing form by pressing Alt-F4, etc. Just want to know any event that will be called everytime.

Title: Re: Any way to Exit a control when form is clicked?
Post by: howardpc on October 05, 2020, 10:22:56 am

You could maybe harness your controls' OnEditingDone event.

Title: Re: Any way to Exit a control when form is clicked?
Post by: egsuh on October 05, 2020, 11:44:13 am

Quote

You could maybe harness your controls' OnEditingDone event.

Nothing is 100% reliable. I'll search for other methods.

Title: Re: Any way to Exit a control when form is clicked?
Post by: Sieben on October 05, 2020, 12:14:20 pm

Very often you will have to watch more than a single event to cover all situations. But in most cases you need to write just one handler since most of them are simple TNotifyEvents. Stop searching for THE EVENT...

Title: Re: Any way to Exit a control when form is clicked?
Post by: BrunoK on October 05, 2020, 01:58:09 pm

Code: Pascal [Select][+]

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Memo1: TMemo;
    procedure FormClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure Memo1Enter(Sender: TObject);
    procedure Memo1Exit(Sender: TObject);
  private
    FDummyWinC: TWinControl;
    procedure DummyWinCEnter(Sender: TObject);
  public
 
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.FormShow(Sender: TObject);
begin
  if not Assigned(FDummyWinC) then begin
    FDummyWinC := TWinControl.Create(Self);
    FDummyWinC.Parent := Self;
    FDummyWinC.SetBounds(0,0,0,0);
    FDummyWinC.OnEnter:=@DummyWinCEnter;
 
    { If it has to respond to TAB, include next 2 lines }
    FDummyWinC.TabStop := true;
    FDummyWinC.TabOrder:=Memo1.TabOrder+1;
  end;
end;
 
procedure TForm1.FormClick(Sender: TObject);
begin
  FDummyWinC.SetFocus;
end;
 
procedure TForm1.Memo1Enter(Sender: TObject);
begin
  Memo1.Lines.Add('Entered:'+FormatDateTime('hh:nn:ss',now));
end;
 
procedure TForm1.Memo1Exit(Sender: TObject);
begin
  Memo1.Lines.Add('Exited:'+FormatDateTime('hh:nn:ss',now));
end;
 
procedure TForm1.DummyWinCEnter(Sender: TObject);
begin
  FDummyWinC.PerformTab(True); // Tab to next control
end;
 
end.

Title: Re: Any way to Exit a control when form is clicked?
Post by: lucamar on October 05, 2020, 04:42:35 pm

Quote from: BrunoK on October 05, 2020, 01:58:09 pm

Code: Pascal [Select][+][-]
procedure TForm1.DummyWinCEnter(Sender: TObject);
begin
FDummyWinC.PerformTab(True); // Tab to next control
end;

If you're going to do that you might just as well do it as I wrote before, making the memo do PerformTab(). You simply introduced a "phantom" control in the "focus" chain and doing it this way you might accidentally find yourself "tabing" back to the memo, depending on the controls's tab order. And it also complicates the program unneccesarily.

Title: Re: Any way to Exit a control when form is clicked?
Post by: BrunoK on October 05, 2020, 06:08:21 pm

Quote from: lucamar on October 05, 2020, 04:42:35 pm

If you're going to do that you might just as well do it as I wrote before, making the memo do PerformTab(). You simply introduced a "phantom" control in the "focus" chain and doing it this way you might accidentally find yourself "tabing" back to the memo, depending on the controls's tab order. And it also complicates the program unneccesarily.

Tested on Win10 :
If the only control on the form is the Memo then MemoExit is not called.

Title: Re: Any way to Exit a control when form is clicked?
Post by: wp on October 05, 2020, 06:32:47 pm

I think it is not a very user-friendly concept to change the focus when a click on the form occurs, this is against all conventions and the users will become very frustrated.

Title: Re: Any way to Exit a control when form is clicked?
Post by: lucamar on October 05, 2020, 07:13:45 pm

Quote from: BrunoK on October 05, 2020, 06:08:21 pm

Tested on Win10 :
If the only control on the form is the Memo then MemoExit is not called.

Yes, I said that too but, frankly, if the memo is the only control and all that is needed is to trigger its OnExit event one might as well call the handler directly from the form's OnClick one.

In fact, from the OP's description:

Quote from: egsuh on October 05, 2020, 09:57:58 am

What I need is to store the content of controls whenever it is changed. I'm looking for the most secure way. Practically exiting control may happen in many cases .. by directly entering into another control, clicking on a form, closing the form by clickicking on the small x button, or closing form by pressing Alt-F4, etc. Just want to know any event that will be called everytime.

what I would do is to add a "SaveMemo" method to the form and call from whatever event(s) it should be called or, anyway, from the form's OnCloseQuery handler, when you know the contents are finally fixed.

I have got a program, kind of a "notes to self/things to remember" pad, which needs to do something similar and one of the options I looked into for an "auto-save" feature was to intercept the <Enter> key (in the memo's OnKeyUp event) and save the contents then, but I finally realized it was a futile exercise and what I did was to use a TXMLPropStorage to store some session properties and to save/load the memo contents using its events. After a few false starts (first time I ever used that component) all was a piece of cake compared to, say, dealing with the shortcomings of TMemo ;D

Title: Re: Any way to Exit a control when form is clicked?
Post by: Handoko on October 05, 2020, 07:33:29 pm

If the OP's intention is to save the user provided values to disk, I think it should not be performed if user simply clicks on the form.

When providing value on a textbox or memo I might clicking the form several times but that does not mean I already finish with that item. For example, after typing some text, I forget and need to do some copy/paste something from other applications. That could be a web browser, help file or my personal-saved text files. And I always have multiple applications running and showing on my screen. So I may need to click on the form to bring the application to the front, move the form a better location on the screen, the go back and continue providing the value for the textbox.

Title: Re: Any way to Exit a control when form is clicked?
Post by: egsuh on October 09, 2020, 04:10:39 pm

I found this issue was discussed in StackOverflow, and found that simplest way is to write

Self.ActiveControl := nil;

which will call the OnExit procedure of focused control. I tested this, and reliable --- this calls OnExit event of focused control when I press other tab, or close the Windows by clicking F4 or samll x of the window (on Windows 10).

But I cannot do this in Frame. There are no ActiveControl in Frame. Is there any work-around?

Title: Re: Any way to Exit a control when form is clicked?
Post by: howardpc on October 09, 2020, 05:31:36 pm

ActiveControl is a TCustomForm property.
So you could try

Code: Pascal [Select][+]

ParentForm.ActiveControl := Nil;

Title: Re: Any way to Exit a control when form is clicked?
Post by: Sieben on October 09, 2020, 07:01:02 pm

But again - why? OnExit is triggered when the control is left for whatever reason, and for closing form there is this wonderful event OnCloseQuery where you can even stop the whole thing if something goes wrong, ask the user if she/he really means to leave, if he/she wants to save or not and so on... why not do it the way lucamar suggested...?

Title: Re: Any way to Exit a control when form is clicked?
Post by: marcio2003 on October 09, 2020, 08:01:23 pm

Code: Pascal [Select][+]

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Form1.FocusControl( nil );
end;

Windows 10 64bit - Lazarus v2.0.6

Title: Re: Any way to Exit a control when form is clicked?
Post by: egsuh on October 10, 2020, 12:45:09 am

I'm not sure addressing this issue again is valuable enough, but I'd like to share my idea and experiements with others.

First of all, I appreciate all the comments and commenters.

My baseline purpose is the content in the controls are saved to a field in object, like

Code: Pascal [Select][+]

type
     TMyObject = class
     published
          Name,
          Address : string; 
          OtherInfo: TStringList; 
 
          // methods
     end; 
 
     TMyFrame = class (TFrame)
           edit1 : TTIEdit;   // name
           edit2 : TTIEdit;   // address
           OtherInfoEdit : TValueListEditor; 
  
           // methods
      private
           FMyObject : TMyObject;
           procedure setMyObject(AValue: TMyObject); 
      public
            property MyObject : TMyObject read FMyObject write setMyObject; 
   
      end; 
 
implementation 
 
procedure TMyFrame.setMyObject(AValue: TMyObject);
begin
    if AValue <> nil then begin  
        FMyObject := AValue; 
        OtherInfoEdit.Strings.Text := FMyObject.OtherInfo.Text;    // initialize the content of valuelist editor
    end; 
end;  
 
 

I do not assign any saving procedure myself for RTTI controls. But I have to write them for general controls, TValueListEditor here. So,

Code: Pascal [Select][+]

procedure TMyFrame.OtherInfoEditEditingDone(sender: TObject);   // or 
procedure TMyFrame.OtherInfoExit(sender: TObject);   // either one is the same
begin 
     MyObject.OtherInfo.Text := OtherInfoEdit.Strings.Text; 
end; 
 

And I want the (changed) contents in the controls are automatically saved in the MyObject variable. The contents are saved when focus moves from one control to another, but not (neither RTTI controls nor general controls, neither OnEditingDone nor OnExit) when I leave the form like by running other Windows application, by closing the form pressing Alt-F4 or small x, or on other cases I do not remember exactly. So I was looking for ways that I can save my changes reliably, i.e. will call OnExit or OnEditingDone reliably.

I thought over solutions suggested here in comments. But I think it better not to introduce any futher things like TWinControl or TNotifyEvent or other event handlers or new variable like ParentForm.

And I found putting ActiveContol to nil in the form.

Code: Pascal [Select][+]

procedure TMyForm.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
     // It is possible to ask whether to save the changes here, but decided to put it later setp, between Object and permanent storage (e.g. database)
     Self.ActiveControl := nil;
end;
 

This will call OnExit or OnEditingDone procedures defined only in the frames.

Hope that I did not mislead you by the title ".. when form is clicked?". At first, I tried to save the content by clicking on (title bar or vacant part of) the form but I found that there are other situations like pressing Alt-F4.

Thank all of you again for your kind advices.