Recent

Author Topic: Synedit with word wrap?  (Read 19415 times)

cookie22

  • New Member
  • *
  • Posts: 16
Synedit with word wrap?
« on: October 23, 2014, 04:10:03 pm »
I need synedit with word wrap. Does any one know about a version or someone who implemented word wrap to synedit?

I don't understand why such a basic feature is missing in such a mighty component.

Thanks,

Cookie

BigChimp

  • Hero Member
  • *****
  • Posts: 5740
  • Add to the wiki - it's free ;)
    • FPCUp, PaperTiger scanning and other open source projects
Want quicker answers to your questions? Read http://wiki.lazarus.freepascal.org/Lazarus_Faq#What_is_the_correct_way_to_ask_questions_in_the_forum.3F

Open source including papertiger OCR/PDF scanning:
https://bitbucket.org/reiniero

Lazarus trunk+FPC trunk x86, Windows x64 unless otherwise specified

typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #2 on: October 23, 2014, 04:46:35 pm »
I am trying to write a SynEdit descendant which would make SynEdit more friendly  to ordinary edit usage. But I cannot promise anything.

Perhaps for now you could try this wordwrap routine, since FPC WordWrap funtion does not work fine.

Code: [Select]
function WrapTextUTF8(S :string; MaxCol: integer): string;
var
  P :PChar;
  CharLen :integer;
  RightSpace : Integer = 0;
  N :integer = 0;
  i : Integer;
  j : Integer;
  Len :integer = 0;
  ResultLen :Integer;
  LineEndingLen :Integer;
begin
  Result := '';
  P := PChar(S);
  while P^ <> #0 do
  begin
    CharLen := UTF8CharacterLength(P);

    // Result := Result + UTF8Copy(P, 1, 1);
    i := 1;
    j := 0;
    ResultLen := Length(Result);
    while i <= CharLen do
    begin
      /// Result := Result + (P + j)^;
      SetLength(Result, ResultLen + 1);
      Result[ResultLen + 1] := (P + j)^;
      ///
      Inc(i);
      Inc(j);
      Inc(ResultLen);
    end;
    //
    Inc(N);
    if P^ = #10 then
      N := 0;
    if N > MaxCol then
    begin
      Len := Length(Result);
      RightSpace := Len - RPos(' ', Result);
      if RightSpace > 0 then
      begin
        Dec(P, RightSpace);
        Dec(Len, RightSpace);
        SetLength(Result, Len {- RightSpace});
      end;
      // Add lineending chars to Result
      Result := Result + LineEnding;
      {---
      LineEndingLen := Length(LineEnding);
      SetLength(Result, Len + LineEndingLen);
      if LineEndingLen = 1 then
        Result[Len + 1] := LineEnding[1]
      else
      begin
        Result[Len + 1] := LineEnding[1];
        Result[Len + 2] := LineEnding[2]
      end;
      ---}
      N := 0;
    end;
    Inc(P, CharLen);
  end;
end;         

Maybe you could even improve it.

http://bugs.freepascal.org/view.php?id=26677
« Last Edit: October 23, 2014, 04:55:46 pm by typo »

Edson

  • Hero Member
  • *****
  • Posts: 1301
Re: Synedit with word wrap?
« Reply #3 on: October 23, 2014, 07:29:03 pm »
I am trying to write a SynEdit descendant which would make SynEdit more friendly  to ordinary edit usage. But I cannot promise anything.
Are you thinking on include some other features, apart from Word wrap?
Lazarus 2.2.6 - FPC 3.2.2 - x86_64-win64 on Windows 10

typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #4 on: October 23, 2014, 11:51:18 pm »
Formatted text.

I don't know if I could actually "implement" wordwrapping on SynEdit. I will try. For my needs probably it will be enough.
« Last Edit: October 24, 2014, 12:20:53 am by typo »

Edson

  • Hero Member
  • *****
  • Posts: 1301
Re: Synedit with word wrap?
« Reply #5 on: October 24, 2014, 05:34:49 am »
I think Word wrap it's a lot of work on SynEdit. Specially if you want to control correctly the line number.

