Read INI

[Pe3s]

Hello, I found the code on the internet

Code: Pascal  [Select][+][-]

1. procedure TForm1.SaveSettings;
2. begin
3.   myINI := TIniFile.Create(ChangeFileExt(Application.ExeName, '.ini'));
4.   try
5.     Assert(myINI <> nil);
6.     if HandleAllocated then
7.     begin
8.       Wp.Length := SizeOf(TWindowPlacement);
9.       GetWindowPlacement(Handle, @Wp);
10.  
11.       myINI.WriteInteger('Placement', 'Top', Wp.rcNormalPosition.Top);
12.       myINI.WriteInteger('Placement', 'Left', Wp.rcNormalPosition.Left);
13.       myINI.WriteInteger('Placement', 'Width', Wp.rcNormalPosition.Right - Wp.rcNormalPosition.Left);
14.       myINI.WriteInteger('Placement', 'Height', Wp.rcNormalPosition.Bottom - Wp.rcNormalPosition.Top);
15.  
16.       myINI.WriteBool('Placement', 'Maximized', WindowState = wsMaximized);
17.     end;
18.   finally
19.     myINI.Free;
20.   end;
21. end;

how can i read these settings
Thank you

[ezlage]

Take a look:

https://wiki.lazarus.freepascal.org/Using_INI_Files
https://www.freepascal.org/docs-html/fcl/inifiles/tinifile.html

[ArtLogi]

You can also do it with RTL functions (as filehandling and string functions) and dynamic arrays, but that is the hard way, to get everything trapped on events and more so without bugs, when there is a ready made tool for ini-files.

I can not recommend... only advantage is that it is easier to remember the primitive functions than advanced library etc.

[Handoko]

I quickly written a short demo:

Code: Pascal  [Select][+][-]

1. unit Unit1;
2.  
3. {$mode objfpc}{$H+}
4.  
5. interface
6.  
7. uses
8.   Classes, Forms, Controls, StdCtrls, IniFiles;
9.  
10. type
11.  
12.   { TForm1 }
13.  
14.   TForm1 = class(TForm)
15.     btnLoad: TButton;
16.     btnSave: TButton;
17.     chkAutosave: TCheckBox;
18.     procedure btnLoadClick(Sender: TObject);
19.     procedure btnSaveClick(Sender: TObject);
20.     procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
21.     procedure FormCreate(Sender: TObject);
22.   private
23.     procedure SavePosition;
24.     procedure LoadPosition;
25.   end;
26.  
27. const
28.   ConfigFile = 'config.ini';
29.  
30. var
31.   Form1: TForm1;
32.  
33. implementation
34.  
35. {$R *.lfm}
36.  
37. { TForm1 }
38.  
39. procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
40. begin
41.   if chkAutosave.Checked then
42.     SavePosition;
43. end;
44.  
45. procedure TForm1.FormCreate(Sender: TObject);
46. begin
47.   LoadPosition;
48. end;
49.  
50. procedure TForm1.btnLoadClick(Sender: TObject);
51. begin
52.   LoadPosition;
53. end;
54.  
55. procedure TForm1.btnSaveClick(Sender: TObject);
56. begin
57.   SavePosition;
58. end;
59.  
60. procedure TForm1.SavePosition;
61. var
62.   Config: TIniFile;
63. begin
64.   Config := TIniFile.Create(ConfigFile);
65.   try
66.     Config.WriteInteger('Position', 'Top', Self.Top);
67.     Config.WriteInteger('Position', 'Left', Self.Left);
68.     Config.WriteInteger('Position', 'Width', Self.Width);
69.     Config.WriteInteger('Position', 'Height', Self.Height);
70.   finally
71.     Config.Free;
72.   end;
73. end;
74.  
75. procedure TForm1.LoadPosition;
76. var
77.   Config: TIniFile;
78. begin
79.   Config := TIniFile.Create(ConfigFile);
80.   try
81.     Self.Top    := Config.ReadInteger('Position', 'Top', 100);
82.     Self.Left   := Config.ReadInteger('Position', 'Left', 100);
83.     Self.Width  := Config.ReadInteger('Position', 'Width', 320);
84.     Self.Height := Config.ReadInteger('Position', 'Height', 240);
85.   finally
86.     Config.Free;
87.   end;
88. end;
89.  
90. end.

