Lazarus

Free Pascal => General => Topic started by: comingnine on September 07, 2018, 10:33:09 am

Title: Inconsistent FloatToStrF and Format ?
Post by: comingnine on September 07, 2018, 10:33:09 am

The code tries to output a rounded float, and the output are given in the block comment. As seen, FloatToStrF and Format are inconsistent within FPC, and inconsistent with Delphi under Win32 and Lnx64. Could you help to comment how to make FloatToStrF and Format consistent within FPC (and with Delphi) ?

Code: [Select]

{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}
{$ASSERTIONS ON}
program TruncBug;
{$IFNDEF FPC}{$APPTYPE CONSOLE}{$ENDIF}
uses SysUtils;

var
  A: Extended;
begin
  A := 0.6659963050;

  (*        FPC 3.1.1-r39514     Delphi7      Delphi25Tokyo
     Win32:   0.66599630       0.66599631      0.66599631
     Win64:   0.66599631                       0.66599631
     Lnx64:   0.66599630
  *)
  Writeln(FloatToStrF(A, ffFixed, 20, 8));

  (*        FPC 3.1.1-r39514     Delphi7      Delphi25Tokyo
     Win32:   0.66599630       0.66599631      0.66599631
     Win64:   0.66599631                       0.66599631
     Lnx64:   0.66599630
  *)
  Writeln(Format('%.8n',[A]));
end.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: comingnine on September 08, 2018, 05:59:57 am

It seems that the FloatToStrF and Format behave inconsistently even within FPC Win32...

Code: [Select]

{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}
{$ASSERTIONS ON}
program TruncBug;
{$IFNDEF FPC}{$APPTYPE CONSOLE}{$ENDIF}
uses
  SysUtils;

var
  A,B: Extended;
begin
  A := 0.3050;
  B := 0.6659963050;

  (*          FPC 3.1.1-r39514     Delphi7              Delphi25Tokyo
     Win32:   0.31; 0.66599630     0.31; 0.66599631     0.31; 0.66599631
     Win64:   0.31; 0.66599631                          0.31; 0.66599631
     Lnx64:   0.31; 0.66599630
  *)
  Writeln(FloatToStrF(A, ffFixed, 20, 2) + '; '+ FloatToStrF(B, ffFixed, 20, 8));

  (*          FPC 3.1.1-r39514     Delphi7              Delphi25Tokyo
     Win32:   0.31; 0.66599630     0.31; 0.66599631     0.31; 0.66599631
     Win64:   0.31; 0.66599631                          0.31; 0.66599631
     Lnx64:   0.31; 0.66599630
  *)
  Writeln(Format('%.2n; %.8n',[A,B]));
end.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: Thaddy on September 08, 2018, 08:01:19 am

Can you explain this:

Code: Pascal [Select][+]

{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}

??? :P ::) O:-) <grumpy >:D >:D>
{$IFDEF D+} is shorthand for {$IF DEFINED(DEBUG}} or even {$IFDEF DEBUG} so you just wasted a second of your life by writing this... ;D

btw the output on linux armhf 32 is:

Code: Bash [Select][+]

0.31; 0.66599631
0.31; 0.66599631

Note you are using a quite old trunk and recently there have been some changes regarding this.
IF you use trunk, then ALWAYS use the CURRENT trunk, give or take one or two minor revisions.
Otherwise it is rather pointless. I used 39712.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: comingnine on September 08, 2018, 11:21:01 am

Quote from: Thaddy on September 08, 2018, 08:01:19 am

Can you explain this:
Code: Pascal [Select][+][-]
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}
??? :P ::) O:-) <grumpy >:D >:D>
{$IFDEF D+} is shorthand for {$IF DEFINED(DEBUG}} or even {$IFDEF DEBUG} so you just wasted a second of your life by writing this... ;D

Code: [Select]

{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF} // With this redundant line commented out, nothing will be written. :D
{$ASSERTIONS ON}
program Test;
{$IFNDEF FPC}{$APPTYPE CONSOLE}{$ENDIF}
uses
  SysUtils;

begin
  {$IFDEF DEBUG}
  Writeln('Hello World');
  {$ENDIF}
end.

With that redundant line commented out, nothing will be written. :D

Quote from: Thaddy on September 08, 2018, 08:01:19 am

