lazarus tools manual

[hamza]

Hi to all

I need a manual that explain how to use lazarus pascal tools like updown switch....etc

Thank you and waiting your support.

[JuhaManninen]

It cannot be used like an updown switch.

[hamza]

Can u help me...i need example how to use updown tool in pascal???

Also i did not find pdf files that explain lazarus tools???

[Eugene Loza]

hamza, I don't know lazarus tools like updown switch...
I remember there was a kind of a switch in some ancient Delphi version (like 1.0) widgets. I even used it once or twice... But now I can't even find the picture of it in google.

[tr_escape]

Hello Hamza,

Do you mean you need a button or slider button to change some values?

If so lazarus has got some nice buttons you can look in the attach.


But if not could you please explain much more about your project or idea?

Also you can use your orginal/native language.

Best regards

[hamza]

yes you are correct...im trying to change the values from 0-10 using updown..pl see below pic
so.plz i need just an example.

[howardpc]

Try this. Start a new Lazarus project. Double-click the main form to generate an OnCreate event handler, and complete the unit as follows:

Code: [Select]

unit mainUpDown;

{$mode objfpc}{$H+}

interface

uses
  Classes, Forms, ComCtrls, Spin;

type

  { TForm1 }

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    spinEdit: TSpinEdit;
    upDown: TUpDown;
    procedure upDownChangingEx(Sender: TObject; var AllowChange: Boolean;
                               NewValue: SmallInt; Direction: TUpDownDirection);
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  upDown:=TUpDown.Create(Self);
  upDown.Top:=10;
  upDown.Left:=10;
  upDown.OnChangingEx:=@updownChangingEx;
  upDown.Parent:=Self;

  spinEdit:=TSpinEdit.Create(Self);
  spinEdit.Top:=10;
  spinEdit.Left:=upDown.BoundsRect.Right + 10;
  spinEdit.Value:=5;
  spinEdit.Parent:=Self;

  Caption:='UpDown demo';
end;

procedure TForm1.updownChangingEx(Sender: TObject; var AllowChange: Boolean;
  NewValue: SmallInt; Direction: TUpDownDirection);
begin
  case Direction of
    updDown: spinEdit.Value:=spinEdit.Value-1;
    updUp:   spinEdit.Value:=spinEdit.Value+1;
  end;
end;

end.


Then press F9.

[tr_escape]

Hello,

Create a form and put a UpDown component.

Double click to OnChangingEx event and write that code:

Code: [Select]

procedure TForm1.UpDown1ChangingEx(Sender: TObject; var AllowChange: Boolean;
  NewValue: SmallInt; Direction: TUpDownDirection);
begin
  case Direction of
    updUp: begin
             Edit1.Text := IntToStr(NewValue);
    end;
    updDown: begin
             Edit1.Text := IntToStr(NewValue);
    end;
  end;
end;

Also you can use FloatSpinEdit and SpinEdit for changing values without coding too.

[hamza]

Mr. tr_escape and Mr. howardpc  thank you for your help.