Print Page - Setting events stored in other unit to controls

Free Pascal => Beginners => Topic started by: Gald on May 09, 2021, 06:06:38 pm

Title: Setting events stored in other unit to controls
Post by: Gald on May 09, 2021, 06:06:38 pm

Hello hello!

I trying to do something like this:

Label1.OnClick:=@LabelClick;

But the event LabelClick is on another unit.
None of this below is working.

Code: Pascal [Select][+]

Label1.OnClick:=@Unit2.LabelClick;
Label1.OnClick:=Unit2.@LabelClick;
Label1.OnClick:=Unit2.SomeClass.LabelClick;
Label1.OnClick:=Unit2.SomeClass.@LabelClick;
Label1.OnClick:=@Unit2.SomeClass.LabelClick;

Then, how can I do it?

Title: Re: Setting events stored in other unit to controls
Post by: Bart on May 09, 2021, 07:25:15 pm

Define "not working".
Compilation error?
Runtime error?
Something else?

Bart

Title: Re: Setting events stored in other unit to controls
Post by: Gald on May 09, 2021, 07:47:29 pm

Quote from: Bart on May 09, 2021, 07:25:15 pm

Define "not working".

C:\Test\unit1.pas(37,20) Error: (4001) Incompatible types: got "<address of procedure(TObject);Register>" expected "<procedure variable type of procedure(TObject) of object;Register>"

There's also this hit info on Attachment.

Title: Re: Setting events stored in other unit to controls
Post by: Gald on May 09, 2021, 09:23:33 pm

Could you please look at this sample project?
I still having problems.

Title: Re: Setting events stored in other unit to controls
Post by: Handoko on May 09, 2021, 09:52:14 pm

This works:

Code: Pascal [Select][+]

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Forms, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    procedure TheReplacement(Sender: TObject);
  public
 
  end;
 
var
  Form1: TForm1;
 
implementation
 
uses Unit2;
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  Label1.OnClick := @TheReplacement;
end;
 
procedure TForm1.TheReplacement(Sender: TObject);
begin
  OnClickReplacement(Sender);
end;
 
end.

Code: Pascal [Select][+]

unit Unit2;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  StdCtrls, Graphics;
 
procedure OnClickReplacement(Sender: TObject);
 
implementation
 
procedure OnClickReplacement(Sender: TObject);
begin
  if not(Sender is TLabel) then Exit;
  (Sender as TLabel).Font.Style := [fsBold];
end;
 
end.

Just to warn you, don't use such trick too much. Or your code will be become spaghetti code:
https://en.wikipedia.org/wiki/Spaghetti_code

Title: Re: Setting events stored in other unit to controls
Post by: Gald on May 09, 2021, 10:33:55 pm

Quote from: Handoko on May 09, 2021, 09:52:14 pm

Just to warn you, don't use such trick too much.

:o :o LOooolll

My goal was to do it a lot.
I have to find another way.

Title: Re: Setting events stored in other unit to controls
Post by: Gustavo 'Gus' Carreno on May 09, 2021, 11:48:03 pm

Hey Gald,

Quote from: Gald on May 09, 2021, 06:06:38 pm

But the event LabelClick is on another unit.

I understand separation of concerns and the need to put things in little manageable boxes, but what I can't understand is why you want events from one form to be handled in some other unit.

In my point of view, a Label's event should reside on the same unit that declares it and that, at least for me, checks both these boxes: separation of concern and the put-things-in-little-boxes.

Can I, very politely, ask for an explanation on why would you want to bridge across a unit for an event?
I think there's a design flaw on your side that needs to be addressed, not shamed, but addressed :)

Cheers,
Gus

Title: Re: Setting events stored in other unit to controls
Post by: Handoko on May 10, 2021, 05:39:22 am

Quote from: Gald on May 09, 2021, 10:33:55 pm

My goal was to do it a lot.
I have to find another way.

You will better understand what spaghetti code is if you really make one.

If you're working on a commercial project or a company, you have to be careful. Any wrong decision can be costly. But if it is you personal project then it is okay. We can learn from other's experience and we can learn from our own mistakes.