Anyway, Good luck.
Lazarus 2.2.6 - FPC 3.2.2 - x86_64-win64 on Windows 10

cookie22

  • New Member
  • *
  • Posts: 16
Re: Synedit with word wrap?
« Reply #6 on: October 24, 2014, 08:51:40 am »
That's true, but I don't get why it was removed in the port. The original version had it already implemeted.  :'(

It is realy a very basic feature.
« Last Edit: October 24, 2014, 08:53:26 am by cookie22 »

BigChimp

  • Hero Member
  • *****
  • Posts: 5740
  • Add to the wiki - it's free ;)
    • FPCUp, PaperTiger scanning and other open source projects
Re: Synedit with word wrap?
« Reply #7 on: October 24, 2014, 09:27:17 am »
You're very welcome to write a patch to put it back in based on the original code...
Want quicker answers to your questions? Read http://wiki.lazarus.freepascal.org/Lazarus_Faq#What_is_the_correct_way_to_ask_questions_in_the_forum.3F

Open source including papertiger OCR/PDF scanning:
https://bitbucket.org/reiniero

Lazarus trunk+FPC trunk x86, Windows x64 unless otherwise specified

typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #8 on: October 29, 2014, 09:32:02 pm »
I think wordwrap was implemented after the forking that has originated our SynEdit.

http://sourceforge.net/p/synedit/wiki/Home/

On this SynEdit, word wrap is made by a plugin. Here is the whole SynEditWordWrap.pas file:

Code: [Select]
{-------------------------------------------------------------------------------
The contents of this file are subject to the Mozilla Public License
Version 1.1 (the "License"); you may not use this file except in compliance
with the License. You may obtain a copy of the License at
http://www.mozilla.org/MPL/

Software distributed under the License is distributed on an "AS IS" basis,
WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License for
the specific language governing rights and limitations under the License.

The Original Code is SynEditWordWrap.pas by Flávio Etrusco, released 2003-12-11.
Unicode translation by Maël Hörz.
All Rights Reserved.

Contributors to the SynEdit and mwEdit projects are listed in the
Contributors.txt file.

Alternatively, the contents of this file may be used under the terms of the
GNU General Public License Version 2 or later (the "GPL"), in which case
the provisions of the GPL are applicable instead of those above.
If you wish to allow use of your version of this file only under the terms
of the GPL and not to allow others to use your version of this file
under the MPL, indicate your decision by deleting the provisions above and
replace them with the notice and other provisions required by the GPL.
If you do not delete the provisions above, a recipient may use your version
of this file under either the MPL or the GPL.

$Id: SynEditWordWrap.pas,v 1.8.2.6 2008/09/14 16:24:59 maelh Exp $

You may retrieve the latest version of this file at the SynEdit home page,
located at http://SynEdit.SourceForge.net

Known Issues:
-------------------------------------------------------------------------------}
//todo: Use a single implementation of ReWrapLines that takes starting line and number of lines to rewrap
//todo: Tweak code to try finding better wrapping points. Some support by the highlighters will be needed, probably.
//todo: Document the code
//todo: The length of the last Row of a Line could be calculated from the Line length instead of being stored. This would be only useful when most of the lines aren't wrapped.

{$IFNDEF QSYNEDITWORDWRAP}
unit SynEditWordWrap;
{$ENDIF}

{$I SynEdit.inc}

interface

uses
{$IFDEF SYN_CLX}
  QSynEditTypes,
  QSynEditTextBuffer,
  QSynEdit,
{$ELSE}
  SynEditTypes,
  SynEditTextBuffer,
  SynEdit,
{$ENDIF}
  SysUtils,
  Classes;

var
  // Accumulate/hide whitespace at EOL (at end of wrapped rows, actually)
  OldWhitespaceBehaviour: Boolean = False;

const
  MaxIndex = MaxInt div 16;

