Print Page - for achar := 'A' to 'Z' do

Free Pascal => General => Topic started by: Fred vS on October 23, 2022, 08:49:51 pm

Title: for achar := 'A' to 'Z' do
Post by: Fred vS on October 23, 2022, 08:49:51 pm

Hello.

I just tested this code:

procedure loop_of_char;
var
achar : char;
begin
  for achar := 'A' to 'Z' do writeln(achar);
end;
 

And (Wow) it gives me all the uppercase letters of the latin alphabet.

But it is safe to do that ?

Title: Re: for achar := 'A' to 'Z' do
Post by: Thaddy on October 23, 2022, 09:02:09 pm

This is a bit more safe:

Code: Pascal [Select][+]

var a: char;
begin
   for a in ['A'..'Z'] do writeln(a);
end.

But your code is safe too.

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 23, 2022, 09:02:42 pm

I think it should be, because of the strictures that apply to Pascal identifiers: I remember comment on this from Jonas et al. when somebody wanted to know if the compiler could be modified to run on an EBCDIC-based mainframe.

However it might still be safer to use AnsiChar.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: Thaddy on October 23, 2022, 09:38:10 pm

I agree that - given modern Pascal - dialects it is always better to write the intention.
But in this case it makes no difference either way.
So yes, explain your char or string type by proper declaration.

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 23, 2022, 09:44:26 pm

One might laugh but... I've used a tool in the past which made no assumption about character set, i.e. collation order or what characters could appear in an identifier, but /did/ assume that digits were sequential and ordered 0...9.

And damme, but if you look hard enough you can find character sets where even that doesn't apply.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 23, 2022, 10:01:34 pm

@Thaddy and @Mark : Thanks for the infos and happy to discover it.

It does not work with:

Code: Pascal [Select][+]

for achar := 'Ά' to 'Ω' do

but personnaly I dont need it (at the moment).

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 23, 2022, 10:16:33 pm

Yeah, well they're outside the set of characters that can be legitimately used in Pascal identifiers, so all bets are off.

I've given a bit of thought to "simple" rules of thumb determining what can be in an identifier, what can be used as an operator and so on... but at the same time I think that the Unicode Consortium has put a serious amount of work into it some of which might actually be useful.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: Kays on October 23, 2022, 10:19:29 pm

Quote from: Fred vS on October 23, 2022, 08:49:51 pm

[…] But it is safe to do that ?

To quote from the ISO standard 7185 (“Standard Pascal”):

Quote

6.4.2.2 Required simple-types
The following types shall exist
integer-type. […]
real-type. […]
Boolean-type. […]
char-type. […] The following relations shall hold.
The subset of character values representing the digits 0 to 9 shall be numerically ordered and contiguous.
The subset of character values representing the upper case letters A to Z, if available, shall be alphabetically ordered but not necessarily contiguous.
The subset of character values representing the lower case letters a to z, if available, shall be alphabetically ordered but not necessarily contiguous.

That’s all fine, but the compiler still needs to claim ISO-compliance. Bottom line, your algorithm is “safe”, i. e. produces the expected result, as long as ord('A') + 25 = ord('Z').

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 23, 2022, 10:36:39 pm

Note that the ISO standard doesn't declare that there are 26 characters in the range A through Z.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: Bart on October 23, 2022, 10:40:43 pm

If you really want to be safe (in the sense that there are guaranteed to be no other characters in between, regardless of character set) you can do:

Code: Pascal [Select][+]

const
  Alphabet = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ';
begin
  for aChar in Alphabet do writeln(AChar);
end.

Yes, I know it's silly ;)

Bart

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 23, 2022, 10:53:38 pm

Thanks all for the light.

By the way, the goal is to get all the devices on a Windows system with something like this:

Code: Pascal [Select][+]

   var
    achar : char
    ...
     for achar := 'A' to 'Z' do
        begin
         if directoryexists(achar + ':\') then writeln(achar + ':\ exists'');
 

Maybe (surely) there are other ways but this code works as expected. :-\

Title: Re: for achar := 'A' to 'Z' do
Post by: Kays on October 23, 2022, 10:59:28 pm

Quote from: MarkMLl on October 23, 2022, 10:36:39 pm

Note that the ISO standard doesn't declare that there are 26 characters in the range A through Z.

Well, if your comment is meant to say it could be less than 26 characters:

Quote