Programmers dislike spaghetti code because it is hard to maintain. Finding and fixing bug is hard, adding new features is hard, even reading it is hard. Just as what Gus said, I believe there is a design flaw. But let's put that aside, here are the things you can do to minimize that bad effects.

Use proper names for variables, functions and procedures
It really will improve the code readability, a lot.

Put them into groups
Normally we should put the codes that related near together but you're going to separate it and put them into other unit. I heard you said 'a lot'. So those things should be grouped and properly arranged in a good order.

Don't mix with others
The unit that stores events, should not contain other kind of codes. If it has, you should move them out to another unit.

Give proper comments
Often, we need to revisit the code we wrote some years ago. It can be helpful if you document the code by using comments. Just don't overuse comment, that is bad too.

If someday that code becomes 'too hard' for you to handle then you will know it is a spaghetti code. Lesson learned. But if that never happens, you learn the new trick.

Title: Re: Setting events stored in other unit to controls
Post by: Gustavo 'Gus' Carreno on May 10, 2021, 07:05:47 am

Hey Gald,

After reading what Handoko wrote, and from a recent experience with code from a person that didn't went the OOP route and instead opted for the Procedural way and having units to group those procedure/function by his arbitrary rules, I now have another question:

How well versed are you on OOP?

I ask this because it kinda sounds like your decision to put Event handlers in other units is what that other fellah did with the procedural approach.

I need to stress this out: No shame what so ever.
But you have to pick a lane and stick to it.

And by that I mean, you either go OOP and every object has his own unit, of sorts.
Or you decide to go all in with the procedural approach and you spread your code in a different way.

If you embrace the OOP methodology, I think your code will be a lot kinder to other programmers.
If, on the other side, you are going for the procedural approach, then your code will be considered spaghetti by the majority of the programmers that only have patience for OOP.
But at least it's your spaghetti and you'll know how to navigate it. But, alas, you'll be a solo programmer on this one for a long time :(

So yeah, pick your lane, stick to it and PLEASE pay attention to the VERY GOOD advice that Handoko gave you, it's rather good and very valuable!!

Cheers,
Gus

Title: Re: Setting events stored in other unit to controls
Post by: Gald on May 10, 2021, 08:32:21 am

Thank you so so so much for your tips!

Handoko, I'll do some tests on it, and learn more about that.

Gus, I like your curiosity!
I'm doing an application with a kind of "web page" (scrollbox) that loads a file with the interface and his methods.
It's like what a Browser does with HTML, but with native controls. So, the users will have tools to create their own "pages", very limited, with a list of premade code in some units. If the user puts a Buttom he must choose a small list of premade actions, which will be stored in some units. Then he will generate his personal form (page) and it will be stored in a file and shared with others users to load it in runtime and navigate.
And was not a fan of OOP, but it starts to get interesting. I saw some things in recent years, but I didn't use my hands to write and learn for real. I gonna find some direct/concentrated articles/lessons about it right now.

You may find this video interest: https://www.youtube.com/watch?v=cvDyQUpaFf4

Title: Re: Setting events stored in other unit to controls
Post by: Handoko on May 10, 2021, 08:40:41 pm

What you're going to develop is not simple. Not only creating a set of predefined actions, you may also need to create a GUI editor and/or maybe a text parser/interpreter, which has some similarities with the game builder I'm developing. But I like your creativity and eagerness for doing something challenging.

Here I wrote a simplified demo. Not exactly what you want but it should give the idea.

Code: Pascal [Select][+]

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, Forms, ExtCtrls, StdCtrls, ActionsLib;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    btnUp: TButton;
    btnDown: TButton;
    btnLeft: TButton;
    btnRight: TButton;
    Shape1: TShape;
    procedure FormCreate(Sender: TObject);
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  SetTarget(Shape1);
  SetButtonUp(btnUp);
  SetButtonDown(btnDown);
  SetButtonLeft(btnLeft);
  SetButtonRight(btnRight);
