avoid 2 instances program

[Ericktux]

Good day to all, my question is

how avoid open twice my program
unused "UniqueInstance"

help please. 

[howardpc]

For one example see
http://wiki.lazarus.freepascal.org/UniqueInstance

[Ericktux]

thank, but I want to use otherwise.   

[typo]

"Otherwise" has a huge range of meanings.

Do you have any issue with UniqueInstance?

[Syndrome]

example for windows:

Code: [Select]

uses LazUTF8, Windows;

function AlreadyRunning:boolean;
const
   ApplicationSecretString = 'qweqweqweqweqweqweqweqwe';
var
   MutexHandle:Handle;
   Str:UnicodeString;
begin
   Str:= UTF8ToUTF16(ApplicationSecretString);
   MutexHandle:= Crea]"]>BlockedtexW(nil,true,@Str[1]);
   if MutexHandle = 0 then exit(true);
   if GetLastError = ERROR_ALREADY_EXISTS then exit(true);
   Result:= false;
end;

procedure TForm1.FormCreate(Sender:TObject);
begin
   if AlreadyRunning then halt;
end;


[Ericktux]

I love you Syndrome, works perfectly 

last question  , how do I return the same form maximize or restore. thanks

[Ericktux]

I am testing these codes to restore the existing "form" in maximized:

Code: [Select]

procedure TForm1.FormCreate(Sender:TObject);
begin
   if AlreadyRunning then
   begin   
   //halt;
   //Application.Restore;   <--- nothing
   //Application.BringToFront;    <--- nothing
   end;
end;
but nothing happens, little help.

[Syndrome]

This example activates previous instance of application:

Code: [Select]

uses LazUTF8, Windows;

var
   InterprocVarHandle:Handle = 0;
   InterprocVar:PHandle = nil;

function AlreadyRunning:boolean;
const
   ApplicationSecretString = 'qweqweqweqweqweqweqweqwe';
var
   Str:UnicodeString;
   AlreadyCreated:Boolean;
begin
   Str:= UTF8ToUTF16(ApplicationSecretString);

   // Create an interprocess variable
   InterprocVarHandle:= CreateFileMappingW(Handle(-1),Nil,PAGE_READWRITE,0,SizeOf(InterprocVar^),@Str[1]);

   if InterprocVarHandle = 0 then exit(true);
   AlreadyCreated:= GetLastError = ERROR_ALREADY_EXISTS;

   // Get a pointer to the variable
   InterprocVar:= MapViewOfFile(InterprocVarHandle,FILE_MAP_ALL_ACCESS,0,0,SizeOf(InterprocVar^));

   if InterprocVar = nil then exit(true);
   if AlreadyCreated then exit(true);

   // Write main form's handle to the interprocess variable
   InterprocVar^:= Form1.Handle;

   Result:= false;
end;

procedure ActivatePreviousInstance;
var
   PrevMainForm:Handle;
begin
   if InterprocVar <> nil then begin
      // Read previous main form handle from the interprocess variable
      PrevMainForm:= InterprocVar^;

      SendMessage(PrevMainForm,WM_SYSCOMMAND,SC_RESTORE,0);
      SetForegroundWindow(PrevMainForm);
   end;
end;

procedure TForm1.FormCreate(Sender:TObject);
begin
   if AlreadyRunning then begin
      ActivatePreviousInstance;
      halt;
   end;
end;


[Ericktux]

Thanks Syndrome, lo probaré.