type
  TLineIndex = 0..MaxIndex;
  TRowIndex = 0..MaxIndex;
  TRowLength = word;

  TRowIndexArray = array [TLineIndex] of TRowIndex;
  PRowIndexArray = ^TRowIndexArray;

  TRowLengthArray = array [TRowIndex] of TRowLength;
  PRowLengthArray = ^TRowLengthArray;

  {$IFNDEF SYN_COMPILER_4_UP}
  TSysCharSet = set of Char;
  {$ENDIF}

  // For clarity, I'll refer to buffer coordinates as 'Line' and
  // 'Char' and to display (wrapped) coordinates as 'Row' and 'Column'.

  // fLineOffsets[n] is the index of the first row of the [n+1]th line.
  // e.g. Starting row of first line (0) is 0. Starting row of second line (1)
  // is fLineOffsets[0]. Clear?

  TSynWordWrapPlugin = class(TInterfacedObject, ISynEditBufferPlugin)
  private
    fLineOffsets: PRowIndexArray;
    fRowLengths: PRowLengthArray;
    fLineCapacity: integer;
    fRowCapacity: integer;
    fLineCount: integer;

    fEditor: TCustomSynEdit;
    fMinRowLength: TRowLength;
    fMaxRowLength: TRowLength;
    procedure GrowLines(aMinSize: integer);
    procedure MoveLines(aStart: TLineIndex; aMoveBy: integer);
    procedure GrowRows(aMinSize: integer);
    procedure MoveRows(aStart: TRowIndex; aMoveBy: integer);
    procedure SetEmpty;
  protected
    procedure WrapLines;
    function ReWrapLine(aIndex: TLineIndex): integer;
    procedure TrimArrays;
    property LineOffsets: PRowIndexArray read fLineOffsets;
    property RowLengths: PRowLengthArray read fRowLengths;
    property Editor: TCustomSynEdit read fEditor;
  public
    constructor Create(aOwner: TCustomSynEdit);
    destructor Destroy; override;
    property LineCount: integer read fLineCount;
    { ISynEditBufferPlugin }
    function BufferToDisplayPos(const aPos: TBufferCoord): TDisplayCoord;
    function DisplayToBufferPos(const aPos: TDisplayCoord): TBufferCoord;
    function RowCount: integer;
    function GetRowLength(aRow: integer): integer;
    function LinesInserted(aIndex: integer; aCount: integer): integer;
    function LinesDeleted(aIndex: integer; aCount: integer): integer;
    function LinesPutted(aIndex: integer; aCount: integer): integer;
    procedure Reset;
    procedure DisplayChanged;
  end;

implementation

uses
{$IFDEF SYN_CLX}
  QSynUnicode,
{$ELSE}
  SynUnicode,
{$ENDIF}
{$IFDEF SYN_COMPILER_6_UP}
  RTLConsts,
{$ELSE}
  {$IFDEF SYN_CLX}
    QConsts,
  {$ELSE}
    Consts,
  {$ENDIF}
{$ENDIF}
{$IFNDEF SYN_COMPILER_4_UP}
  SynEditMiscProcs,
{$ENDIF}
  Math;

{ TSynWordWrapPlugin }

function TSynWordWrapPlugin.BufferToDisplayPos(
  const aPos: TBufferCoord): TDisplayCoord;
var
  vStartRow: integer; // first row of the line
  cRow: integer;
  vRowLen: integer;
begin
  Assert(aPos.Char > 0);
  Assert(aPos.Line > 0);
  if LineCount < aPos.Line then
  begin
    // beyond EOF
    Result.Column := aPos.Char;
    Result.Row := RowCount + (aPos.Line - LineCount);
    Exit;
  end;
  if aPos.Line = 1 then
    vStartRow := 0
  else
    vStartRow := fLineOffsets[aPos.Line - 2];
  vRowLen := 0;
  for cRow := vStartRow to fLineOffsets[aPos.Line - 1] - 1 do
  begin
    Inc(vRowLen, fRowLengths[cRow]);
    if aPos.Char <= vRowLen then
    begin
      Result.Column := aPos.Char - vRowLen + fRowLengths[cRow];
      Result.Row := cRow + 1;
      Exit;
    end;
  end;
  // beyond EOL
  Result.Column := aPos.Char - vRowLen + fRowLengths[fLineOffsets[aPos.Line - 1] - 1];
  Result.Row := fLineOffsets[aPos.Line - 1];