end;
 
end.

Code: Pascal [Select][+]

unit ActionsLib;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, Forms, StdCtrls, ExtCtrls;
 
procedure SetTarget(Shape: TShape);
procedure SetButtonUp(Button: TButton);
procedure SetButtonDown(Button: TButton);
procedure SetButtonLeft(Button: TButton);
procedure SetButtonRight(Button: TButton);
 
implementation
 
type
 
  { TTmpButton }
 
  TTmpButton = class(TButton)
  public
    procedure ShapeMoveUp(Sender: TObject);
    procedure ShapeMoveDown(Sender: TObject);
    procedure ShapeMoveLeft(Sender: TObject);
    procedure ShapeMoveRight(Sender: TObject);
  end;
 
const
  TargetObject: TShape = nil;
 
var
  TmpButton: TTmpButton;
 
procedure SetTarget(Shape: TShape);
begin
  TargetObject := Shape;
end;
 
procedure SetButtonUp(Button: TButton);
begin
  Button.OnClick := @TmpButton.ShapeMoveUp;
end;
 
procedure SetButtonDown(Button: TButton);
begin
  Button.OnClick := @TmpButton.ShapeMoveDown;
end;
 
procedure SetButtonLeft(Button: TButton);
begin
  Button.OnClick := @TmpButton.ShapeMoveLeft;
end;
 
procedure SetButtonRight(Button: TButton);
begin
  Button.OnClick := @TmpButton.ShapeMoveRight;
end;
 
procedure TTmpButton.ShapeMoveUp(Sender: TObject);
begin
  if not(Assigned(TargetObject)) then Exit;
  TargetObject.Top := TargetObject.Top - 10;
  if TargetObject.Top < -TargetObject.Height then
    TargetObject.Top := TargetObject.Parent.Height;
end;
 
procedure TTmpButton.ShapeMoveDown(Sender: TObject);
begin
  if not(Assigned(TargetObject)) then Exit;
  TargetObject.Top := TargetObject.Top + 10;
  if TargetObject.Top > TargetObject.Parent.Height then
    TargetObject.Top := -TargetObject.Height;
end;
 
procedure TTmpButton.ShapeMoveLeft(Sender: TObject);
begin
  if not(Assigned(TargetObject)) then Exit;
  TargetObject.Left := TargetObject.Left - 10;
  if TargetObject.Left < -TargetObject.Width then
    TargetObject.Left := TargetObject.Parent.Width;
end;
 
procedure TTmpButton.ShapeMoveRight(Sender: TObject);
begin
  if not(Assigned(TargetObject)) then Exit;
  TargetObject.Left := TargetObject.Left + 10;
  if TargetObject.Left > TargetObject.Parent.Width then
    TargetObject.Left := -TargetObject.Width;
end;
 
end.

Title: Re: Setting events stored in other unit to controls
Post by: egsuh on May 11, 2021, 04:05:59 am

Handoko's effort is remarkable. This would not be so difficult if actions are done to "Sender" itself, but would be difficult if events have to do something on other controls.

Title: Re: Setting events stored in other unit to controls
Post by: Gald on May 11, 2021, 04:25:41 am

Handoko, your demo is impressive!
This was exactly what I need.

There are no words to express my gratitude for you.
Keep being the nice guy you are :-*

Title: Re: Setting events stored in other unit to controls
Post by: Gustavo 'Gus' Carreno on May 11, 2021, 08:18:58 am

Hey Gald,

Quote from: Gald on May 10, 2021, 08:32:21 am

Gus, I like your curiosity!

Thank you :)

Quote from: Gald on May 10, 2021, 08:32:21 am

I'm doing an application with a kind of "web page" (scrollbox) that loads a file with the interface and his methods.

Hummmm, so in a way, just what Lazarus is doing with the *.lfm. Rather interesting !!!

Quote from: Gald on May 10, 2021, 08:32:21 am

