Problem with calling procdeure from different Units

[ciammaruca]

hi,
yes, but again: if i backward want to work from Unit2 in Unit1 Form1?
For example, how to create a TEdit in Form1 from Unit2? If i use this below in Unit2, identifer Form1 is not found obviusly!
So, how to make find Form1 from Unit2 ?
thanks

var
  g: TEdit;

begin
  g:=TEdit.Create(Form1);
  g.Parent:=Form1;
end;

[Blaazen]

You need to create the second uses section.

Code: [Select]

...

implementation

uses Unit1;

...

[howardpc]

Here's an example of one way to accomplish what Blaazen explains.

Form1

Code: [Select]

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Forms, StdCtrls;

type

  TForm1 = class(TForm)
  public
    function CreateForm1Edit: TEdit;
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

function TForm1.CreateForm1Edit: TEdit;
begin
  Result:=TEdit.Create(Self);
  Result.Parent:=Self;
end;

end.

Form2

Code: [Select]

unit Unit2;

{$mode objfpc}{$H+}

interface

uses
  Forms, StdCtrls;

type

  TForm2 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    aUnit1Edit: TEdit;
  end;

var
  Form2: TForm2;

implementation

uses Unit1;

{$R *.lfm}

procedure TForm2.FormCreate(Sender: TObject);
begin
  aUnit1Edit:=Form1.CreateForm1Edit;
  aUnit1Edit.SetBounds(10,10,120,23);
  aUnit1Edit.Caption:='Created by Unit2';
end;

end.



[ciammaruca]

gracias caballeros.
One more help, if possible, just to speeding my study: following my example, how to get events of my "on the fly/runtime" TEdit object? So for my example, how to get TForm1.eClick(Sender: TObject) from the both cases, from Unit1 and from Unit2?
muchas gracias a todo el mundo

[cdbc]

Hi
Here's one: http://www.tutorialspoint.com/pascal/
Or... Search for "marco cantu pascal" on google 
Edit: for studying/learning pascal 
Regards Benny

[ciammaruca]

hi again,
no, i can't find the way to call events of runtime objects. So, please, as brief as i can:
- from Unit1 Form1 i call the function Test() in Unit2.
- Test() function in Unit2 creates a new Edit:
implementation
   uses Unit1;
procedure  editCambiato(Sender: TObject);
procedure test();
var
  e: TEdit;
begin
    e:=TEdit.Create(Form1);
    e.Parent:=Form1;
    e.Left:=10;
    e.Top:=50;
   e.OnClick:=@editCambiato; //<-----but this does not work!
end;

The "e.OnClick:=@editCambiato;" line makes this error:
unit2.pas(26,15) Error: Incompatible types: got "<address of procedure(TObject);Register>" expected "<procedure variable type of procedure(TObject) of object;Register>"
So, how to call the e.OnClick event in/from Unit2?

thank you

[taazz]

unit2.pas(26,15) Error: Incompatible types: got "<address of procedure(TObject);Register>" expected "<procedure variable type of procedure(TObject) of object;Register>"

As the message says you can't use simple procedures you need to use object methods.

[ciammaruca]

hi,
ok, but what do you mean? Have i to create an object, as described in this point:
http://wiki.freepascal.org/Programming_Using_Objects#Objects_-_Basics
But again, following my simple example, how to create and call an OnClick event in/from Unit2 of a runtime created object?
Plaese, could you show me the way?
 muchas gracias

[Leledumbo]

Regular procedures are declared OUTSIDE class declaration. "Procedure of object" or simply "method", is declared INSIDE class declaration. Depending on the problem context, you can put your own method in existing classes or write a new class and put it there instead. Technically, the difference lies in the hidden Self parameter. For methods, this refers to the current instance of the owning class. For procedures, this doesn't exist (well, what instance of what class should it refer to?) and thus, the two need to be considered different.