end;

constructor TSynWordWrapPlugin.Create(aOwner: TCustomSynEdit);
begin
  inherited Create; // just to work as reminder in case I revert it to a TComponent...
  if aOwner = nil then
    raise Exception.Create( 'Owner of TSynWordWrapPlugin must be a TCustomSynEdit' );
  fEditor := aOwner;
  Reset;
end;

destructor TSynWordWrapPlugin.Destroy;
begin
  inherited;
  FreeMem(fLineOffsets);
  FreeMem(fRowLengths);
end;

procedure TSynWordWrapPlugin.DisplayChanged;
begin
  if Editor.CharsInWindow <> fMaxRowLength then
    Reset;
end;

function TSynWordWrapPlugin.DisplayToBufferPos(
  const aPos: TDisplayCoord): TBufferCoord;
var
  cLine: integer;
  cRow: integer;
begin
  Assert(aPos.Column > 0);
  Assert(aPos.Row > 0);
  if aPos.Row > RowCount then
  begin
    // beyond EOF
    Result.Char := aPos.Column;
    Result.Line := aPos.Row - RowCount + LineCount;
    Exit;
  end;
  //todo: use a binary search or something smarter
  for cLine := LineCount - 2 downto 0 do
    if aPos.Row > fLineOffsets[cLine] then
    begin
      Result.Line := cLine + 2;
      if aPos.Row = fLineOffsets[cLine + 1] then //last row of line
        Result.Char := Min(aPos.Column, fMaxRowLength + 1)
      else
        Result.Char := Min(aPos.Column, fRowLengths[aPos.Row - 1] + 1);
      for cRow := fLineOffsets[cLine] to aPos.Row - 2 do
        Inc(Result.Char, fRowLengths[cRow]);
      Exit;
    end;
  // first line
  Result.Line := 1;
  if aPos.Row = fLineOffsets[0] then //last row of line
    Result.Char := Min(aPos.Column, fMaxRowLength + 1)
  else
    Result.Char := Min(aPos.Column, fRowLengths[aPos.Row - 1] + 1);
  for cRow := 0 to aPos.Row - 2 do
    Inc(Result.Char, fRowLengths[cRow]);
end;

function TSynWordWrapPlugin.GetRowLength(aRow: integer): integer;
// aRow is 1-based...
begin
  if (aRow <= 0) or (aRow > RowCount) then
    TList.Error(SListIndexError, aRow);
  Result := fRowLengths[aRow - 1];
end;

procedure TSynWordWrapPlugin.GrowLines(aMinSize: integer);
const
  vStepSize = 256;
begin
  Assert(aMinSize > 0);
  if aMinSize > fLineCapacity then
  begin
    aMinSize := aMinSize + vStepSize - (aMinSize mod vStepSize);
    ReallocMem(fLineOffsets, aMinSize * SizeOf(TRowIndex));
    fLineCapacity := aMinSize;
  end;
end;

procedure TSynWordWrapPlugin.GrowRows(aMinSize: integer);
const
  vStepSize = 512;
begin
  Assert(aMinSize > 0);
  if aMinSize > fRowCapacity then
  begin
    aMinSize := aMinSize + vStepSize - (aMinSize mod vStepSize);
    ReallocMem(fRowLengths, aMinSize * SizeOf(TRowLength));
    fRowCapacity := aMinSize;
  end;
end;

function TSynWordWrapPlugin.LinesDeleted(aIndex: integer; aCount: integer): integer;
var
  vStartRow: integer;
  vEndRow: integer;
  cLine: integer;
begin
  if fMaxRowLength = 0 then
  begin
    Result := 0;
    Exit;
  end;
  Assert(aIndex >= 0);
  Assert(aCount >= 1);
  Assert(aIndex + aCount <= LineCount);

  if aIndex = 0 then
    vStartRow := 0
  else
    vStartRow := fLineOffsets[aIndex - 1];
  vEndRow := fLineOffsets[aIndex + aCount - 1];
  Result := vEndRow - vStartRow;
  // resize fRowLengths
  if vEndRow < RowCount then
    MoveRows(vEndRow, -Result);
  // resize fLineOffsets
  MoveLines(aIndex + aCount, -aCount);
  Dec(fLineCount, aCount);
  // update offsets
  for cLine := aIndex to LineCount - 1 do
    Dec(fLineOffsets[cLine], Result);
