Saving form contents as image partially

[Leledumbo]

I have an application with this layout:

Code: [Select]

+--Form---+
|+-------+|
|| Image ||
|+-------+|
|+-------+|
|| Panel ||
|+-------+|
|+-------+|
||Button ||
|+-------+|
+---------+
And I need to save as image the image and panel part. How can I do so?

So far, though haven't tried, my crazy idea is to copy Canvas.Pixels from top left of image to bottom right of panel. But I'm not sure.

[LazaruX]

Do you mean making a kind of screenshot of Image and Panel together? If you mean this, you could just try to make a partial screenshot.

[Zoran]

I found this on Wiki:

http://wiki.lazarus.freepascal.org/Developing_with_Graphics#Taking_a_screenshot_of_the_screen

I haven't tried it though.

[Zoran]

Now I tried and this saves the screenshot of the form:

Code: [Select]

procedure TForm1.Button2Click(Sender: TObject);
var
  MyBitmap: TBitmap;
  MyDC: HDC;
begin
  MyDC := GetDC(Self.Handle);
  MyBitmap := TBitmap.Create;
  try
    MyBitmap.LoadFromDevice(MyDC);
    MyBitmap.SaveToFile('FormsAppearance.bmp');
  finally
    ReleaseDC(Self.Handle, MyDC);
    FreeAndNil(MyBitmap);
  end;
end;


[Leledumbo]

you could just try to make a partial screenshot

That's another idea, too. The problem is, what do I have to set to limit the region of the TBitmap (my knowledge about this class isn't too deep)? Plus, is there any easy way to get the top left of the image and bottom right of the panel? The screenshot will take a whole screen, so I can't use relative position to the form.

I found this on Wiki

Yes, I've seen that page. Combined with what BPsoftware suggests, I can make it right.

[Zoran]

Only now I understand what you actually asked, sorry.

I beleive that this is what you want:

Code: [Select]

uses
  ...,  LCLIntf, LCLType;

...

procedure TForm1.Button2Click(Sender: TObject);
var
  MyBitmap, MyBitmap2: TBitmap;
  MyDC: HDC;
  R: TRect;
begin
  MyBitmap2 := TBitmap.Create;
  MyBitmap := TBitmap.Create;
  try
    MyDC := GetDC(Self.Handle);
    try
      MyBitmap.LoadFromDevice(MyDC);

    finally
      ReleaseDC(Self.Handle, MyDC);
    end;

    R.TopLeft := Image1.BoundsRect.TopLeft;
    R.BottomRight := Panel1.BoundsRect.BottomRight;

    MyBitmap2.Width := R.Right - R.Left;
    MyBitmap2.Height := R.Bottom - R.Top;

    MyBitmap2.Canvas.CopyRect(Rect(0, 0, MyBitmap2.Width, MyBitmap2.Height),
                                      MyBitmap.Canvas, R);
    MyBitmap2.SaveToFile('ImageAndPanel.bmp');
  finally
    FreeAndNil(MyBitmap);
    FreeAndNil(MyBitmap2);
  end;
end;


[Leledumbo]

Thanks, Zoran. I implemented it more or less the same as you do, except that I use ControlToScreen to get screen coordinates of the image and panel.

However, after trying it myself I conclude that taking screenshot and CopyRect-ing it isn't a good idea. I ask the user for a filename before saving it, and it tries to get the screenshot before the save dialog really closes, so the dialog is included in the image. The temporary solution is to call Sleep() with some value (currently 500) before LoadFromDevice(), this will give (enough?) time for the dialog to close. If anyone has a better idea, please tell me.

[Zoran]

Thanks, Zoran. I implemented it more or less the same as you do, except that I use ControlToScreen to get screen coordinates of the image and panel.

However, after trying it myself I conclude that taking screenshot and CopyRect-ing it isn't a good idea. I ask the user for a filename before saving it, and it tries to get the screenshot before the save dialog really closes, so the dialog is included in the image. The temporary solution is to call Sleep() with some value (currently 500) before LoadFromDevice(), this will give (enough?) time for the dialog to close. If anyone has a better idea, please tell me.

I found a solution, you must call Application.ProcessMessages.

This works:

Code: [Select]

procedure TForm1.Button1Click(Sender: TObject);
var
  MyBitmap, MyBitmap2: TBitmap;
  MyDC: HDC;
  R: TRect;
  S: String;
begin
  if InputQuery(Application.Title, 'Your password:', True, S) then begin
    if S = 'pass' then begin
      Application.ProcessMessages;
      MyBitmap2 := TBitmap.Create;
      MyBitmap := TBitmap.Create;
      try
        MyDC := GetDC(Self.Handle);
        try
          MyBitmap.LoadFromDevice(MyDC);

        finally
          ReleaseDC(Self.Handle, MyDC);
        end;

        R.TopLeft := Image1.BoundsRect.TopLeft;
        R.BottomRight := Panel1.BoundsRect.BottomRight;

        MyBitmap2.Width := R.Right - R.Left;
        MyBitmap2.Height := R.Bottom - R.Top;

        MyBitmap2.Canvas.CopyRect(Rect(0, 0, MyBitmap2.Width, MyBitmap2.Height),
                                          MyBitmap.Canvas, R);
        MyBitmap2.SaveToFile('ImageAndPanel.bmp');
      finally
        FreeAndNil(MyBitmap);
        FreeAndNil(MyBitmap2);
      end;

    end else
      ShowMessage('Wrong password');

  end;
end;

The password dialog is not actually removed from screen (and the main form is not repainted yet) until the Application.ProcessMessages is called.

It gets called automaticaly AFTER the buttons message handler, but you need to call it before taking the screenshot, so the solution is rather simple -- call it manually!