Note you are using a quite old trunk and recently there have been some changes regarding this.
IF you use trunk, then ALWAYS use the CURRENT trunk, give or take one or two minor revisions.
Otherwise it is rather pointless. I used 39712.

I just updated to latest trunk of FPC (3.3.1-r39711) and the same inconsistent results within FPC have been obtained...

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: marcov on September 08, 2018, 12:40:41 pm

It is strange that linux64 and win64 differ. Of course the extended type is not the most ideal type to test, specially if you include 64-bit

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: comingnine on September 08, 2018, 02:25:42 pm

Quote from: marcov on September 08, 2018, 12:40:41 pm

It is strange that linux64 and win64 differ. Of course the extended type is not the most ideal type to test, specially if you include 64-bit

The output for Double is attached. I am sorry that I do not know how to correctly interpret the output.

Code: [Select]

{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}
{$ASSERTIONS ON}
program TruncBug;
{$IFNDEF FPC}{$APPTYPE CONSOLE}{$ENDIF}
uses
  SysUtils;

var
  A,B: Double;
begin
  A := 0.3050;
  B := 0.6659963050;

  (*          FPC 3.1.1-r39514     Delphi7              Delphi25Tokyo
     Win32:   0.31; 0.66599631     0.30; 0.66599630     0.30; 0.66599630
     Win64:   0.31; 0.66599631                          0.31; 0.66599631
     Lnx64:   0.31; 0.66599631
  *)
  Writeln(FloatToStrF(A, ffFixed, 20, 2) + '; '+ FloatToStrF(B, ffFixed, 20, 8));

  (*          FPC 3.1.1-r39514     Delphi7              Delphi25Tokyo
     Win32:   0.30; 0.66599630     0.30; 0.66599630     0.30; 0.66599630
     Win64:   0.31; 0.66599631                          0.31; 0.66599631
     Lnx64:   0.30; 0.66599630
  *)
  Writeln(Format('%.2n; %.8n',[A,B]));
end.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: marcov on September 08, 2018, 03:01:02 pm

I think this is all basic floating point behaviour.

There really is no "good" way. It all depends on the number of operations and the order you do it.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: Thaddy on September 08, 2018, 03:39:23 pm

Quote from: comingnine on September 08, 2018, 11:21:01 am

With that redundant line commented out, nothing will be written. :D

{$IFOPT D+} is enough. That's the point. DEBUG is predefined for the compiler. E.g:

Code: Pascal [Select][+]

begin
  {$IFOPT D+} // is the same as { $IFDEF DEBUG} you dont't need to mix them like you did.
  Writeln('Hello World');
  {$ENDIF}
end.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: engkin on September 08, 2018, 04:11:37 pm

When you write:

Code: Pascal [Select][+]

  A := 0.3050;
  B := 0.6659963050;

The compiler has to decide the nearest "binary" representations for these "text" decimal numbers.

What do you get if you try:

Code: Pascal [Select][+]

var
  A,B: Double;
  Ax: DWord absolute A;
  Bx: DWord absolute B;
begin
  A := 0.3050;
  B := 0.6659963050;
  WriteLn('$',IntToHex(Ax,8),', $',IntToHex(Bx,8));

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: Gammatester on September 08, 2018, 04:15:27 pm

Quote from: Thaddy on September 08, 2018, 03:39:23 pm

Quote from: comingnine on September 08, 2018, 11:21:01 am
With that redundant line commented out, nothing will be written. :D
{$IFOPT D+} is enough. That's the point. DEBUG is predefined for the compiler. E.g:
Code: Pascal [Select][+][-]
begin
{$IFOPT D+} // is the same as {$IFDEF DEBUG} you dont't need to mix them like you did.
Writeln('Hello World');
{$ENDIF}
end.

I can confirm comingnine's observation. Here there is no output (Win7/64 and FPC304 or FPC311). May be this is default for Lazarus?

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: PascalDragon on September 08, 2018, 04:22:36 pm

Quote from: marcov on September 08, 2018, 12:40:41 pm

It is strange that linux64 and win64 differ. Of course the extended type is not the most ideal type to test, specially if you include 64-bit

No, it's not. Win64 is the only x86_64 target where Extended is not available. The other targets have not deprecated the FPU and thus FPC is happily using it for calculations.