end;

function TSynWordWrapPlugin.LinesInserted(aIndex: integer; aCount: integer): integer;
var
  vPrevOffset: TRowIndex;
  cLine: integer;
begin
  if fMaxRowLength = 0 then
  begin
    Result := 0;
    Exit;
  end;
  Assert(aIndex >= 0);
  Assert(aCount >= 1);
  Assert(aIndex <= LineCount);
  // resize fLineOffsets
  GrowLines(LineCount + aCount);
  if aIndex < LineCount then // no need for MoveLines if inserting at LineCount (TSynEditStringList.Add)
  begin
    Inc(fLineCount, aCount); // fLineCount must be updated before calling MoveLines()
    MoveLines(aIndex, aCount);
  end
  else
    Inc(fLineCount, aCount);
  // set offset to same as previous line (i.e. the line has 0 rows)
  if aIndex = 0 then
    vPrevOffset := 0
  else
    vPrevOffset := fLineOffsets[aIndex - 1];
  for cLine := aIndex to aIndex + aCount - 1 do
    fLineOffsets[cLine] := vPrevOffset;
  // Rewrap
  Result := 0;
  for cLine := aIndex to aIndex + aCount - 1 do
    Inc(Result, ReWrapLine(cLine));
end;

function TSynWordWrapPlugin.LinesPutted(aIndex: integer; aCount: integer): integer;
var
  cLine: integer;
begin
  if fMaxRowLength = 0 then
  begin
    Result := 0;
    Exit;
  end;
  Assert(aIndex >= 0);
  Assert(aCount >= 1);
  Assert(aIndex + aCount <= LineCount);
  // Rewrap
  Result := 0;
  for cLine := aIndex to aIndex + aCount - 1 do
    Inc(Result, ReWrapLine(cLine));
end;

procedure TSynWordWrapPlugin.MoveLines(aStart: TLineIndex; aMoveBy: integer);
var
  vMoveCount: integer;
begin
  Assert(aMoveBy <> 0);
  Assert(aStart + aMoveBy >= 0);
  Assert(aStart + aMoveBy < LineCount);
  vMoveCount := LineCount - aStart;
  if aMoveBy > 0 then
    Dec(vMoveCount, aMoveBy);
  Move(fLineOffsets[aStart], fLineOffsets[aStart + aMoveBy],
    vMoveCount * SizeOf(TRowIndex));
end;

procedure TSynWordWrapPlugin.MoveRows(aStart: TRowIndex; aMoveBy: integer);
var
  vMoveCount: integer;
begin
  Assert(aMoveBy <> 0);
  Assert(aStart + aMoveBy >= 0);
  Assert(aStart + aMoveBy < RowCount);
  vMoveCount := RowCount - aStart;
  if aMoveBy > 0 then
    Dec(vMoveCount, aMoveBy);
  Move(fRowLengths[aStart], fRowLengths[aStart + aMoveBy],
    vMoveCount * SizeOf(TRowLength));
end;

procedure TSynWordWrapPlugin.Reset;
begin
  Assert(Editor.CharsInWindow >= 0);

  fMaxRowLength := Editor.CharsInWindow;
  fMinRowLength := Editor.CharsInWindow - (Editor.CharsInWindow div 3);

  if fMinRowLength <= 0 then
    fMinRowLength := 1;

  WrapLines;
end;

