Can Ttimer be used only for a GUI application or also in console applications?
You have several options for a console timer:
1. TTimer: Add LCL to the required packages(project inspector)
2 TFPTimer: Add fptimer to the uses, LCL is not needed
3. TThread: Measure time inside a thread, like this:
unit uThreadTimer;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils, lclintf;
type
TOnTimer = procedure(Sender: TObject) of object;
{ TThreadTimer }
TThreadTimer = class(TThread)
private
FTime: QWORD;
FInterval: Cardinal;
FOnTimer: TOnTimer;
FEnabled: Boolean;
procedure DoOnTimer;
protected
procedure Execute; override;
public
property OnTimer: TOnTimer read FOnTimer write FOnTimer;
property Interval: Cardinal read FInterval write FInterval;
property Enabled: Boolean read FEnabled write FEnabled;
procedure StopTimer;
procedure StartTimer;
constructor Create(CreateSuspended: Boolean);
destructor Destroy; override;
end;
implementation
constructor TThreadTimer.Create(CreateSuspended: Boolean);
begin
inherited Create(CreateSuspended);
FInterval := 1000;
FreeOnTerminate := True;
FEnabled := False;
end;
destructor TThreadTimer.Destroy;
begin
//
inherited Destroy;
end;
procedure TThreadTimer.DoOnTimer;
begin
if Assigned(FOnTimer) then
FOnTimer(Self);
end;
procedure TThreadTimer.Execute;
begin
while not Terminated do
begin
Sleep(1);
if (GetTickCount64 - FTime > FInterval) and (FEnabled) then
begin
FTime := GetTickCount64;
Synchronize(@DoOnTimer);
end;
end;
end;
procedure TThreadTimer.StopTimer;
begin
FEnabled := False;
end;
procedure TThreadTimer.StartTimer;
begin
FTime := GetTickCount64;
FEnabled := True;
if Self.Suspended then
Start;
end;
end.