[Solved] "try ... except on" syntax

[Edson]

Can someone, please, explain what is the logic of this?

Code: Pascal  [Select][+][-]

1.     try
2.         ...
3.     except
4.       on EConvertError do Writeln('Invalid number');
5.       on EDivByZero do Writeln('By zero');
6.       else begin Writeln('Other error'); end;
7.       //When a EConvertError or EDivByZero is fired, this doesn't execute.
8.       //When other is fired, this execute.
9.       writeln('Was error');
10.     end;
11.  

First of all: Is legal to include some code after a "on ... do " sentence?

And it's strange for me that when other exception is fired, the screen shows:

      Other error
      Was error

[bytebites]

Code: Pascal  [Select][+][-]

1. program Project1;
2.  
3. uses sysutils;
4. begin
5. try
6.    raise EConvertError.Create('');
7.    except
8.      on EConvertError do Writeln('Invalid number');
9.      on EDivByZero do Writeln('By zero');
10.      else begin Writeln('Other error'); end;
11.      //When a EConvertError or EDivByZero is fired, this doesn't execute.
12.      //When other is fired, this execute.
13.      writeln('Was error');
14.    end;
15. end.
16.  

Invalid number

[Paolo]

Code after "on..do" specialize the action for the specific error raised. Else introduce the answer for the other cases not listed as "on..do", else introduces a list of statements, thus begin..end in your case is useless. If I am not wrong.

[Fibonacci]

Code: Pascal  [Select][+][-]

1. uses SysUtils;
2.  
3. begin
4.   try
5.     raise EAccessViolation.Create('');
6.     //raise EDivByZero.Create('');
7.   except
8.     on EConvertError do writeln('convert error'); //wont continue
9.     on EDivByZero    do writeln('div by zero');   //wont continue
10.     else; //else is required if "on" used, otherwise its Syntax Error
11.  
12.     writeln('exception happened');
13.     writeln('and execution continues');
14.   end;
15.  
16.   writeln('the end');
17.   readln;
18. end.

exception happened
and execution continues
the end

[dbannon]

A small point. The 'else' is not required after a 'on' statement, its just one way to have a block when any other exception gets caught. A better approach, especially while developing, is to just catch any remaining exception with "on Exception", that also allows you to capture and display the exception that was caught. Then, once you know what it is, you can give it its own "on .." line.

Code: Pascal  [Select][+][-]

1.      {$mode objfpc}
2.     uses SysUtils;
3.      
4.     begin
5.       try
6.         raise EAccessViolation.Create('Test');
7.         //raise EDivByZero.Create('');
8.       except
9.         on EConvertError do writeln('convert error'); //wont continue
10.         on EDivByZero    do writeln('div by zero');   //wont continue
11. //        else; //else is required if "on" used, otherwise its Syntax Error
12. //        writeln('exception happened');
13. //        writeln('and execution continues');
14.         on E: Exception do writeln('unknown exception happened : ', E.ClassName, ' ',  E.Message);
15.       end;
16.      
17.       writeln('the end');
18.       readln;
19.     end.

Code: [Select]

dbannon@dell:~/Pascal/CLI$ ./exception
unknown exception happened : EAccessViolation Test
the end


[alpine]

Weird!
It seems that all statements following the else gets executed in case the exception was not caught, e.g.

Code: Pascal  [Select][+][-]

1.   on ...
2.   else;
3.   stat1;
4.   stat2;
5.  
6.   on ...
7.   else
8.     stat1;
9.   stat2;
10.  
11.   on ...
12.   else
13.   begin
14.     stat1;
15.     stat2;
16.   end;  
17.  

But if you have on handler, you must have else to have more statements. On the other hand, you may have statements as long you don't have on handler(s). It is shown into the diagram in https://www.freepascal.org/docs-html/current/ref/refse119.html#x245-26900017.2 BTW, but only now I paid attention to it. I always thought there should be a compound statement after the else  as in e.g. if.
Weird...

[dbannon]

Yeah, I never use the "else" there (because capturing some info about the unexpected exception is always useful) but I sure would have expected a "begin..end" would be needed for multiple statements.

On the other hand, we don't do this -

Code: Pascal  [Select][+][-]

1. try
2.     begin
3.         statement 1
4.         statement 2
5.     end
6. except

So, maybe a list after "else" without the begin .. end  makes sense, I suppose.

Davo

[Warfley]

A small point. The 'else' is not required after a 'on' statement, its just one way to have a block when any other exception gets caught. A better approach, especially while developing, is to just catch any remaining exception with "on Exception", that also allows you to capture and display the exception that was caught. Then, once you know what it is, you can give it its own "on .." line.

Until someone really hates you and puts in a "raise TStringList.Create".

Exceptions can be any object, that they inherit from Exception is just a convention. Infact you may want to write a program without relying on sysutils, then you would define your own exception classes.

So to capture any exception use TObject as base case

[Edson]

Weird!
It seems that all statements following the else gets executed in case the exception was not caught, e.g.

Code: Pascal  [Select][+][-]

1.   on ...
2.   else;
3.   stat1;
4.   stat2;
5.  
6.   on ...
7.   else
8.     stat1;
9.   stat2;
10.  
11.   on ...
12.   else
13.   begin
14.     stat1;
15.     stat2;
16.   end;  
17.  

But if you have on handler, you must have else to have more statements. On the other hand, you may have statements as long you don't have on handler(s). It is shown into the diagram in https://www.freepascal.org/docs-html/current/ref/refse119.html#x245-26900017.2 BTW, but only now I paid attention to it. I always thought there should be a compound statement after the else  as in e.g. if.
Weird...

Yes. That's the explanation. The syntax definition allows just a sentence (or block) after ON ... DO, however allows a list of sentences after ELSE ... until the delimiter END. That's an ugly syntax for ELSE (like in the CASE OF), considering the ELSE for IF works in a different way.

The syntax definition also answer my other question

First of all: Is legal to include some code after a "on ... do " sentence?

No Edson, it's not legal include code after ON sentence.