Assigning a static class methods to regular procedural variables

[simone]

The reference language guide states that static class methods can be assigned to regular procedural variabile.
(https://www.freepascal.org/docs-html/ref/refsu30.html)

Nevertheless the following code generate the error:

Incompatible types: got "<class method type of procedure(TObject) of object;Register>" expected "<procedure variable type of procedure(TObject) of object;Register>"

Why? Thanks in advance for explanations!

Code: Pascal  [Select]

1. unit Unit1;
2. {$mode objfpc}{$H+}
3.  
4. interface
5.  
6. uses
7.   Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;
8.  
9. type
10.   TForm1 = class(TForm)
11.     procedure FormCreate(Sender: TObject);
12.   end;
13.  
14.   Handler=class
15.     class procedure OnClick(Sender : TObject); static;
16.   end;
17.  
18. var
19.   Form1: TForm1;
20.   Button1 : TButton;
21.  
22. implementation
23.  
24. {$R *.lfm}
25.  
26. class procedure Handler.OnClick(Sender: TObject);
27. begin
28.   ShowMessage('Ok');
29. end;
30.  
31. procedure TForm1.FormCreate(Sender: TObject);
32. begin
33.   Button1:=TButton.Create(Self);
34.   Button1.Parent:=Self;
35.   Button1.Left:=100;
36.   Button1.Top:=100;
37.   Button1.OnClick:=@Handler.OnClick;  //<--- ERROR
38. end;
39.  
40. end.

[Blaazen]

Regular procedural variable probably means this:

Code: Pascal  [Select]

1. TRegProcVar = procedure(Sender: TObject); //of object;

i.e. not method.
But it does not work too:

Code: Pascal  [Select]

1. var aRPV: TRegProcVar;
2. begin
3.   aRPV:=@Handler.OnClick;

[engkin]

Regular procedure variable is just a simple pointer.
Method variable is a record of two pointers.
Static class methods can be assigned to the first type, but you seem you want to assign them to the second type. Here is how to do it:

Code: Pascal  [Select]

1. procedure TForm1.FormCreate(Sender: TObject);
2. var
3.   e:TMethod;
4. begin
5.   Button1:=TButton.Create(Self);
6.   Button1.Parent:=Self;
7.   Button1.Left:=100;
8.   Button1.Top:=100;
9.   e.Data:=nil;
10.   e.Code:=@Handler.OnClick;
11.   Button1.OnClick:=TNotifyEvent(e);
12.   //Button1.OnClick:=@Handler.OnClick;  //<--- ERROR
13. end;

[Blaazen]

Finally, this works, but requires delphi mode (and remove @):

Code: Pascal  [Select]

1. {$mode delphi}{$H+}
2. ...
3. TRegProcVar = procedure(Sender: TObject);
4. ...
5. var aRPV: TRegProcVar;
6. begin
7.   aRPV:=Handler.OnClick;

[engkin]

Finally, this works, but requires delphi mode (and remove @):

Code: Pascal  [Select]

1. {$mode delphi}{$H+}
2. ...
3. TRegProcVar = procedure(Sender: TObject);
4. ...
5. var aRPV: TRegProcVar;
6. begin
7.   aRPV:=Handler.OnClick;

or:

Code: Pascal  [Select]

1.   aRPV: TRegProcVar;
2. begin
3.   aRPV:=TRegProcVar(@Handler.OnClick);
4.   aRPV(nil);

[simone]

It was my mistake: In the documentation I underestimated the adjective 'regular' refering to procedure.

I took into consideration class methods to logically group many event handlers of different controls created dynamically in a program with a complex GUI.

Proposed solutions are very interesting from the technical point of view, but in my context could make the code less readable. So I'm looking for others solutions. Thanks!

[Jonas Maebe]

No, it was a compiler bug. It has been fixed in the current development version: https://bugs.freepascal.org/view.php?id=27414

[simone]

Thanks Jonas. Although I'm not very familiar with Delphi, I noticed the same issue with 10.2 Starter Edition...

[clauswk]

Finally, this works, but requires delphi mode (and remove @):

Code: Pascal  [Select]

1. {$mode delphi}{$H+}
2. ...
3. TRegProcVar = procedure(Sender: TObject);
4. ...
5. var aRPV: TRegProcVar;
6. begin
7.   aRPV:=Handler.OnClick;

Thank you, Blaazen. I have been looking for a solution to a similar problem for a couple of days now, and the delphi mode did it.

Claus