'Self' in the code above can be safely removed, but to make it clear (for newbies), I kept them.

[Pe3s]

@Handoko Thank you for the demo.  the problem with ini is that I wanted to make the program remember the form size setting additionally as we maximize the form so that it can write and read.  after returning to the normal window to return to the established dimensions.

[Ally]

Hello Pe3s,

with RestoredTop ... and WindowState it works.

Code: Pascal  [Select][+][-]

1. unit Unit1;
2.  
3. {$mode objfpc}{$H+}
4.  
5. interface
6.  
7. uses
8.   Classes, Forms, Controls, StdCtrls, IniFiles;
9.  
10. type
11.  
12.   { TForm1 }
13.  
14.   TForm1 = class(TForm)
15.     btnClose: TButton;
16.     procedure btnCloseClick(Sender: TObject);
17.     procedure FormShow(Sender: TObject);
18.     procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
19.   private
20.     { private declarations }
21.   public
22.     { public declarations }
23.   end;
24.  
25. const
26.   ConfigFile = 'config.ini';
27.  
28. var
29.   Form1: TForm1;
30.  
31. implementation
32.  
33. {$R *.lfm}
34.  
35. { TForm1 }
36.  
37. procedure TForm1.btnCloseClick(Sender: TObject);
38. begin
39.   Close;
40. end;
41.  
42. procedure TForm1.FormShow(Sender: TObject);
43. var
44.   Config: TIniFile;
45. begin
46.   Config := TIniFile.Create(ConfigFile);
47.   try
48.     Top := Config.ReadInteger('Position', 'Top', 100);
49.     Left := Config.ReadInteger('Position', 'Left', 100);
50.     Width := Config.ReadInteger('Position', 'Width', 320);
51.     Height := Config.ReadInteger('Position', 'Height', 240);
52.     WindowState := TWindowState(Config.ReadInteger('Position', 'WindowState', 0));
53.   finally
54.     Config.Free;
55.   end;
56. end;
57.  
58. procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
59. var
60.   Config: TIniFile;
61. begin
62.   Config := TIniFile.Create(ConfigFile);
63.   try
64.     Config.WriteInteger('Position', 'Top', RestoredTop);
65.     Config.WriteInteger('Position', 'Left', RestoredLeft);
66.     Config.WriteInteger('Position', 'Width', RestoredWidth);
67.     Config.WriteInteger('Position', 'Height', RestoredHeight);
68.     Config.WriteInteger('Position', 'WindowState', Integer(WindowState));
69.   finally
70.     Config.Free;
71.   end;
72. end;
73.  
74. end.

[Pe3s]

Thank you, that's what I meant.
regards

[Tony Stone]

May be worth taking a look at sessionProperties as well.

https://wiki.lazarus.freepascal.org/TXMLPropStorage

@Handoko Thank you for the demo.  the problem with ini is that I wanted to make the program remember the form size setting additionally as we maximize the form so that it can write and read.  after returning to the normal window to return to the established dimensions.

[Gustavo 'Gus' Carreno]

Hey Pe3s,

The code you found is a tad hands on and there's loads you have to do by hand, which can be error prone.

Like @TonyStone mentioned, a better way of doing it is using the T[XML|INI|JSON]PropStorage.
Opting for any of those, you can have your settings automatically loaded at start up and automatically stored upon close.
And in one of 3 flavours: XML, INI, JSON.
The component even has a generic "bag" of options you can store that are not RTTI related.

I tend to use the JSON one(Disclaimer: I'm the author and asked the dev to include it on the sources) since I had an itch to scratch and I did scratch it

Hope this gives you a bit more options.

Cheers,
Gus

[Pe3s]

Thank you

[Gustavo 'Gus' Carreno]

Hey Pe3s,

Thank you

Quite welcome my fellow Pascal enthusiast.

Cheers,
Gus