4 Definitional conventions
[…]
The characters required to form Pascal programs shall be those implicitly required to form the tokens and separators defined in 6.1.
[…]
6.1.1 General
[…] The representation of any letter (upper case or lower case, differences in font (https://xkcd.com/2309/), etc.) occurring anywhere outside of a character-string (see 6.1.7) shall be insignificant in that occurrence to the meaning of the program.
letter = ‘a’ | ‘b’ | ‘c’ | ‘d’ | […] ‘w’ | ‘x’ | ‘y’ | ‘z’ .

Because you can write, compose, say, identifiers as a sequence of letters A – Z, you can specify these letters in a character-string, too.

Furthermore, the ISO standards 7185 and 10206 incorporate clauses from ASCII (ISO standard 646:1983), but I’m not sure what exactly.

Quote from: Fred vS on October 23, 2022, 10:53:38 pm

[…] By the way, the goal is to get all the devices on a Windows system with something like this: […]

Maybe it won’t catch unformatted devices, I don’t know.

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 23, 2022, 11:09:04 pm

Quote from: Kays on October 23, 2022, 10:59:28 pm

Quote from: Fred vS on October 23, 2022, 10:53:38 pm
[…] By the way, the goal is to get all the devices on a Windows system with something like this: […]
Maybe it won’t catch unformatted devices, I don’t know.

I hope so and also no mounted devices.

So all seems ok, I can go to sleep (after commit all that, of course).

Many thanks to all and have a good night and day (or day and night).

Fre;D

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 23, 2022, 11:21:30 pm

Allez, for the game, this one works too ;) :

Code: Pascal [Select][+]

procedure inc_char;
var
achar : char = 'A';
begin
  while achar <= 'Z' do
      begin
      writeln(achar);
      inc(achar);
     end;
end;

Title: Re: for achar := 'A' to 'Z' do
Post by: Bart on October 23, 2022, 11:50:33 pm

Quote from: Fred vS on October 23, 2022, 10:53:38 pm

By the way, the goal is to get all the devices on a Windows system with something like this:

I haved a DriveComboBox for that...
You can specify what type of drive when populating (e.g. removables only).
Windows only of course.

Bart

Title: Re: for achar := 'A' to 'Z' do
Post by: Jorg3000 on October 24, 2022, 08:55:27 am

Hi!
And if you need information about the type of a drive, see ...

Code: Pascal [Select][+]

aType:=Windows.GetDriveType(PChar(aRootPath));

DRIVE_REMOVABLE=2; DRIVE_FIXED=3; DRIVE_REMOTE=4; DRIVE_CDROM=5; DRIVE_RAMDISK=6;

https://learn.microsoft.com/en-us/windows/win32/api/fileapi/nf-fileapi-getdrivetypea (https://learn.microsoft.com/en-us/windows/win32/api/fileapi/nf-fileapi-getdrivetypea)
Jörg

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 24, 2022, 09:03:36 am

Quote from: Kays on October 23, 2022, 10:59:28 pm

4 Definitional conventions
[…]
The characters required to form Pascal programs shall be those implicitly required to form the tokens and separators defined in 6.1.

But that is distinct from your earlier

Quote

6.4.2.2 Required simple-types

This was the point in the discussion a few years ago of a mainframe port: FPC could quite happily have EBCDIC-based string types (i.e. section 6), but changing the compiler itself to use anything other than an ASCII representation for the program (i.e. section 4) would have been decidedly non-trivial.

So a cross-compiler would have been viable, at least for newer variants of the IBM mainframe architecture, but a native compiler much less so.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: ASerge on October 24, 2022, 06:43:08 pm

Quote from: Fred vS on October 23, 2022, 10:53:38 pm

By the way, the goal is to get all the devices on a Windows system with something like this:

Code: Pascal [Select][+]

{$MODE OBJFPC}
{$APPTYPE CONSOLE}
{$LONGSTRINGS ON}
 
uses SysUtils, Windows;
 
procedure PrintDrives;
var
  BufSize: DWORD;
  P, Buffer: PUnicodeChar;
  S: UnicodeString;
begin
  BufSize := GetLogicalDriveStringsW(0, nil);
  if BufSize = 0 then
    RaiseLastOSError;
  GetMem(Buffer, BufSize * SizeOf(UnicodeChar));
  try
    if GetLogicalDriveStringsW(BufSize, Buffer) = 0 then
      RaiseLastOSError;
    P := Buffer;
    while P[0] <> #0 do
    begin
      S := P;
      Inc(P, Length(S) + 1);
      Writeln(S);
    end;
  finally
    FreeMem(Buffer);
  end;
end;
 
begin
  PrintDrives;
  Readln;
end.

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 24, 2022, 07:52:37 pm

@Jorge3000 and @ASerge and @Bart: many thanks for that execellent options.

But I forgot to note that I prefer a cross-os code and not use window unit .
So I will stay with one of the options using a loop with if directoryexists((achar + ':\') in it.

Fre;D

Title: Re: for achar := 'A' to 'Z' do
Post by: wildfire on October 24, 2022, 08:12:36 pm

Quote from: Fred vS on October 24, 2022, 07:52:37 pm

@Jorge3000 and @ASerge and @Bart: many thanks for that execellent options.

But I forgot to note that I prefer a cross-os code and not use window unit .
So I will stay with one of the options using a loop with if directoryexists((achar + ':\') in it.

Fre;D

Which in itself is not cross OS.

Title: Re: for achar := 'A' to 'Z' do
Post by: MarkMLl on October 24, 2022, 08:37:46 pm

Quote from: wildfire on October 24, 2022, 08:12:36 pm

Which in itself is not cross OS.

I have to agree, since I'm sure that Fred is interested in more than Windows and DOS. But allowing that the other OSes tend to be unix-based, it's difficult to decide on an appropriate alternative unless we try to do something like enumerating / plus any other filesystems that some system component can access without actually mounting it.

MarkMLl

Title: Re: for achar := 'A' to 'Z' do
Post by: Fred vS on October 24, 2022, 08:45:39 pm

Quote from: wildfire on October 24, 2022, 08:12:36 pm

Quote from: Fred vS on October 24, 2022, 07:52:37 pm
@Jorge3000 and @ASerge and @Bart: many thanks for that execellent options.

But I forgot to note that I prefer a cross-os code and not use window unit .
So I will stay with one of the options using a loop with if directoryexists((achar + ':\') in it.

Fre;D

Which in itself is not cross OS.

It depend what you call cross OS, the previous code of course will have no result on Unix.
Here part of the code to populate a grid, like a filedialog. (of course using {$ifdef windows} for the afphabet drivers and {$ifdef unix} for "/" in path will make code lighter but will not generate crash without it.)

Code: Pascal [Select][+]

// this will be for Windows only
{$ifdef windows}  // optional
  for achar := 'A' to 'Z' do
    begin
     if directoryexists(achar + ':\') then
       begin
        Inc(x);
        fo.places.rowcount := x+1;
         fo.places[1][x] := string(achar + ':\');
       end;
   end;
   
    if directoryexists('C:\users') then  // only Windows
    begin
      Inc(x);
      fo.places.rowcount := x+1;
      fo.places[1][x] := string('C:\users');
    end;
{$endif}   
 
{$ifdef unix} // optional
    if directoryexists('/') then // only Unix
    begin
      Inc(x);
      fo.places.rowcount := x+1;
      fo.places[1][x] := string('/');
    end;
    if directoryexists('/usr') then // only unix
    begin
      Inc(x);
      fo.places.rowcount := x+1;
      fo.places[1][x] := string('/usr');
    end;
    {$endif}
 
    if directoryexists(tosysfilepath(sys_getuserhomedir)) then // Windows and Unix
    begin
      Inc(x);
      fo.places.rowcount := x+1;
      fo.places[1][x] := string(tosysfilepath(sys_getuserhomedir));
    end;
    if directoryexists(tosysfilepath(sys_getuserhomedir + directoryseparator + 'Desktop')) then // Windows and Unix
    begin
      Inc(x);
      fo.places.rowcount := x+1;
      fo.places[1][x] := string(tosysfilepath(sys_getuserhomedir + directoryseparator + 'Desktop'));
    end;
....
 

Title: Re: for achar := 'A' to 'Z' do
Post by: PascalDragon on October 25, 2022, 07:47:44 am

Quote from: wildfire on October 24, 2022, 08:12:36 pm

Quote from: Fred vS on October 24, 2022, 07:52:37 pm
@Jorge3000 and @ASerge and @Bart: many thanks for that execellent options.

But I forgot to note that I prefer a cross-os code and not use window unit .
So I will stay with one of the options using a loop with if directoryexists((achar + ':\') in it.

Fre;D

Which in itself is not cross OS.

If you need to work with drive letters you already are not cross platform. And sometimes you need to provide a platform specific view (e.g. displaying the full root on *nix systems, but displaying the drive letters on Windows for the user to find themselves at home).

Lazarus

Free Pascal => General => Topic started by: Fred vS on October 23, 2022, 08:49:51 pm