Quote from: comingnine on September 07, 2018, 10:33:09 am

The code tries to output a rounded float, and the output are given in the block comment. As seen, FloatToStrF and Format are inconsistent within FPC, and inconsistent with Delphi under Win32 and Lnx64. Could you help to comment how to make FloatToStrF and Format consistent within FPC (and with Delphi) ?

The difference between the FPC targets is that Extended is not available on x86_64-win64, while it is available for the other x86_64 targets as well as all i386 targets (plus i8086, but that's probably neither here nor there for you :P ). It's also not supported on any other platform we have (e.g. ARM, PowerPC, etc.).
So your best bet would be to stick with Double if you want to be cross platform.
Why Delphi differs to FPC I don't know though it could be (as only the final digit differs) that FPC rounds a tad different than Delphi.

Quote from: Thaddy on September 08, 2018, 03:39:23 pm

Quote from: comingnine on September 08, 2018, 11:21:01 am
With that redundant line commented out, nothing will be written. :D
{$IFOPT D+} is enough. That's the point. DEBUG is predefined for the compiler. E.g:
Code: Pascal [Select][+][-]
begin
{$IFOPT D+} // is the same as { $IFDEF DEBUG} you dont't need to mix them like you did.
Writeln('Hello World');
{$ENDIF}
end.

You are not entirely correct. The D option or DebugInfo is only enabled (outside of using $D+ or $DebugInfo On) when the parameter -g is passed (see here (https://www.freepascal.org/docs-html/current/prog/progsu89.html#x97-960001.3.6)).
However by default the fpc.cfg file contains this:

Code: [Select]

#IFDEF DEBUG
  -gl
  -Crtoi
  #WRITE Compiling Debug Version
#ENDIF

So it's in fact like this: if you compile with -dDEBUG then -g will be set and thus the D option will be as well.

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: comingnine on September 08, 2018, 05:20:15 pm

Quote from: engkin on September 08, 2018, 04:11:37 pm

What do you get if you try:

It seems the representation is the same.

Code: [Select]

{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$IFOPT D+} {$DEFINE DEBUG} {$ENDIF}
{$ASSERTIONS ON}
program TruncBug;
{$IFNDEF FPC}{$APPTYPE CONSOLE}{$ENDIF}
uses
  SysUtils;

var
  A,B: Double;
  Ax: Cardinal absolute A;
  Bx: Cardinal absolute B;
begin
  A := 0.3050;
  B := 0.6659963050;

  (*          FPC 3.1.1-r39514         Delphi7                  Delphi25Tokyo
     Win32:   0.31; 0.66599631         0.30; 0.66599630         0.30; 0.66599630
     Win64:   0.31; 0.66599631                                  0.31; 0.66599631
     Lnx64:   0.31; 0.66599631
  *)
  Writeln(FloatToStrF(A, ffFixed, 20, 2) + '; '+ FloatToStrF(B, ffFixed, 20, 8));

  (*          FPC 3.1.1-r39514         Delphi7                  Delphi25Tokyo
     Win32:   0.30; 0.66599630         0.30; 0.66599630         0.30; 0.66599630
     Win64:   0.31; 0.66599631                                  0.31; 0.66599631
     Lnx64:   0.30; 0.66599630
  *)
  Writeln(Format('%.2n; %.8n',[A,B]));

  (*          FPC                      Delphi7                  Delphi25Tokyo
     WIN32    $B851EB85, $7BA76B3E     $B851EB85, $7BA76B3E     $B851EB85, $7BA76B3E
     WIN64    $B851EB85, $7BA76B3E                              $B851EB85, $7BA76B3E
     LNX64    $B851EB85, $7BA76B3E
  *)
  WriteLn('$',IntToHex(Ax,8),', $',IntToHex(Bx,8))
end.

Quote from: PascalDragon on September 08, 2018, 04:22:36 pm

Many thanks for your helpful comments !

Title: Re: Inconsistent FloatToStrF and Format ?
Post by: engkin on September 09, 2018, 07:29:15 am

Quote from: comingnine on September 08, 2018, 05:20:15 pm

It seems the representation is the same.

While most likely they are the same, but the previous code is wrong. We should use QWord instead of DWord. Double is 8 bytes.