It's like what a Browser does with HTML, but with native controls. So, the users will have tools to create their own "pages", very limited, with a list of premade code in some units. If the user puts a Buttom he must choose a small list of premade actions, which will be stored in some units. Then he will generate his personal form (page) and it will be stored in a file and shared with others users to load it in runtime and navigate.
And was not a fan of OOP, but it starts to get interesting. I saw some things in recent years, but I didn't use my hands to write and learn for real. I gonna find some direct/concentrated articles/lessons about it right now.

Getting more interesting by the minute !!!
Please report back with your progress!!!

Can I ask if you're willing to share your code in one of the many code sharing platforms? I'm partial to GitHub, but anyone will do :)

Quote from: Gald on May 10, 2021, 08:32:21 am

You may find this video interest: https://www.youtube.com/watch?v=cvDyQUpaFf4

I'll have a watch :)

Cheers,
Gus

Title: Re: Setting events stored in other unit to controls
Post by: Gustavo 'Gus' Carreno on May 11, 2021, 08:20:24 am

Hey Handoko,

As per usual a brilliant effort!!!

Thanks Handoko!!

Cheers,
Gus

Title: Re: Setting events stored in other unit to controls
Post by: Handoko on May 18, 2021, 08:54:08 pm

Quote from: egsuh on May 11, 2021, 04:05:59 am

This would not be so difficult if actions are done to "Sender" itself, but would be difficult if events have to do something on other controls.

Yes, you're right. It is much more challenging. Here I wrote a demo for setting button's OnClick event to control the behavior of 2 shapes.

Code: Pascal [Select][+]

unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, Forms, Graphics, StdCtrls, ExtCtrls, ActionsLib;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    btnStart: TButton;
    procedure btnStartClick(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FShapes: array of TShape;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.btnStartClick(Sender: TObject);
var
  aShape:  TShape;
  aButton: TButton;
begin
 
  btnStart.Free;
 
  // Create the shapes
  SetLength(FShapes, 2);
  aShape              := TShape.Create(Self);
  aShape.Parent       := Self;
  aShape.Left         := 40;
  aShape.Top          := 40;
  aShape.Brush.Color  := clMoneyGreen;
  aShape.Shape        := stCircle;
  FShapes[0]          := aShape;
  aShape              := TShape.Create(Self);
  aShape.Parent       := Self;
  aShape.Left         := 130;
  aShape.Top          := 40;
  aShape.Brush.Color  := clYellow;
  aShape.Shape        := stTriangle;
  FShapes[1]          := aShape;
  aShape              := TShape.Create(Self);
  aShape.Parent       := Self;
  aShape.Left         := 220;
  aShape.Top          := 40;
  aShape.Brush.Color  := clSkyBlue;
  aShape.Shape        := stDiamond;
  FShapes[2]          := aShape;
 
  // Create the labels
  with TLabel.Create(Self) do
  begin
    Parent := Self;
    Left   := 70;
    Top    := 20;
    Caption := 'A';
  end;
  with TLabel.Create(Self) do
  begin
    Parent := Self;
    Left   := 160;
    Top    := 20;
    Caption := 'B';
  end;
  with TLabel.Create(Self) do
  begin
    Parent := Self;
    Left   := 250;
    Top    := 20;
    Caption := 'C';
  end;
 
  // Create buttons
  aButton := TButton.Create(Self);
  aButton.Parent  := Form1;
  aButton.Left    := 40;
  aButton.Top     := 130;
  aButton.Width   := 240;
  aButton.Caption := 'AB swap color';
  ButtonClickSwapColor(aButton, FShapes[0], FShapes[1]);
  aButton         := TButton.Create(Self);
  aButton.Parent  := Form1;
  aButton.Left    := 40;
  aButton.Top     := 160;
  aButton.Width   := 240;
  aButton.Caption := 'BC swap color';
  ButtonClickSwapColor(aButton, FShapes[1], FShapes[2]);
  aButton         := TButton.Create(Self);
  aButton.Parent  := Form1;
  aButton.Left    := 40;
  aButton.Top     := 190;
  aButton.Width   := 240;
  aButton.Caption := 'AB swap shape';
  ButtonClickSwapShape(aButton, FShapes[0], FShapes[1]);
 
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
var
  i: Integer;
begin
  for i := 0 to Length(FShapes)-1 do
    FShapes[i].Free;
  SetLength(FShapes, 0);
end;
 
end.

In the code above, all the visual components on the form are created at run-time except btnStart, line #15.
Setting the OnClick events can be found on the lines #93, #100, #107.

Code: Pascal [Select][+]

unit ActionsLib;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, Forms, Graphics, StdCtrls, ExtCtrls;
 
procedure ButtonClickSwapColor(Button: TButton; Shape1, Shape2: TShape);
procedure ButtonClickSwapShape(Button: TButton; Shape1, Shape2: TShape);
 
implementation
 
const
  ID_Length = 30; // not sure but 30 should be more than enough
 
type
 
  IDstring = string[ID_Length];
  TLink = record
    ID:    IDstring;
    Item1: TShape;
    Item2: TShape;
  end;
 
  { TTmpShape }
 
  TTmpShape = class(TShape)
  public
    procedure SwapColor(Sender: TObject);
    procedure SwapShape(Sender: TObject);
  end;
 
var
  TmpShape: TTmpShape;
  Links:    array of TLink;
 
procedure SaveLink(const ID: IDstring; Shape1, Shape2: TShape);
var
  i: Integer;
begin
  i := Length(Links);
  SetLength(Links, i+1);
  Links[i].ID    := ID;
  Links[i].Item1 := Shape1;
  Links[i].Item2 := Shape2;
end;
 
procedure GetLink(const ID: IDstring; out Shape1, Shape2: TShape);
var
  i: Integer;
begin
  Shape1 := nil;
  Shape2 := nil;
  for i := 0 to Length(Links)-1 do
    if Links[i].ID = ID then
    begin
      Shape1 := Links[i].Item1;
      Shape2 := Links[i].Item2;
      Exit;
    end;
end;
 
procedure ButtonClickSwapColor(Button: TButton; Shape1, Shape2: TShape);
var
  S: string;
begin
  S := PtrInt(Button).ToString + 'Click';
  SaveLink(S, Shape1, Shape2);
  Button.OnClick := @TmpShape.SwapColor;
end;
 
procedure ButtonClickSwapShape(Button: TButton; Shape1, Shape2: TShape);
var
  S: string;
begin
  S := PtrInt(Button).ToString + 'Click';
  SaveLink(S, Shape1, Shape2);
  Button.OnClick := @TmpShape.SwapShape;
end;
 
{ TTmpShape }
 
procedure TTmpShape.SwapColor(Sender: TObject);
var
  Shape1, Shape2: TShape;
  Temp:           TColor;
  S:              string;
begin
  if not(Sender is TButton) then Exit;
  S := PtrInt(Sender).ToString + 'Click';
  GetLink(S, Shape1, Shape2);
  if (Shape1 = nil) or (Shape2 = nil) then Exit;
  Temp               := Shape1.Brush.Color;
  Shape1.Brush.Color := Shape2.Brush.Color;
  Shape2.Brush.Color := Temp;
end;
 
procedure TTmpShape.SwapShape(Sender: TObject);
var
  Shape1, Shape2: TShape;
  Temp:           TShapeType;
  S:              string;
begin
  if not(Sender is TButton) then Exit;
  S := PtrInt(Sender).ToString + 'Click';
  GetLink(S, Shape1, Shape2);
  if (Shape1 = nil) or (Shape2 = nil) then Exit;
  Temp         := Shape1.Shape;
  Shape1.Shape := Shape2.Shape;
  Shape2.Shape := Temp;
end;
 
initialization
  SetLength(Links, 0);
 
finalization
  SetLength(Links, 0);
 
end.

This demo only show 2 functions: SwapColor and SwapShape, line #10 & #11.

TLink is used to keep track which items to control, line #21.

This simplified demo only shows setting the OnClick events, you can expand it to handle other events by changing how the ID generated, see line #69, #78.