function TSynWordWrapPlugin.ReWrapLine(aIndex: TLineIndex): integer;
// Returns RowCount delta (how many wrapped lines were added or removed by this change).
var
  vMaxNewRows: Cardinal;
  vLine: UnicodeString;
  vLineRowCount: Integer; //numbers of rows parsed in this line
  vTempRowLengths: PRowLengthArray;
  vRowBegin: PWideChar;
  vLineEnd: PWideChar;
  vRowEnd: PWideChar;
  vRunner: PWideChar;
  vRowMinEnd: PWideChar;
  vLastVisibleChar: PWideChar;

  vStartRow: Integer; // first row of the line
  vOldNextRow: Integer; // first row of the next line, before the change
  cLine: Integer;

  p : PRowIndexArray;
begin
  // ****** First parse the new string using an auxiliar array *****
  vLine := TSynEditStringList(Editor.Lines).ExpandedStrings[aIndex];
  vLine := Editor.ExpandAtWideGlyphs(vLine);
  // Pre-allocate a buffer for rowlengths
  vMaxNewRows := ((Length(vLine) - 1) div fMinRowLength) + 1;
  vTempRowLengths := AllocMem(vMaxNewRows * SizeOf(TRowLength));
  try
    vLineRowCount := 0;
    vRowBegin := PWideChar(vLine);
    vRowEnd := vRowBegin + fMaxRowLength;
    vLineEnd := vRowBegin + Length(vLine);
    while vRowEnd < vLineEnd do
    begin
      if OldWhitespaceBehaviour and CharInSet(vRowEnd^, [#32, #9]) then
      begin
        repeat
          Inc(vRowEnd);
        until not CharInSet(vRowEnd^, [#32, #9]);
      end
      else
      begin
        vRowMinEnd := vRowBegin + fMinRowLength;
        vRunner := vRowEnd;
        while vRunner > vRowMinEnd do
        begin
          if Editor.IsWordBreakChar(vRunner^) then
          begin
            vRowEnd := vRunner;
            break;
          end;
          Dec(vRunner);
        end;
      end;
      // Check TRowLength overflow
      if OldWhitespaceBehaviour and (vRowEnd - vRowBegin > High(TRowLength)) then
      begin
        vRowEnd := vRowBegin + High(TRowLength);
        vRowMinEnd := vRowEnd - (High(TRowLength) mod Editor.TabWidth);
        while (vRowEnd^ = #9) and (vRowEnd > vRowMinEnd) do
          Dec(vRowEnd);
      end;

      // do not cut wide glyphs in half
      if vRowEnd > vRowBegin then
      begin
        vLastVisibleChar := vRowEnd - 1;
        while (vLastVisibleChar^ = FillerChar) and (vLastVisibleChar > vRowBegin) do
          dec(vLastVisibleChar);
        vRowEnd := vLastVisibleChar + 1;
      end;

      // Finally store the rowlength
      vTempRowLengths[vLineRowCount] := vRowEnd - vRowBegin;

      Inc(vLineRowCount);
      vRowBegin := vRowEnd;
      Inc(vRowEnd, fMaxRowLength);
    end; //endwhile vRowEnd < vLineEnd
    if (vLineEnd > vRowBegin) or (Length(vLine) = 0) then
    begin
      vTempRowLengths[vLineRowCount] := vLineEnd - vRowBegin;
      Inc(vLineRowCount);
    end;

    // ****** Then updates the main arrays ******
    if aIndex = 0 then
      vStartRow := 0
    else
      vStartRow := fLineOffsets[aIndex - 1];
    vOldNextRow := fLineOffsets[aIndex];
    Result := vLineRowCount - (vOldNextRow - vStartRow);
    if Result <> 0 then
    begin
      // MoveRows depends on RowCount, so we need some special processing...
      if Result > 0 then
      begin
        // ...if growing, update offsets (and thus RowCount) before rowlengths
        GrowRows(RowCount + Result);
        if Result = 1 then begin
          // EG: this makes Schlemiel run twice as fast, but doesn't solve
          // the algorithmic issue if someone can spend some time looking
          // at the big picture... there are huge speedups to be made by
          // eliminating this loop
          p:=fLineOffsets;
          for cLine := aIndex to LineCount - 1 do
             Inc(p[cLine])
        end else begin
          p:=fLineOffsets;
          for cLine := aIndex to LineCount - 1 do
            Inc(p[cLine], Result);
        end;
        if vOldNextRow < RowCount - Result then
          MoveRows(vOldNextRow, Result);
      end
      else
      begin
        // ...if shrinking, update offsets after rowlengths
        if vOldNextRow < RowCount then
          MoveRows(vOldNextRow, Result);
        for cLine := aIndex to LineCount - 1 do
          Inc(fLineOffsets[cLine], Result);
      end;
    end;
    Move(vTempRowLengths[0], fRowLengths[vStartRow], vLineRowCount * SizeOf(TRowLength));
  finally
    FreeMem(vTempRowLengths);
  end;
end;

procedure TSynWordWrapPlugin.WrapLines;
var
  cRow: Integer;
  cLine: Integer;
  vLine: UnicodeString;
  vMaxNewRows: Integer;
  vRowBegin: PWideChar;
  vLineEnd: PWideChar;
  vRowEnd: PWideChar;
  vRunner: PWideChar;
  vRowMinEnd: PWideChar;
  vLastVisibleChar: PWideChar;
begin
  if (Editor.Lines.Count = 0) or (fMaxRowLength <= 0) then
  begin
    SetEmpty;
    Exit;
  end;

  GrowLines(Editor.Lines.Count);
  GrowRows(Editor.Lines.Count);

  cRow := 0;
  for cLine := 0 to Editor.Lines.Count - 1 do
  begin
    vLine := TSynEditStringList(Editor.Lines).ExpandedStrings[cLine];
    vLine := Editor.ExpandAtWideGlyphs(vLine);

    vMaxNewRows := ((Length(vLine) - 1) div fMinRowLength) + 1;
    GrowRows(cRow + vMaxNewRows);

    vRowBegin := PWideChar(vLine);
    vRowEnd := vRowBegin + fMaxRowLength;
    vLineEnd := vRowBegin + Length(vLine);
    while vRowEnd < vLineEnd do
    begin
      if OldWhitespaceBehaviour and CharInSet(vRowEnd^, [#32, #9]) then
      begin
        repeat
          Inc(vRowEnd);
        until not CharInSet(vRowEnd^, [#32, #9]);
      end
      else
      begin
        vRowMinEnd := vRowBegin + fMinRowLength;
        vRunner := vRowEnd;
        while vRunner > vRowMinEnd do
        begin
          if Editor.IsWordBreakChar(vRunner^) then
          begin
            vRowEnd := vRunner;
            break;
          end;
          Dec(vRunner);
        end;
      end;

      if OldWhitespaceBehaviour and (vRowEnd - vRowBegin > High(TRowLength)) then
      begin
        vRowEnd := vRowBegin + High(TRowLength);
        vRowMinEnd := vRowEnd - (High(TRowLength) mod Editor.TabWidth);
        while (vRowEnd^ = #9) and (vRowEnd > vRowMinEnd) do
          Dec(vRowEnd);
      end;

      // do not cut wide glyphs in half
      if vRowEnd > vRowBegin then
      begin
        vLastVisibleChar := vRowEnd - 1;
        while (vLastVisibleChar^ = FillerChar) and (vLastVisibleChar > vRowBegin) do
          dec(vLastVisibleChar);
        vRowEnd := vLastVisibleChar + 1;
      end;

      fRowLengths[cRow] := vRowEnd - vRowBegin;

      Inc(cRow);
      vRowBegin := vRowEnd;
      Inc(vRowEnd, fMaxRowLength);
    end;
    if (vLineEnd > vRowBegin) or (Length(vLine) = 0) then
    begin
      fRowLengths[cRow] := vLineEnd - vRowBegin;
      Inc(cRow);
    end;
    fLineOffsets[cLine] := cRow;
  end;
  fLineCount := Editor.Lines.Count;
end;

function TSynWordWrapPlugin.RowCount: integer;
begin
  if LineCount > 0 then
    Result := fLineOffsets[LineCount - 1]
  else
    Result := 0;
end;

procedure TSynWordWrapPlugin.SetEmpty;
begin
  fLineCount := 0;
  // free unsused memory
  TrimArrays;
end;

procedure TSynWordWrapPlugin.TrimArrays;
begin
  ReallocMem(fLineOffsets, LineCount * SizeOf(TRowIndex));
  fLineCapacity := LineCount;
  ReallocMem(fRowLengths, RowCount * SizeOf(TRowLength));
  fRowCapacity := RowCount;
end;

end.         
« Last Edit: October 30, 2014, 12:37:25 am by typo »

cookie22

  • New Member
  • *
  • Posts: 16
Re: Synedit with word wrap?
« Reply #9 on: October 31, 2014, 10:52:34 pm »
The problem is, you can't just copy it because the gutter works different in both forks.

typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #10 on: October 31, 2014, 11:05:31 pm »
Yes, of course, and not only the Gutter.

Indeed this component is not helping me so much, since it seems to deliver results to SynEdit itself, which is different from ours.

With our SynEdit probably I will need to handle the text by myself. If I could simply deliver an array of text information like this component seems to do, the things would be easier.
« Last Edit: October 31, 2014, 11:29:01 pm by typo »

Martin_fr

  • Administrator
  • Hero Member
  • *
  • Posts: 9794
  • Debugger - SynEdit - and more
    • wiki
Re: Synedit with word wrap?
« Reply #11 on: November 01, 2014, 12:03:57 am »
If you refer to the one you attached in http://forum.lazarus.freepascal.org/index.php/topic,26320.0

On a very surface inspection: It stores a mapping of real line, and display line in fLineOffsets
(e.g if line 1 wraps, then line 2 becomes display line 3 ...)

That is how folding works (just reverse) The fold module does that. There is a concept of "views" wrapping around the text buffer, based on TSynEditStrings.

Only folding is not fully based on that yet, but it is meant to someday be.

So there is a place to hook. (unfinished...)

---
Problem:
fLineOffsets: array ...

works for small text.

But if you have 100,000 lines or more then it becomes *very CPU intensive.

Because if you jump to a bookmark at line 50000 you need to sum up all the lines above (required to set the scrollbar right)

So you need a better storage. Some kind of index. A tree with pages of line mappings.

--------------
And yes, all that "view" stuff, wass added after the fork. So the old edit does not have it.


typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #12 on: November 01, 2014, 11:16:56 am »
AFAICS, text processors handle only visible lines or paragraphs, letting lines/pages count calculation to a different thread. It is not so fast, anyway.

Text processors pages are not so easily resizable and word wrap process can be "hiden" from the user in a thread.
« Last Edit: November 01, 2014, 12:41:21 pm by typo »

Martin_fr

  • Administrator
  • Hero Member
  • *
  • Posts: 9794
  • Debugger - SynEdit - and more
    • wiki
Re: Synedit with word wrap?
« Reply #13 on: November 01, 2014, 12:51:10 pm »
Yes, wordwrap (re-wrap) for none visible lines, are bes done in a thread (or in idle)

But that is not what I wrote about:

In order to set the scrollbar (which must correspondent to the amount of visible lines (lines after wrapping) you must often calculate between real and visible numbers.

In the array, you store info per line. that is if a line wraps once, you store "2" (meaning: this line takes 2 display lines).
Then to get the line mapping, for line 50000 you must sum-up 50000 entries.

If you store the final map (that is for line 5 you store 10, because all lines wrap once, so this is the 10th visible line) then it gets worse. Edit the 1st line of text, so it rewraps, and you  have to update all entries.

Even in a thread it uses up your laptops battery....


typo

  • Hero Member
  • *****
  • Posts: 3051
Re: Synedit with word wrap?
« Reply #14 on: November 01, 2014, 02:01:49 pm »
Could not one re-wrap only until the end of the paragraph? And store paragraph information instead of lines? Paragraphs are not as often modified in number of lines when edited. And resizing could be made not so easy.

I see that lines in SynEdit are paragraphs and why store information relativelly to the first line?

Reset procedure in this component should be used only when resized, not for every edition one does.

So why not to limit resizability?
« Last Edit: November 01, 2014, 09:23:05 pm by typo »

 

TinyPortal © 2005-2018